[gentoo-commits] gentoo-x86 commit in x11-libs/libdrm: libdrm-2.4.46.ebuild ChangeLog

[Chi-Thanh Christopher Nguyen (chithanh)]

chithanh    13/07/02 21:49:21

  Modified:             ChangeLog
  Added:                libdrm-2.4.46.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.1.12.2/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.234                x11-libs/libdrm/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libdrm/ChangeLog?rev=1.234&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libdrm/ChangeLog?rev=1.234&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libdrm/ChangeLog?r1=1.233&r2=1.234

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-libs/libdrm/ChangeLog,v
retrieving revision 1.233
retrieving revision 1.234
diff -u -r1.233 -r1.234
--- ChangeLog	9 Jun 2013 16:00:15 -0000	1.233
+++ ChangeLog	2 Jul 2013 21:49:21 -0000	1.234
@@ -1,6 +1,12 @@
 # ChangeLog for x11-libs/libdrm
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-libs/libdrm/ChangeLog,v 1.233 2013/06/09 16:00:15 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/libdrm/ChangeLog,v 1.234 2013/07/02 21:49:21 chithanh Exp $
+
+*libdrm-2.4.46 (02 Jul 2013)
+
+  02 Jul 2013; Chí-Thanh Christopher Nguyễn <chithanh@g.o>
+  +libdrm-2.4.46.ebuild:
+  Version bump.
 
   09 Jun 2013; Agostino Sarubbo <ago@g.o> libdrm-2.4.45.ebuild:
   Stable for sh, wrt bug #463430



1.1                  x11-libs/libdrm/libdrm-2.4.46.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libdrm/libdrm-2.4.46.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-libs/libdrm/libdrm-2.4.46.ebuild?rev=1.1&content-type=text/plain

Index: libdrm-2.4.46.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-libs/libdrm/libdrm-2.4.46.ebuild,v 1.1 2013/07/02 21:49:21 chithanh Exp $

EAPI=5
inherit xorg-2

EGIT_REPO_URI="git://anongit.freedesktop.org/git/mesa/drm"

DESCRIPTION="X.Org libdrm library"
HOMEPAGE="http://dri.freedesktop.org/"
if [[ ${PV} = 9999* ]]; then
	SRC_URI=""
else
	SRC_URI="http://dri.freedesktop.org/${PN}/${P}.tar.bz2"
fi

KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~amd64-linux ~arm-linux ~x86-linux ~sparc-solaris ~x64-solaris ~x86-solaris"
VIDEO_CARDS="exynos freedreno intel nouveau omap radeon vmware"
for card in ${VIDEO_CARDS}; do
	IUSE_VIDEO_CARDS+=" video_cards_${card}"
done

IUSE="${IUSE_VIDEO_CARDS} libkms"
REQUIRED_USE="video_cards_exynos? ( libkms )"
RESTRICT="test" # see bug #236845

RDEPEND="dev-libs/libpthread-stubs
	video_cards_intel? ( >=x11-libs/libpciaccess-0.10 )"
DEPEND="${RDEPEND}"

PATCHES=(
	"${FILESDIR}"/${PN}-2.4.28-solaris.patch
)

src_prepare() {
	if [[ ${PV} = 9999* ]]; then
		# tests are restricted, no point in building them
		sed -ie 's/tests //' "${S}"/Makefile.am
	fi
	xorg-2_src_prepare
}

src_configure() {
	XORG_CONFIGURE_OPTIONS=(
		--enable-udev
		$(use_enable video_cards_exynos exynos-experimental-api)
		$(use_enable video_cards_freedreno freedreno-experimental-api)
		$(use_enable video_cards_intel intel)
		$(use_enable video_cards_nouveau nouveau)
		$(use_enable video_cards_omap omap-experimental-api)
		$(use_enable video_cards_radeon radeon)
		$(use_enable video_cards_vmware vmwgfx)
		$(use_enable libkms)
	)
	xorg-2_src_configure
}