[gentoo-commits] gentoo-x86 commit in dev-util/gtk-doc: gtk-doc-1.13-r1.ebuild ChangeLog

[Romain Perier (mrpouet)]

mrpouet     10/02/16 20:06:54

  Modified:             ChangeLog
  Added:                gtk-doc-1.13-r1.ebuild
  Log:
  Import two patches from upstream: touch MODULE-overrides.txt when missing in gtkdoc-scan, be compatible with old versions of gtk-doc in fixxref. Per bug #305191, thanks to Kacper Kowalik.
  (Portage version: 2.2_rc62/cvs/Linux x86_64)

Revision  Changes    Path
1.116                dev-util/gtk-doc/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/gtk-doc/ChangeLog?rev=1.116&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/gtk-doc/ChangeLog?rev=1.116&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/gtk-doc/ChangeLog?r1=1.115&r2=1.116

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/gtk-doc/ChangeLog,v
retrieving revision 1.115
retrieving revision 1.116
diff -u -r1.115 -r1.116
--- ChangeLog	14 Feb 2010 22:23:40 -0000	1.115
+++ ChangeLog	16 Feb 2010 20:06:54 -0000	1.116
@@ -1,6 +1,16 @@
 # ChangeLog for dev-util/gtk-doc
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/gtk-doc/ChangeLog,v 1.115 2010/02/14 22:23:40 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/gtk-doc/ChangeLog,v 1.116 2010/02/16 20:06:54 mrpouet Exp $
+
+*gtk-doc-1.13-r1 (16 Feb 2010)
+
+  16 Feb 2010; Romain Perier <mrpouet@g.o>
+  +gtk-doc-1.13-r1.ebuild,
+  +files/gtk-doc-1.13-fixxref-compat.patch,
+  +files/gtk-doc-1.13-scan-touch-module-overrides.patch:
+  Import two patches from upstream: touch MODULE-overrides.txt when missing
+  in gtkdoc-scan, be compatible with old versions of gtk-doc in fixxref. Per
+  bug #305191, thanks to Kacper Kowalik.
 
 *gtk-doc-1.13 (14 Feb 2010)
 



1.1                  dev-util/gtk-doc/gtk-doc-1.13-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/gtk-doc/gtk-doc-1.13-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-util/gtk-doc/gtk-doc-1.13-r1.ebuild?rev=1.1&content-type=text/plain

Index: gtk-doc-1.13-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/gtk-doc/gtk-doc-1.13-r1.ebuild,v 1.1 2010/02/16 20:06:54 mrpouet Exp $

EAPI="2"

inherit eutils elisp-common gnome2

DESCRIPTION="GTK+ Documentation Generator"
HOMEPAGE="http://www.gtk.org/gtk-doc/"

LICENSE="GPL-2 FDL-1.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
IUSE="debug doc emacs test"

RDEPEND=">=dev-libs/glib-2.6
	>=dev-lang/perl-5.6
	>=app-text/openjade-1.3.1
	dev-libs/libxslt
	>=dev-libs/libxml2-2.3.6
	~app-text/docbook-xml-dtd-4.3
	app-text/docbook-xsl-stylesheets
	~app-text/docbook-sgml-dtd-3.0
	>=app-text/docbook-dsssl-stylesheets-1.40
	emacs? ( virtual/emacs )"

DEPEND="${RDEPEND}
	~dev-util/gtk-doc-am-${PV}
	>=dev-util/pkgconfig-0.19
	>=app-text/scrollkeeper-0.3.14
	>=app-text/gnome-doc-utils-0.3.2
	test? ( app-text/scrollkeeper-dtd )"

SITEFILE=61${PN}-gentoo.el

DOCS="AUTHORS ChangeLog MAINTAINERS NEWS README TODO"

src_prepare() {
	gnome2_src_prepare

	# Remove global Emacs keybindings.
	epatch "${FILESDIR}/${PN}-1.8-emacs-keybindings.patch"

	# gtk-doc.make puts $(DOC_MODULE)-overrides.txt in EXTRA_DIST,
	# so this file must exist to be able to "make dist".
	# fix bug #305191, upstream ##590625.
	epatch "${FILESDIR}/${P}-scan-touch-module-overrides.patch"
	# This restores a compatible behavior with previous versions of gtk-doc,
	# which is required by many tarballs, fix bug #305191, upstream #605211
	epatch "${FILESDIR}/${P}-fixxref-compat.patch"
}

src_compile() {
	gnome2_src_compile

	use emacs && elisp-compile tools/gtk-doc.el
}

src_install() {
	gnome2_src_install

	# Don't install those files, they are in gtk-doc-am now
	rm "${D}"/usr/share/aclocal/gtk-doc.m4 || die "failed to remove gtk-doc.m4"
	rm "${D}"/usr/bin/gtkdoc-rebase || die "failed to remove gtkdoc-rebase"

	if use doc; then
		docinto doc
		dodoc doc/*
		docinto examples
		dodoc examples/*
	fi

	if use emacs; then
		elisp-install ${PN} tools/gtk-doc.el*
		elisp-site-file-install "${FILESDIR}/${SITEFILE}"
	fi
}

pkg_postinst() {
	if use emacs; then
		elisp-site-regen
		elog "gtk-doc does no longer define global key bindings for Emacs."
		elog "You may set your own key bindings for \"gtk-doc-insert\" and"
		elog "\"gtk-doc-insert-section\" in your ~/.emacs file."
	fi
}

pkg_postrm() {
	use emacs && elisp-site-regen
}