[gentoo-commits] repo/gentoo:master commit in: sys-kernel/gentoo-kernel-bin/

[Sam James]

commit:     9e1955f89c30895b4ff95669da988818e2966822
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Wed Oct 13 03:43:51 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Wed Oct 13 03:43:58 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9e1955f8

sys-kernel/gentoo-kernel-bin: add 5.14.11-r1 for arm64

Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-kernel/gentoo-kernel-bin/Manifest              |   1 +
 .../gentoo-kernel-bin-5.14.11-r1.ebuild            | 113 +++++++++++++++++++++
 2 files changed, 114 insertions(+)

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 5e1e883a61f..1741672624d 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -52,6 +52,7 @@ DIST gentoo-kernel-5.14.10-1.amd64.xpak 68081742 BLAKE2B b2b443d53ddfc3ef45133a3
 DIST gentoo-kernel-5.14.10-1.arm64.xpak 63345321 BLAKE2B 6c1dcbad9d5311a20645072383f0ac845c91b137974fe423d8ea1d2e2c33eb2218b5099f0a35a68321a86ed06fb9609c93b75981ba8401433a8f80d1149ba67e SHA512 386e481acc70d160ff7283ddbc48915278e900350111f94241f164530229ca52e77219706825dc66d02a1bc521d79c1d5172bf78aae04720e5e42446487b06b0
 DIST gentoo-kernel-5.14.10-1.x86.xpak 59178806 BLAKE2B 10a6f1e987b859ca3f1b904b521b8ebf7e7139883d5686559e9f3e3e18fe14bc259632f54ea14057d1659b4c92915e4032f0f0c4dbdd15c38698f7efe19a137e SHA512 f6c5c8dd1f1dfa17bd43a38f90e4d31554c232a71b6d2b5e4d9a2a33aac311b924db84827d6fd4f95f73e6b7000e8958e346347f6e4f99301fc9e71ced86cad2
 DIST gentoo-kernel-5.14.11-1.amd64.xpak 68067146 BLAKE2B 8ce01c1f9003c298f262c23db11d837955dad760ac1fd39d9cb857500b64ce55c4a7b71823d3eff4443721e2430ca4966a304bd35023fba574de6ddc8ddd2cfd SHA512 2efe779c30023c4177b0f5d9d868f97018f887122d16a87a43ac5c32ce73b41b75838cb0d270930fe87cef788b9d1c9af7dc9e60e3ae4583b827105403beb393
+DIST gentoo-kernel-5.14.11-1.arm64.xpak 63292538 BLAKE2B a4e485ebd2c1e757fabf159d676b52dbdb8be4ff3613ef1c4be4dff1cdcc928fbcaa2e7b223ed906b76d6eac559930a8da9b48c25b927b7d82ca5c5eeb0a31fe SHA512 fd2a6c74f35d9ac4843be51a8cb015af65cff36b7479b09e861fc5eae5333327792e8b4c013809e2880c7386ff00221fff02647b059842ae0b178b585c9f3ca7
 DIST gentoo-kernel-5.14.11-1.x86.xpak 59165591 BLAKE2B 870935f0eddc88cb23aac651f92663a963e148a3c526bd30daa17ed3b63175c16553e8a8fc7edb7a728859d436199a12cf4bc230490805b0342de1a4a0033e39 SHA512 0ddd7b81473cb552ffd1bb20fee14191cff033145fac4ce1d6688a674db2e3f401c851021c2d39fdb05ef1b034a210adae8196c718220fc8d38508bfac1102c8
 DIST gentoo-kernel-5.14.7-1.amd64.xpak 68031586 BLAKE2B 7cc01200f01a93daf5f0c84b09e066474dc5dcef76ddadf5e43843a3bb8a69710134ee9546cbfc6da0149b96e480d59cc0ceb610608c7e6710dccbb9e9e185f2 SHA512 595ce0155ef9df5809d7c27ee310d3978bde477e6778468f467c9f07a60c43dd7ce6e39320d3e298639f01c18cfed5811de480d0afd884586d13f434c533fe6b
 DIST gentoo-kernel-5.14.7-1.arm64.xpak 63383693 BLAKE2B d8780cdd6306f36530d82b9a5b6a74e1d2caf9c4e9db31d6816020bc9415fe92891e418dd08f89628f3d36189c84f97c10b570091c2d1a94a494f37a21286706 SHA512 90ef111ef0ef68dd362c458c9e6ea15959713118787ebd8c68492bd204da83a212e5def456fd550c3f175565c262581855599adeb34692c65f54c2f2d7f1d06c

diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.14.11-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.14.11-r1.ebuild
new file mode 100644
index 00000000000..c4534b7e4c4
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.14.11-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 1 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+		-> ${BINPKG}.arm64.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}