[gentoo-commits] gentoo-x86 commit in net-analyzer/argus: ChangeLog argus-3.0.3.8.ebuild

[Peter Volkov (pva)]

pva         10/05/06 09:06:10

  Modified:             ChangeLog
  Added:                argus-3.0.3.8.ebuild
  Log:
  Version bump. Some patches were accepted upstream.
  (Portage version: 2.1.8.3/cvs/Linux x86_64)

Revision  Changes    Path
1.23                 net-analyzer/argus/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/argus/ChangeLog?rev=1.23&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/argus/ChangeLog?rev=1.23&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/argus/ChangeLog?r1=1.22&r2=1.23

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/argus/ChangeLog,v
retrieving revision 1.22
retrieving revision 1.23
diff -u -r1.22 -r1.23
--- ChangeLog	2 May 2010 15:16:28 -0000	1.22
+++ ChangeLog	6 May 2010 09:06:10 -0000	1.23
@@ -1,6 +1,12 @@
 # ChangeLog for net-analyzer/argus
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/argus/ChangeLog,v 1.22 2010/05/02 15:16:28 pva Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/argus/ChangeLog,v 1.23 2010/05/06 09:06:10 pva Exp $
+
+*argus-3.0.3.8 (06 May 2010)
+
+  06 May 2010; Peter Volkov <pva@g.o> +argus-3.0.3.8.ebuild,
+  +files/argus-3.0.3.8-autoconf-2.65.patch:
+  Version bump. Some patches were accepted upstream.
 
 *argus-3.0.3.7 (02 May 2010)
 



1.1                  net-analyzer/argus/argus-3.0.3.8.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/argus/argus-3.0.3.8.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-analyzer/argus/argus-3.0.3.8.ebuild?rev=1.1&content-type=text/plain

Index: argus-3.0.3.8.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/argus/argus-3.0.3.8.ebuild,v 1.1 2010/05/06 09:06:10 pva Exp $

EAPI="2"

inherit eutils autotools

DESCRIPTION="network Audit Record Generation and Utilization System"
HOMEPAGE="http://www.qosient.com/argus/"
SRC_URI="http://qosient.com/argus/dev/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
IUSE="debug tcpd"

#	sasl? ( >=dev-libs/cyrus-sasl-2.1.22 )
RDEPEND="net-libs/libpcap
	tcpd? ( >=sys-apps/tcp-wrappers-7.6 )"

DEPEND="${RDEPEND}
	>=sys-devel/bison-1.28
	>=sys-devel/flex-2.4.6"

src_prepare() {
	sed -e 's:/etc/argus.conf:/etc/argus/argus.conf:' \
		-i argus/argus.c \
		-i support/Config/argus.conf \
		-i man/man8/argus.8 \
		-i man/man5/argus.conf.5 || die

	sed -e 's:#\(ARGUS_SETUSER_ID=\).*:\1argus:' \
		-e 's:#\(ARGUS_SETGROUP_ID=\).*:\1argus:' \
		-e 's:\(#ARGUS_CHROOT_DIR=\).*:\1/var/lib/argus:' \
			-i support/Config/argus.conf || die

	epatch "${FILESDIR}/argus-3.0.3.8-autoconf-2.65.patch"
	eautoreconf
}

src_configure() {
	use debug && touch .debug # enable debugging
	#	$(use_with sasl) \
	econf \
		$(use_with tcpd wrappers)
}

src_install () {
	doman man/man5/* man/man8/*
	dosbin bin/argus{,bug} || die

	dodoc ChangeLog CREDITS README || die

	insinto /etc/argus
	doins support/Config/argus.conf || die

	newinitd "${FILESDIR}/argus.initd" argus || die
	dodir /var/lib/argus
}

pkg_preinst() {
	enewgroup argus
	enewuser argus -1 -1 /var/lib/argus argus
}

pkg_postinst() {
	elog "Note, if you modify ARGUS_DAEMON value in argus.conf it's quite"
	elog "possible that init script will fail to work."
}