[gentoo-commits] repo/gentoo:master commit in: games-simulation/openrct2/

[Conrad Kostecki]

commit:     f19bb5750532f0f22eb03cb8d2c4f22491939be3
Author:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
AuthorDate: Mon Nov 22 21:14:10 2021 +0000
Commit:     Conrad Kostecki <conikost <AT> gentoo <DOT> org>
CommitDate: Mon Nov 22 21:14:10 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f19bb575

games-simulation/openrct2: add 0.3.5.1

Signed-off-by: Conrad Kostecki <conikost <AT> gentoo.org>

 games-simulation/openrct2/Manifest                |   1 +
 games-simulation/openrct2/openrct2-0.3.5.1.ebuild | 166 ++++++++++++++++++++++
 2 files changed, 167 insertions(+)

diff --git a/games-simulation/openrct2/Manifest b/games-simulation/openrct2/Manifest
index a009a3dfe4ee..2bd946f4a8dd 100644
--- a/games-simulation/openrct2/Manifest
+++ b/games-simulation/openrct2/Manifest
@@ -1,4 +1,5 @@
 DIST openrct2-0.3.4.1.tar.gz 14222683 BLAKE2B 170a3beef36f00c1ad7845d8005e0d1e84c9ea4585e650f6bd9bf5ef2cca721b4b274e1a12801d7273a03860eb4c6f564bed9003359f1f4faef7abbf6ab5a028 SHA512 23267ce782d491a042a1733694d4bcdefb9af8a03eb70e0b9f13a464411d238d6c6962dc3cf57275e1641095c4bb859698fd1dae80df5b757a6718d42e5da57f
+DIST openrct2-0.3.5.1.tar.gz 14178153 BLAKE2B a1f15fd427392195502e917f1fd4d8064a2905c1995c9e94157073c6acc026d1f716fb06294768630aa75d104d7c851388c72c38653e4804deeb8237b4a31c00 SHA512 0e36db302631b75aa1411eca945bddd1120997efbc48ba9172887f834670f34e345b8c96f363cdc8791d94bb4df32f6e70e30001989c194a8c525e2614241c84
 DIST openrct2-0.3.5.tar.gz 14179345 BLAKE2B fdba3d18bb6ab051e6612f9c1f1780c8d7c36f3566317cdd1c227617d86f2052b94407d2ae73102c2cab02337ed8c3f6d0456e577841ccee03405a3a67198bcf SHA512 036ad6f88ebe04673a55f679a8ac5e07600ec6e6ab6a2971e1ee9c378e779301084d0c4d134f664921c0cfc3ed222fed9a0e68e3f6ec3b493f6cc5bc745cea05
 DIST openrct2-objects-1.0.21.zip 3159059 BLAKE2B 9a42cddb02a0b5c476d5e84c5943d08190957567ea9cff44b0d4496f6a9ee9a548dd0a359e4a4dac21eacac9a074e25f7fc4ce1c37f4002dd5d35c61660e68c2 SHA512 b267db6542562c0c46c9964c865d33abff57d3d3c9a1f4073366f34cc229af2483a51538e56597d0e17ffdcd5bb1ba52ddc8198f8a0afaf0a30fdc2e00e6b3c0
 DIST openrct2-replays-0.0.43.zip 1669525 BLAKE2B 41b9b1accd877b98c7e244abfe799233e0bf75c14fa7e83e8c1fe996406303dec009c396345ec554a5ca1549172b1497e3adb5d038179c42ae1e719c9707567a SHA512 bed91fdfb7c67449f46effc7102ecfb46f3f5b43130cdbfc1343067a95a046714a0d2e9444b8059845c48bec5d0d4d8560ae7e3a3b6ec7182e7eff5bf40a5131

