[gentoo-commits] repo/gentoo:master commit in: sys-libs/pam/

[Mikle Kolyada]

commit:     0f4ede808390a021c78e5fac6d62f44f88727cf6
Author:     Mikle Kolyada <zlogene <AT> gentoo <DOT> org>
AuthorDate: Sun Nov 18 18:23:54 2018 +0000
Commit:     Mikle Kolyada <zlogene <AT> gentoo <DOT> org>
CommitDate: Sun Nov 18 18:24:10 2018 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0f4ede80

sys-libs/pam: Drop old

Signed-off-by: Mikle Kolyada <zlogene <AT> gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11

 sys-libs/pam/pam-1.3.1.ebuild | 126 ------------------------------------------
 1 file changed, 126 deletions(-)

diff --git a/sys-libs/pam/pam-1.3.1.ebuild b/sys-libs/pam/pam-1.3.1.ebuild
deleted file mode 100644
index 75f1b0b62cf..00000000000
--- a/sys-libs/pam/pam-1.3.1.ebuild
+++ /dev/null
@@ -1,126 +0,0 @@
-# Copyright 1999-2018 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-inherit autotools db-use fcaps multilib-minimal toolchain-funcs
-
-DESCRIPTION="Linux-PAM (Pluggable Authentication Modules)"
-HOMEPAGE="https://github.com/linux-pam/linux-pam"
-SRC_URI="https://github.com/linux-pam/linux-pam/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="|| ( BSD GPL-2 )"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux"
-IUSE="audit berkdb +cracklib debug nis nls +pie selinux static-libs"
-
-DEPEND="app-text/docbook-xml-dtd:4.3
-	app-text/docbook-xml-dtd:4.4
-	app-text/docbook-xml-dtd:4.5
-	nls? ( sys-devel/gettext )"
-
-RDEPEND="${DEPEND}
-	audit? ( >=sys-process/audit-2.2.2[${MULTILIB_USEDEP}] )
-	berkdb? ( >=sys-libs/db-4.8.30-r1:=[${MULTILIB_USEDEP}] )
-	cracklib? ( >=sys-libs/cracklib-2.9.1-r1[${MULTILIB_USEDEP}] )
-	selinux? ( >=sys-libs/libselinux-2.2.2-r4[${MULTILIB_USEDEP}] )
-	nis? ( >=net-libs/libtirpc-0.2.4-r2[${MULTILIB_USEDEP}] )
-	nls? ( >=virtual/libintl-0-r1[${MULTILIB_USEDEP}] )
-	!<sys-apps/openrc-0.11.8
-	!sys-auth/openpam
-	!sys-auth/pam_userdb"
-
-BDEPEND="virtual/pkgconfig"
-
-PDEPEND="sys-auth/pambase"
-
-S="${WORKDIR}/linux-${P}"
-
-src_prepare() {
-	default
-	eapply "${FILESDIR}/${PN}-remove-browsers.patch"
-	touch ChangeLog || die
-	eautoreconf
-}
-
-multilib_src_configure() {
-	# Do not let user's BROWSER setting mess us up. #549684
-	unset BROWSER
-
-	# Disable automatic detection of libxcrypt; we _don't_ want the
-	# user to link libxcrypt in by default, since we won't track the
-	# dependency and allow to break PAM this way.
-
-	export ac_cv_header_xcrypt_h=no
-
-	local myconf=(
-		--with-db-uniquename=-$(db_findver sys-libs/db)
-		--enable-securedir="${EPREFIX}"/$(get_libdir)/security
-		--libdir=/usr/$(get_libdir)
-		--disable-prelude
-		$(use_enable audit)
-		$(use_enable berkdb db)
-		$(use_enable cracklib)
-		$(use_enable debug)
-		$(use_enable nis)
-		$(use_enable nls)
-		$(use_enable pie)
-		$(use_enable selinux)
-		$(use_enable static-libs static)
-		--enable-isadir='.' #464016
-		)
-	ECONF_SOURCE="${S}" econf ${myconf[@]}
-}
-
-multilib_src_compile() {
-	emake sepermitlockdir="${EPREFIX}/run/sepermit"
-}
-
-multilib_src_install() {
-	emake DESTDIR="${D}" install \
-		sepermitlockdir="${EPREFIX}/run/sepermit"
-
-	local prefix
-	if multilib_is_native_abi; then
-		prefix=
-		gen_usr_ldscript -a pam pamc pam_misc
-	else
-		prefix=/usr
-	fi
-
-	# create extra symlinks just in case something depends on them...
-	local lib
-	for lib in pam pamc pam_misc; do
-		if ! [[ -f "${ED}"${prefix}/$(get_libdir)/lib${lib}$(get_libname) ]]; then
-			dosym lib${lib}$(get_libname 0) ${prefix}/$(get_libdir)/lib${lib}$(get_libname)
-		fi
-	done
-}
-
-multilib_src_install_all() {
-	find "${ED}" -type f -name '*.la' -delete || die
-
-	if use selinux; then
-		dodir /usr/lib/tmpfiles.d
-		cat - > "${D}"/usr/lib/tmpfiles.d/${CATEGORY}:${PN}:${SLOT}.conf <<EOF
-d /run/sepermit 0755 root root
-EOF
-	fi
-}
-
-pkg_postinst() {
-	ewarn "Some software with pre-loaded PAM libraries might experience"
-	ewarn "warnings or failures related to missing symbols and/or versions"
-	ewarn "after any update. While unfortunate this is a limit of the"
-	ewarn "implementation of PAM and the software, and it requires you to"
-	ewarn "restart the software manually after the update."
-	ewarn ""
-	ewarn "You can get a list of such software running a command like"
-	ewarn "  lsof / | egrep -i 'del.*libpam\\.so'"
-	ewarn ""
-	ewarn "Alternatively, simply reboot your system."
-
-	# The pam_unix module needs to check the password of the user which requires
-	# read access to /etc/shadow only.
-	fcaps cap_dac_override sbin/unix_chkpwd
-}