[gentoo-commits] repo/gentoo:master commit in: dev-libs/9libs/

[Jeroen Roovers]

commit:     50509dd21d74690f368892b196c1af6c6187f123
Author:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
AuthorDate: Sun Jan 13 23:19:18 2019 +0000
Commit:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
CommitDate: Mon Jan 14 00:04:53 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=50509dd2

dev-libs/9libs: Add USE=X,static-libs

Package-Manager: Portage-2.3.55, Repoman-2.3.12
Signed-off-by: Jeroen Roovers <jer <AT> gentoo.org>

 dev-libs/9libs/9libs-1.0-r4.ebuild | 59 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)

diff --git a/dev-libs/9libs/9libs-1.0-r4.ebuild b/dev-libs/9libs/9libs-1.0-r4.ebuild
new file mode 100644
index 00000000000..84c7b9323a1
--- /dev/null
+++ b/dev-libs/9libs/9libs-1.0-r4.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools toolchain-funcs
+
+DESCRIPTION="A package of Plan 9 compatibility libraries"
+HOMEPAGE="https://www.netlib.org/research/9libs/9libs-1.0.README"
+SRC_URI="https://www.netlib.org/research/9libs/${P}.tar.bz2"
+
+LICENSE="PLAN9"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="static-libs X"
+
+DEPEND="
+	X? (
+		>=x11-libs/libX11-1.0.0[static-libs?]
+		>=x11-libs/libXt-1.0.0[static-libs?]
+	)
+"
+RDEPEND="
+	${DEPEND}
+"
+DOCS=(
+	README
+)
+PATCHES=(
+	"${FILESDIR}"/${PN}-va_list.patch # Bug 385387
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	tc-export CC
+
+	econf \
+		$(use_enable static-libs static) \
+		$(use_with X x) \
+		--enable-shared \
+		--includedir=/usr/include/9libs
+}
+
+src_install() {
+	default
+
+	# rename some man pages to avoid collisions with dev-libs/libevent
+	local f
+	for f in add balloc bitblt cachechars event frame graphics rgbpix; do
+		mv "${D}"/usr/share/man/man3/${f}.{3,3g} || die
+	done
+
+	if ! use static-libs; then
+		find "${ED}" -name '*.la' -delete || die
+	fi
+}