diff --git a/games-simulation/openrct2/openrct2-0.3.5.1.ebuild b/games-simulation/openrct2/openrct2-0.3.5.1.ebuild
new file mode 100644
index 000000000000..af9c013eb4ff
--- /dev/null
+++ b/games-simulation/openrct2/openrct2-0.3.5.1.ebuild
@@ -0,0 +1,166 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake readme.gentoo-r1 xdg-utils
+
+MY_PN="OpenRCT2"
+MY_PN_OBJ="objects"
+MY_PN_RPL="replays"
+MY_PN_TS="title-sequences"
+MY_PV_OBJ="1.0.21"
+MY_PV_RPL="0.0.57"
+MY_PV_TS="0.1.2c"
+
+DESCRIPTION="An open source re-implementation of Chris Sawyer's RollerCoaster Tycoon 2"
+HOMEPAGE="https://openrct2.org/"
+SRC_URI="
+	https://github.com/${MY_PN}/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
+	https://github.com/${MY_PN}/${MY_PN_OBJ}/releases/download/v${MY_PV_OBJ}/${MY_PN_OBJ}.zip -> ${PN}-${MY_PN_OBJ}-${MY_PV_OBJ}.zip
+	https://github.com/${MY_PN}/${MY_PN_TS}/releases/download/v${MY_PV_TS}/${MY_PN_TS}.zip -> ${PN}-${MY_PN_TS}-${MY_PV_TS}.zip
+	test? ( https://github.com/${MY_PN}/${MY_PN_RPL}/releases/download/v${MY_PV_RPL}/${MY_PN_RPL}.zip -> ${PN}-${MY_PN_RPL}-${MY_PV_RPL}.zip )
+"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="dedicated +lightfx +opengl scripting test +truetype"
+
+COMMON_DEPEND="
+	dev-libs/icu:=
+	dev-libs/jansson:=
+	dev-libs/libzip:=
+	media-libs/libpng:0=
+	net-misc/curl[ssl]
+	sys-libs/zlib
+	!dedicated? (
+		media-libs/libsdl2
+		media-libs/speexdsp
+		opengl? ( virtual/opengl )
+	)
+	dev-libs/openssl:0=
+	scripting? ( dev-lang/duktape:= )
+	truetype? (
+		media-libs/fontconfig:1.0
+		media-libs/freetype:2
+	)
+"
+
+RDEPEND="
+	${COMMON_DEPEND}
+	dedicated? (
+		acct-group/openrct2
+		acct-user/openrct2
+	)
+"
+
+DEPEND="
+	${COMMON_DEPEND}
+	dev-cpp/nlohmann_json
+	test? ( dev-cpp/gtest )
+"
+
+BDEPEND="
+	app-arch/unzip
+	virtual/pkgconfig
+"
+
+RESTRICT="!test? ( test )"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.2.4-include-additional-paths.patch"
+	"${FILESDIR}/${PN}-0.2.6-gtest-1.10.patch"
+)
+
+src_unpack() {
+	unpack "${P}".tar.gz
+
+	mkdir -p "${S}"/data/sequence || die
+	cd "${S}"/data/sequence || die
+	unpack "${PN}-${MY_PN_TS}-${MY_PV_TS}".zip
+
+	mkdir -p "${S}"/data/object || die
+	cd "${S}"/data/object || die
+	unpack "${PN}-${MY_PN_OBJ}-${MY_PV_OBJ}".zip
+
+	if use test; then
+		mkdir -p "${S}"/testdata/replays || die
+		cd "${S}"/testdata/replays || die
+		unpack "${PN}-${MY_PN_RPL}-${MY_PV_RPL}".zip
+	fi
+}
+
+src_prepare() {
+	cmake_src_prepare
+
+	# Don't treat warnings as errors.
+	sed -e 's/-Werror//' -i CMakeLists.txt || die
+}
+
+src_configure() {
+	# Note: There is currently no support for Disord-RPC and Google Benchmark,
+	# as both packages do not exist in Gentoo, so support for them has been disabled.
+	local mycmakeargs=(
+		-DDISABLE_DISCORD_RPC=ON
+		-DDISABLE_GOOGLE_BENCHMARK=ON
+		-DDISABLE_GUI=$(usex dedicated)
+		-DDISABLE_HTTP=OFF
+		-DDISABLE_NETWORK=OFF
+		$(usex !dedicated "-DDISABLE_OPENGL=$(usex !opengl)" "")
+		-DDISABLE_TTF=$(usex !truetype)
+		-DDOWNLOAD_OBJECTS=OFF
+		-DDOWNLOAD_REPLAYS=OFF
+		-DDOWNLOAD_TITLE_SEQUENCES=OFF
+		-DENABLE_LIGHTFX=$(usex lightfx)
+		-DENABLE_SCRIPTING=$(usex scripting)
+		-DOPENRCT2_USE_CCACHE=OFF
+		-DPORTABLE=OFF
+		-DSTATIC=OFF
+		$(usex test "-DSYSTEM_GTEST=ON" "")
+		-DWITH_TESTS=$(usex test)
+		-DUSE_MMAP=ON
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	# Since the tests need the OpenRCT2 data,
+	# we need to symlink them into the build directory,
+	# otherwise some tests will fail, as they don't find the OpenRCT2 data.
+	# It is currently not possible to override that path.
+	# See: https://github.com/OpenRCT2/OpenRCT2/issues/6473
+	ln -s "${S}"/data "${BUILD_DIR}" || die
+
+	cmake_src_test
+}
+
+src_install() {
+	use scripting && DOCS+=( "distribution/scripting.md" "distribution/openrct2.d.ts" )
+
+	cmake_src_install
+
+	if use dedicated; then
+		newinitd "${FILESDIR}"/openrct2.initd openrct2
+		newconfd "${FILESDIR}"/openrct2.confd openrct2
+	fi
+
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}