[gentoo-commits] gentoo-x86 commit in net-misc/rygel: ChangeLog rygel-0.9.6.ebuild

[Gilles Dartiguelongue (eva)]

eva         11/01/23 23:07:19

  Modified:             ChangeLog
  Added:                rygel-0.9.6.ebuild
  Log:
  Version bump. Port to gtk+:3.
  
  (Portage version: 2.2.0_alpha18/cvs/Linux x86_64)

Revision  Changes    Path
1.6                  net-misc/rygel/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/rygel/ChangeLog?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/rygel/ChangeLog?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/rygel/ChangeLog?r1=1.5&r2=1.6

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/rygel/ChangeLog,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- ChangeLog	11 Jan 2011 05:47:10 -0000	1.5
+++ ChangeLog	23 Jan 2011 23:07:19 -0000	1.6
@@ -1,6 +1,11 @@
 # ChangeLog for net-misc/rygel
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/rygel/ChangeLog,v 1.5 2011/01/11 05:47:10 ford_prefect Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/rygel/ChangeLog,v 1.6 2011/01/23 23:07:19 eva Exp $
+
+*rygel-0.9.6 (23 Jan 2011)
+
+  23 Jan 2011; Gilles Dartiguelongue <eva@g.o> +rygel-0.9.6.ebuild:
+  Version bump. Port to gtk+:3.
 
   11 Jan 2011; Arun Raghavan <ford_prefect@g.o> rygel-0.8.2.ebuild,
   rygel-0.8.3.ebuild, rygel-0.9.1.ebuild:



1.1                  net-misc/rygel/rygel-0.9.6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/rygel/rygel-0.9.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/rygel/rygel-0.9.6.ebuild?rev=1.1&content-type=text/plain

Index: rygel-0.9.6.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/rygel/rygel-0.9.6.ebuild,v 1.1 2011/01/23 23:07:19 eva Exp $

EAPI="3"
GCONF_DEBUG="no"

inherit gnome2

DESCRIPTION="Rygel is an open source UPnP/DLNA MediaServer"
HOMEPAGE="http://live.gnome.org/Rygel"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="X nls +sqlite tracker transcode"

# The deps for tracker? and transcode? are just the earliest available
# version at the time of writing this ebuild
RDEPEND="
	>=dev-libs/glib-2.26:2
	>=dev-libs/libgee-0.5.2
	>=media-libs/gupnp-dlna-0.5
	>=media-libs/gstreamer-0.10.23
	>=media-libs/gst-plugins-base-0.10.28
	>=net-libs/gupnp-0.13.4
	>=net-libs/gupnp-av-0.7
	>=net-libs/libsoup-2.26:2.4
	>=sys-libs/e2fsprogs-libs-1.41.3
	sqlite? ( >=dev-db/sqlite-3.5:3 )
	tracker? ( >=app-misc/tracker-0.8.17 )
	transcode? (
		>=media-libs/gst-plugins-bad-0.10.14
		>=media-plugins/gst-plugins-twolame-0.10.12
		>=media-plugins/gst-plugins-ffmpeg-0.10.5
	)
	X? ( >=x11-libs/gtk+-2.90.3:3 )
"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	sys-devel/gettext
	dev-util/intltool
"
# Maintainer only
#	>=dev-lang/vala-0.11.2
#	>=net-libs/gupnp-vala-0.7.2
#   dev-libs/libxslt

DOCS="AUTHORS ChangeLog NEWS README TODO"

pkg_setup() {
	G2CONF="${G2CONF}
		--enable-gst-launch-plugin
		$(use_enable nls)
		$(use_enable sqlite media-export-plugin)
		$(use_enable tracker tracker-plugin)
		$(use_with X ui)"
}

src_install() {
	gnome2_src_install
	find "${ED}" -name "*.la" -delete || die
}