[gentoo-commits] gentoo-x86 commit in sys-libs/slang: slang-2.2.0.ebuild ChangeLog

[Matsuu Takuto (matsuu)]

matsuu      09/08/24 23:57:01

  Modified:             ChangeLog
  Added:                slang-2.2.0.ebuild
  Log:
  Version bumped. Added zlib USE flag.
  (Portage version: 2.1.6.13/cvs/Linux x86_64)

Revision  Changes    Path
1.101                sys-libs/slang/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/slang/ChangeLog?rev=1.101&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/slang/ChangeLog?rev=1.101&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/slang/ChangeLog?r1=1.100&r2=1.101

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-libs/slang/ChangeLog,v
retrieving revision 1.100
retrieving revision 1.101
diff -u -r1.100 -r1.101
--- ChangeLog	6 May 2009 17:56:05 -0000	1.100
+++ ChangeLog	24 Aug 2009 23:57:00 -0000	1.101
@@ -1,6 +1,11 @@
 # ChangeLog for sys-libs/slang
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-libs/slang/ChangeLog,v 1.100 2009/05/06 17:56:05 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/slang/ChangeLog,v 1.101 2009/08/24 23:57:00 matsuu Exp $
+
+*slang-2.2.0 (24 Aug 2009)
+
+  24 Aug 2009; MATSUU Takuto <matsuu@g.o> +slang-2.2.0.ebuild:
+  Version bumped. Added zlib USE flag.
 
   06 May 2009; Raúl Porcel <armin76@g.o> slang-2.1.4.ebuild:
   arm/ia64/s390/sh/sparc stable wrt #267920



1.1                  sys-libs/slang/slang-2.2.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/slang/slang-2.2.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-libs/slang/slang-2.2.0.ebuild?rev=1.1&content-type=text/plain

Index: slang-2.2.0.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-libs/slang/slang-2.2.0.ebuild,v 1.1 2009/08/24 23:57:00 matsuu Exp $

EAPI=2
inherit eutils

DESCRIPTION="a portable programmer's library designed to allow a developer to create robust portable software."
HOMEPAGE="http://www.s-lang.org"
SRC_URI="ftp://ftp.fu-berlin.de/pub/unix/misc/slang/v${PV%.*}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
IUSE="cjk pcre png readline zlib"

RDEPEND="sys-libs/ncurses
	pcre? ( dev-libs/libpcre )
	png? ( media-libs/libpng )
	cjk? ( dev-libs/oniguruma )
	readline? ( sys-libs/readline )
	zlib? ( sys-libs/zlib )"
DEPEND="${RDEPEND}"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-2.1.2-slsh-libs.patch \
		"${FILESDIR}"/${PN}-2.1.3-uclibc.patch
}

src_configure() {
	local myconf

	if use readline; then
		myconf+=" --with-readline=gnu"
	else
		myconf+=" --with-readline=slang"
	fi

	econf \
		$(use_with cjk onig) \
		$(use_with pcre) \
		$(use_with png) \
		$(use_with zlib z) \
		${myconf}
}

src_compile() {
	emake -j1 elf static || die "emake elf static failed"

	cd slsh
	emake -j1 slsh || die "emake slsh failed"
}

src_install() {
	emake -j1 DESTDIR="${D}" install-all || die "emake install-all failed"

	rm -rf "${D}"/usr/share/doc/{slang,slsh}

	dodoc NEWS README *.txt doc/{,internal,text}/*.txt
	dohtml doc/slangdoc.html slsh/doc/html/*.html
}