[gentoo-commits] gentoo-x86 commit in net-p2p/ktorrent: ChangeLog ktorrent-2.2.7.ebuild ktorrent-3.0.2.ebuild

[Ioannis Aslanidis (deathwing00)]

deathwing00    08/05/31 12:55:51

  Modified:             ChangeLog
  Added:                ktorrent-2.2.7.ebuild ktorrent-3.0.2.ebuild
  Log:
  Version bump.
  (Portage version: 2.1.5.2)

Revision  Changes    Path
1.82                 net-p2p/ktorrent/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-p2p/ktorrent/ChangeLog?rev=1.82&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-p2p/ktorrent/ChangeLog?rev=1.82&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-p2p/ktorrent/ChangeLog?r1=1.81&r2=1.82

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-p2p/ktorrent/ChangeLog,v
retrieving revision 1.81
retrieving revision 1.82
diff -u -r1.81 -r1.82
--- ChangeLog	25 Apr 2008 15:30:08 -0000	1.81
+++ ChangeLog	31 May 2008 12:55:51 -0000	1.82
@@ -1,6 +1,13 @@
 # ChangeLog for net-p2p/ktorrent
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-p2p/ktorrent/ChangeLog,v 1.81 2008/04/25 15:30:08 yngwin Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-p2p/ktorrent/ChangeLog,v 1.82 2008/05/31 12:55:51 deathwing00 Exp $
+
+*ktorrent-3.0.2 (31 May 2008)
+*ktorrent-2.2.7 (31 May 2008)
+
+  31 May 2008; Ioannis Aslanidis <deathwing00@g.o>
+  +ktorrent-2.2.7.ebuild, +ktorrent-3.0.2.ebuild:
+  Version bump.
 
 *ktorrent-2.2.6 (25 Apr 2008)
 



1.1                  net-p2p/ktorrent/ktorrent-2.2.7.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-p2p/ktorrent/ktorrent-2.2.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-p2p/ktorrent/ktorrent-2.2.7.ebuild?rev=1.1&content-type=text/plain

Index: ktorrent-2.2.7.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-p2p/ktorrent/ktorrent-2.2.7.ebuild,v 1.1 2008/05/31 12:55:51 deathwing00 Exp $

inherit kde

MY_P="${P/_/}"
MY_PV="${PV/_/}"
DESCRIPTION="A BitTorrent program for KDE."
HOMEPAGE="http://ktorrent.org/"
SRC_URI="http://ktorrent.org/downloads/${MY_PV}/${MY_P}.tar.bz2"
LICENSE="GPL-2"

SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="avahi kdeenablefinal"

DEPEND="dev-libs/gmp
	>=dev-libs/geoip-1.4.0-r1
	avahi? ( >=net-dns/avahi-0.6.16-r1 )"
RDEPEND="${DEPEND}
	|| ( =kde-base/kdebase-kioslaves-3.5* =kde-base/kdebase-3.5* )"

S="${WORKDIR}/${MY_P}"

need-kde 3.5

LANGS="ar bg br ca cs cy da de el en_GB es et fa fr gl hu it ja ka lt
ms nb nds nl pa pl pt pt_BR ru rw sk sr sr@Latn sv tr uk zh_CN zh_TW"

for X in ${LANGS} ; do
	IUSE="${IUSE} linguas_${X}"
done

pkg_setup() {
	if use avahi && ! built_with_use net-dns/avahi qt3 ; then
		echo
		eerror "In order to use ktorrents zeroconf plugin you need to have"
		eerror "net-dns/avahi emerged with \"qt3\" in your USE flag. Please add"
		eerror "that flag, re-emerge avahi, and then emerge ktorrent again."
		echo
		die "net-dns/avahi not built with \"qt3\" support."
	fi

	kde_pkg_setup
}

