[gentoo-commits] gentoo-x86 commit in sys-power/acpid: acpid-2.0.23.ebuild ChangeLog

[Samuli Suominen (ssuominen)]

ssuominen    14/08/24 09:04:35

  Modified:             ChangeLog
  Added:                acpid-2.0.23.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

Revision  Changes    Path
1.119                sys-power/acpid/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/acpid/ChangeLog?rev=1.119&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/acpid/ChangeLog?rev=1.119&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/acpid/ChangeLog?r1=1.118&r2=1.119

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-power/acpid/ChangeLog,v
retrieving revision 1.118
retrieving revision 1.119
diff -u -r1.118 -r1.119
--- ChangeLog	21 Jul 2014 19:38:08 -0000	1.118
+++ ChangeLog	24 Aug 2014 09:04:35 -0000	1.119
@@ -1,6 +1,11 @@
 # ChangeLog for sys-power/acpid
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-power/acpid/ChangeLog,v 1.118 2014/07/21 19:38:08 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-power/acpid/ChangeLog,v 1.119 2014/08/24 09:04:35 ssuominen Exp $
+
+*acpid-2.0.23 (24 Aug 2014)
+
+  24 Aug 2014; Samuli Suominen <ssuominen@g.o> +acpid-2.0.23.ebuild:
+  Version bump.
 
   21 Jul 2014; Samuli Suominen <ssuominen@g.o> acpid-2.0.22.ebuild:
   Check for CONFIG_INPUT_EVDEV wrt #508460 by Thomas D.



1.1                  sys-power/acpid/acpid-2.0.23.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/acpid/acpid-2.0.23.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/acpid/acpid-2.0.23.ebuild?rev=1.1&content-type=text/plain

Index: acpid-2.0.23.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-power/acpid/acpid-2.0.23.ebuild,v 1.1 2014/08/24 09:04:35 ssuominen Exp $

EAPI=5
inherit linux-info systemd

DESCRIPTION="Daemon for Advanced Configuration and Power Interface"
HOMEPAGE="http://sourceforge.net/projects/acpid2"
SRC_URI="mirror://sourceforge/${PN}2/${P}.tar.xz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ia64 -ppc ~x86"
IUSE="selinux"

RDEPEND="selinux? ( sec-policy/selinux-apm )"
DEPEND="${RDEPEND}
	    >=sys-kernel/linux-headers-3"

pkg_pretend() {
	local CONFIG_CHECK="~INPUT_EVDEV"
	local WARNING_INPUT_EVDEV="CONFIG_INPUT_EVDEV is required for ACPI button event support."
	[[ ${MERGE_TYPE} != buildonly ]] && check_extra_config
}

pkg_setup() { :; }

src_configure() {
	econf --docdir=/usr/share/doc/${PF}
}

src_install() {
	emake DESTDIR="${D}" install

	newdoc kacpimon/README README.kacpimon
	dodoc -r samples
	rm -f "${D}"/usr/share/doc/${PF}/COPYING || die

	exeinto /etc/acpi
	newexe "${FILESDIR}"/${PN}-1.0.6-default.sh default.sh
	exeinto /etc/acpi/actions
	newexe samples/powerbtn/powerbtn.sh powerbtn.sh
	insinto /etc/acpi/events
	newins "${FILESDIR}"/${PN}-1.0.4-default default

	newinitd "${FILESDIR}"/${PN}-2.0.16-init.d ${PN}
	newconfd "${FILESDIR}"/${PN}-2.0.16-conf.d ${PN}

	systemd_dounit "${FILESDIR}"/systemd/${PN}.{service,socket}
}

pkg_postinst() {
	if [[ -z ${REPLACING_VERSIONS} ]]; then
		elog
		elog "You may wish to read the Gentoo Linux Power Management Guide,"
		elog "which can be found online at:"
		elog "http://www.gentoo.org/doc/en/power-management-guide.xml"
		elog
	fi

	# files/systemd/acpid.socket -> ListenStream=/run/acpid.socket
	mkdir -p "${ROOT%/}"/run

	if ! grep -qs "^tmpfs.*/run " "${ROOT%/}"/proc/mounts ; then
		echo
		ewarn "You should reboot the system now to get /run mounted with tmpfs!"
	fi
}