[gentoo-commits] gentoo-x86 commit in app-text/hyperestraier: ChangeLog hyperestraier-1.4.13.ebuild

[Akinori Hattori (hattya)]

hattya      08/02/04 17:28:35

  Modified:             ChangeLog
  Added:                hyperestraier-1.4.13.ebuild
  Log:
  new upstream release.
  (Portage version: 2.1.3.19)

Revision  Changes    Path
1.47                 app-text/hyperestraier/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/hyperestraier/ChangeLog?rev=1.47&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/hyperestraier/ChangeLog?rev=1.47&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/hyperestraier/ChangeLog?r1=1.46&r2=1.47

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-text/hyperestraier/ChangeLog,v
retrieving revision 1.46
retrieving revision 1.47
diff -u -r1.46 -r1.47
--- ChangeLog	17 Nov 2007 20:53:28 -0000	1.46
+++ ChangeLog	4 Feb 2008 17:28:35 -0000	1.47
@@ -1,6 +1,12 @@
 # ChangeLog for app-text/hyperestraier
-# Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/hyperestraier/ChangeLog,v 1.46 2007/11/17 20:53:28 wltjr Exp $
+# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-text/hyperestraier/ChangeLog,v 1.47 2008/02/04 17:28:35 hattya Exp $
+
+*hyperestraier-1.4.13 (04 Feb 2008)
+
+  04 Feb 2008; Akinori Hattori <hattya@g.o>
+  +hyperestraier-1.4.13.ebuild:
+  new upstream release.
 
   17 Nov 2007; William L. Thomson Jr. <wltjr@g.o>
   -hyperestraier-1.4.0-r1.ebuild, -hyperestraier-1.4.9.ebuild,



1.1                  app-text/hyperestraier/hyperestraier-1.4.13.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/hyperestraier/hyperestraier-1.4.13.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/hyperestraier/hyperestraier-1.4.13.ebuild?rev=1.1&content-type=text/plain

Index: hyperestraier-1.4.13.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-text/hyperestraier/hyperestraier-1.4.13.ebuild,v 1.1 2008/02/04 17:28:35 hattya Exp $

inherit java-pkg-opt-2

IUSE="debug java mecab ruby"

DESCRIPTION="a full-text search system for communities"
HOMEPAGE="http://hyperestraier.sf.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="LGPL-2.1"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"
SLOT="0"

RDEPEND=">=dev-db/qdbm-1.8.75
	sys-libs/zlib
	java? ( >=virtual/jre-1.4 )
	mecab? ( app-text/mecab )
	ruby? ( dev-lang/ruby )"
DEPEND="${RDEPEND}
	java? ( >=virtual/jdk-1.4 )"

src_unpack() {

	unpack ${A}
	cd "${S}"

	# fix for insecure runpath warning.
	sed -i "/^LDENV/d" Makefile.in

	sed -i "/^JAVACFLAGS/s:$: ${JAVACFLAGS}:" java*/Makefile.in

}

src_compile() {

	econf \
		`use_enable debug` \
		`use_enable mecab` \
		|| die
	emake || die

	local u d

	for u in java ruby; do
		if ! use ${u}; then
			continue
		fi

		for d in ${u}native ${u}pure; do
			cd ${d}
			econf || die
			emake || die
			cd -
		done
	done

}

src_test() {

	emake -j1 check || die

	local u d

	for u in java ruby; do
		if ! use ${u}; then
			continue
		fi

		for d in ${u}native; do
			cd ${d}
			emake -j1 check || die
			cd -
		done
	done

}

src_install() {

	emake DESTDIR="${D}" MYDOCS= install || die
	dodoc ChangeLog README* THANKS
	dohtml doc/*

	local u d

	for u in java ruby; do
		if ! use ${u}; then
			continue
		fi

		for d in ${u}native ${u}pure; do
			cd ${d}
			emake DESTDIR="${D}" install || die
			cd -
			dohtml -r doc/${d}api
		done
	done

	if use java; then
		java-pkg_dojar "${D}"/usr/$(get_libdir)/*.jar
		rm -f "${D}"/usr/$(get_libdir)/*.jar
	fi

	rm -f "${D}"/usr/bin/*test

}



-- 
gentoo-commits@l.g.o mailing list