[gentoo-commits] repo/gentoo:master commit in: sys-apps/tomoyo-tools/

[Jakov Smolić]

commit:     b5c1bb58b6a37d92139d65b364f3ccd3e2a98392
Author:     Jakov Smolić <jsmolic <AT> gentoo <DOT> org>
AuthorDate: Fri Nov  5 18:29:27 2021 +0000
Commit:     Jakov Smolić <jsmolic <AT> gentoo <DOT> org>
CommitDate: Sat Nov  6 20:32:53 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b5c1bb58

sys-apps/tomoyo-tools: Port to EAPI 8

Closes: https://bugs.gentoo.org/819240
Signed-off-by: Jakov Smolić <jsmolic <AT> gentoo.org>

 .../tomoyo-tools-2.5.0_p20130214-r1.ebuild         | 26 ++++++++++++----------
 1 file changed, 14 insertions(+), 12 deletions(-)

diff --git a/sys-apps/tomoyo-tools/tomoyo-tools-2.5.0_p20130214-r1.ebuild b/sys-apps/tomoyo-tools/tomoyo-tools-2.5.0_p20130214-r1.ebuild
index e8e373515d0..025594e4dd3 100644
--- a/sys-apps/tomoyo-tools/tomoyo-tools-2.5.0_p20130214-r1.ebuild
+++ b/sys-apps/tomoyo-tools/tomoyo-tools-2.5.0_p20130214-r1.ebuild
@@ -1,29 +1,31 @@
 # Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
+EAPI=8
 
-inherit epatch multilib toolchain-funcs
+inherit toolchain-funcs
 
 MY_P="${P/_p/-}"
 DESCRIPTION="TOMOYO Linux tools"
 HOMEPAGE="http://tomoyo.sourceforge.jp/"
 SRC_URI="mirror://sourceforge.jp/tomoyo/53357/${MY_P}.tar.gz"
+S="${WORKDIR}/${PN}"
 
 LICENSE="GPL-2"
 SLOT="0"
 KEYWORDS="~amd64 ~x86"
 
-COMMON_DEPEND="sys-libs/ncurses:="
-DEPEND="${COMMON_DEPEND}
-	virtual/pkgconfig"
-RDEPEND="${COMMON_DEPEND}
+DEPEND="sys-libs/ncurses:="
+RDEPEND="${DEPEND}
 	!sys-apps/ccs-tools"
+BDEPEND="virtual/pkgconfig"
 
-S="${WORKDIR}/${PN}"
+PATCHES=(
+	"${FILESDIR}"/${P}-warnings.patch
+)
 
 src_prepare() {
-	epatch "${FILESDIR}"/${P}-warnings.patch
+	default
 
 	# Fix libdir
 	sed -i \
@@ -35,8 +37,6 @@ src_prepare() {
 		-e 's|-lncurses|$(shell ${PKG_CONFIG} --libs ncurses)|g' \
 		usr_sbin/Makefile || die
 
-	echo "CONFIG_PROTECT=\"/usr/$(get_libdir)/tomoyo/conf\"" > "${T}/50${PN}"
-
 	tc-export CC PKG_CONFIG
 }
 
@@ -45,10 +45,12 @@ src_install() {
 
 	emake INSTALLDIR="${D}" install
 
-	doenvd "${T}/50${PN}"
+	newenvd - 50${PN} <<- _EOF_
+		CONFIG_PROTECT=/usr/$(get_libdir)/tomoyo/conf
+	_EOF_
 
 	# Fix out-of-place readme and license
-	rm "${D}"/usr/$(get_libdir)/tomoyo/{COPYING.tomoyo,README.tomoyo} || die
+	rm "${ED}"/usr/$(get_libdir)/tomoyo/{COPYING.tomoyo,README.tomoyo} || die
 	dodoc README.tomoyo
 }