[gentoo-commits] gentoo-x86 commit in sys-libs/e2fsprogs-libs: ChangeLog e2fsprogs-libs-1.41.1.ebuild

[Mike Frysinger (vapier)]

vapier      08/09/01 22:29:36

  Modified:             ChangeLog
  Added:                e2fsprogs-libs-1.41.1.ebuild
  Log:
  Version bump.
  (Portage version: 2.2_rc8/cvs/Linux 2.6.26.2 x86_64)

Revision  Changes    Path
1.3                  sys-libs/e2fsprogs-libs/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog?r1=1.2&r2=1.3

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- ChangeLog	16 Aug 2008 04:59:44 -0000	1.2
+++ ChangeLog	1 Sep 2008 22:29:36 -0000	1.3
@@ -1,6 +1,12 @@
 # ChangeLog for sys-libs/e2fsprogs-libs
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog,v 1.2 2008/08/16 04:59:44 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog,v 1.3 2008/09/01 22:29:36 vapier Exp $
+
+*e2fsprogs-libs-1.41.1 (01 Sep 2008)
+
+  01 Sep 2008; Mike Frysinger <vapier@g.o>
+  +files/e2fsprogs-libs-1.41.1-subs.patch, +e2fsprogs-libs-1.41.1.ebuild:
+  Version bump.
 
   16 Aug 2008; Mike Frysinger <vapier@g.o>
   +files/e2fsprogs-libs-1.41.0-null-blkid.patch,



1.1                  sys-libs/e2fsprogs-libs/e2fsprogs-libs-1.41.1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/e2fsprogs-libs/e2fsprogs-libs-1.41.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/e2fsprogs-libs/e2fsprogs-libs-1.41.1.ebuild?rev=1.1&content-type=text/plain

Index: e2fsprogs-libs-1.41.1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-libs/e2fsprogs-libs/e2fsprogs-libs-1.41.1.ebuild,v 1.1 2008/09/01 22:29:36 vapier Exp $

inherit eutils flag-o-matic toolchain-funcs

DESCRIPTION="e2fsprogs libraries (common error, subsystem, uuid, block id)"
HOMEPAGE="http://e2fsprogs.sourceforge.net/"
SRC_URI="mirror://sourceforge/e2fsprogs/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="nls"

RDEPEND="!sys-libs/com_err
	!sys-libs/ss
	!<sys-fs/e2fsprogs-1.41"
DEPEND="nls? ( sys-devel/gettext )
	sys-devel/bc"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${PN}-1.41.0-makefile.patch
	epatch "${FILESDIR}"/${PN}-1.41.1-subs.patch
}

src_compile() {
	export LDCONFIG=/bin/true
	export CC=$(tc-getCC)
	export STRIP=/bin/true

	# We want to use the "bsd" libraries while building on Darwin, but while
	# building on other Gentoo/*BSD we prefer elf-naming scheme.
	local libtype
	case ${CHOST} in
		*-darwin*) libtype=bsd;;
		*)         libtype=elf;;
	esac

	econf \
		--enable-${libtype}-shlibs \
		$(use_enable !elibc_uclibc tls) \
		$(use_enable nls) \
		|| die
	emake || die
}

src_install() {
	export LDCONFIG=/bin/true
	export CC=$(tc-getCC)
	export STRIP=/bin/true

	emake DESTDIR="${D}" install || die

	dodir /$(get_libdir)
	local lib slib
	for lib in "${D}"/usr/$(get_libdir)/*.a ; do
		slib=${lib##*/}
		mv "${lib%.a}"$(get_libname)* "${D}"/$(get_libdir)/ || die "moving lib ${slib}"
		gen_usr_ldscript ${slib%.a}$(get_libname)
	done
}