src_unpack() {
	kde_src_unpack

	local MAKE_LANGS
	cd "${WORKDIR}/${MY_P}/translations"
	for X in ${LANGS} ; do
		use linguas_${X} && MAKE_LANGS="${MAKE_LANGS} ${X}"
	done
	sed -i -e "s:SUBDIRS=.*:SUBDIRS=${MAKE_LANGS}:" Makefile.am

	cd "${S}"
	# Fix automagic dependencies on avahi
	epatch "${FILESDIR}/${PN}-2.2.5-avahi-check.patch"

	rm -f "${S}/configure"
}

src_compile(){
	local myconf="${myconf}
		$(use_with avahi)
		--enable-builtin-country-flags
		--enable-knetwork
		--enable-system-geoip
		--enable-torrent-mimetype
		--disable-geoip"

	kde_src_compile
}



1.1                  net-p2p/ktorrent/ktorrent-3.0.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-p2p/ktorrent/ktorrent-3.0.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-p2p/ktorrent/ktorrent-3.0.2.ebuild?rev=1.1&content-type=text/plain

Index: ktorrent-3.0.2.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-p2p/ktorrent/ktorrent-3.0.2.ebuild,v 1.1 2008/05/31 12:55:51 deathwing00 Exp $

EAPI="1"
NEED_KDE=":kde-4"
inherit versionator kde4-base

# Install to KDEDIR rather than /usr, to slot properly.
PREFIX="${KDEDIR}"

DESCRIPTION="A BitTorrent program for KDE."
HOMEPAGE="http://ktorrent.org/"
SRC_URI="http://${PN}.org/downloads/${PV}/${P}.tar.bz2"

LICENSE="GPL-2"
KEYWORDS="~amd64 ~x86"
SLOT="kde-4"
IUSE="+bwscheduler +infowidget +ipfilter +logviewer +scanfolder +search +stats +upnp +webinterface +zeroconf"

DEPEND="dev-libs/gmp
	app-crypt/qca:2"
RDEPEND="${DEPEND}
	infowidget? ( >=dev-libs/geoip-1.4.4 )
	ipfilter? (
		|| ( >=kde-base/kdebase-kioslaves-4.0.0:${SLOT}
			>=kde-base/kdebase-4.0.0:${SLOT} ) )
	zeroconf? (
		|| ( >=kde-base/kdnssd-4.0.0:${SLOT}
			>=kde-base/kdenetwork-4.0.0:${SLOT} ) )"

LANGS="ar be bg ca da de el en_GB eo es et eu fi fr ga gl hu it ja km lt nb nds nl nn
oc pl pt pt_BR ru se sk sr sv tr uk zh_CN zh_TW"

for X in ${LANGS}; do
	IUSE="${IUSE} linguas_${X}"
done

src_compile() {
	comment_all_add_subdirectory po/ || die "sed to remove all linguas failed."

	local X
	for X in ${LANGS}; do
		if use linguas_${X}; then
			sed -i -e "/add_subdirectory(\s*${X}\s*)\s*$/ s/^#DONOTCOMPILE //" \
				po/CMakeLists.txt || die "sed to uncomment ${lang} failed."
		fi
	done

	mycmakeargs="${mycmakeargs}
		-DCMAKE_INSTALL_PREFIX=${PREFIX}
		-DENABLE_DHT_SUPPORT=ON
		$(cmake-utils_use_enable bwscheduler BWSCHEDULER_PLUGIN)
		$(cmake-utils_use_enable infowidget INFOWIDGET_PLUGIN)
		$(cmake-utils_use_with infowidget SYSTEM_GEOIP)
		$(cmake-utils_use_enable ipfilter IPFILTER_PLUGIN)
		$(cmake-utils_use_enable logviewer LOGVIEWER_PLUGIN)
		$(cmake-utils_use_enable scanfolder SCANFOLDER_PLUGIN)
		$(cmake-utils_use_enable search SEARCH_PLUGIN)
		$(cmake-utils_use_enable stats STATS_PLUGIN)
		$(cmake-utils_use_enable upnp UPNP_PLUGIN)
		$(cmake-utils_use_enable webinterface WEBINTERFACE_PLUGIN)
		$(cmake-utils_use_enable zeroconf ZEROCONF_PLUGIN)"
	kde4-base_src_compile
}



-- 
gentoo-commits@l.g.o mailing list