[gentoo-commits] gentoo-x86 commit in net-wireless/aircrack-ng: aircrack-ng-1.2_beta3-r3.ebuild aircrack-ng-9999.ebuild ChangeLog aircrack-ng-1.2_beta3-r2.ebuild

[Richard Farina (zerochaos)]

zerochaos    14/08/03 23:13:27

  Modified:             aircrack-ng-9999.ebuild ChangeLog
  Added:                aircrack-ng-1.2_beta3-r3.ebuild
  Removed:              aircrack-ng-1.2_beta3-r2.ebuild
  Log:
  snapshot to fix some issues
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key DD11F94A)

Revision  Changes    Path
1.11                 net-wireless/aircrack-ng/aircrack-ng-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/aircrack-ng/aircrack-ng-9999.ebuild?rev=1.11&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/aircrack-ng/aircrack-ng-9999.ebuild?rev=1.11&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/aircrack-ng/aircrack-ng-9999.ebuild?r1=1.10&r2=1.11

Index: aircrack-ng-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-wireless/aircrack-ng/aircrack-ng-9999.ebuild,v
retrieving revision 1.10
retrieving revision 1.11
diff -u -r1.10 -r1.11
--- aircrack-ng-9999.ebuild	18 Jul 2014 03:41:02 -0000	1.10
+++ aircrack-ng-9999.ebuild	3 Aug 2014 23:13:27 -0000	1.11
@@ -1,6 +1,6 @@
 # Copyright 1999-2014 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-wireless/aircrack-ng/aircrack-ng-9999.ebuild,v 1.10 2014/07/18 03:41:02 zerochaos Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/aircrack-ng/aircrack-ng-9999.ebuild,v 1.11 2014/08/03 23:13:27 zerochaos Exp $
 
 EAPI="5"
 
@@ -58,7 +58,6 @@
 		liveflags=REVFLAGS=-D_REVISION="${ESVN_WC_REVISION}"
 	fi
 
-	replace-flags -Os -O2
 	emake \
 	CC="$(tc-getCC)" \
 	AR="$(tc-getAR)" \



1.84                 net-wireless/aircrack-ng/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/aircrack-ng/ChangeLog?rev=1.84&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/aircrack-ng/ChangeLog?rev=1.84&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/aircrack-ng/ChangeLog?r1=1.83&r2=1.84

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-wireless/aircrack-ng/ChangeLog,v
retrieving revision 1.83
retrieving revision 1.84
diff -u -r1.83 -r1.84
--- ChangeLog	18 Jul 2014 03:41:02 -0000	1.83
+++ ChangeLog	3 Aug 2014 23:13:27 -0000	1.84
@@ -1,6 +1,13 @@
 # ChangeLog for net-wireless/aircrack-ng
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-wireless/aircrack-ng/ChangeLog,v 1.83 2014/07/18 03:41:02 zerochaos Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/aircrack-ng/ChangeLog,v 1.84 2014/08/03 23:13:27 zerochaos Exp $
+
+*aircrack-ng-1.2_beta3-r3 (03 Aug 2014)
+
+  03 Aug 2014; Rick Farina <zerochaos@g.o>
+  +aircrack-ng-1.2_beta3-r3.ebuild, -aircrack-ng-1.2_beta3-r2.ebuild,
+  aircrack-ng-9999.ebuild:
+  snapshot to fix some issues
 
 *aircrack-ng-1.2_beta3-r2 (18 Jul 2014)
 



1.1                  net-wireless/aircrack-ng/aircrack-ng-1.2_beta3-r3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/aircrack-ng/aircrack-ng-1.2_beta3-r3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/aircrack-ng/aircrack-ng-1.2_beta3-r3.ebuild?rev=1.1&content-type=text/plain

Index: aircrack-ng-1.2_beta3-r3.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-wireless/aircrack-ng/aircrack-ng-1.2_beta3-r3.ebuild,v 1.1 2014/08/03 23:13:27 zerochaos Exp $

EAPI="5"

PYTHON_COMPAT=( python2_7 )
DISTUTILS_OPTIONAL=1

inherit toolchain-funcs distutils-r1 flag-o-matic

DESCRIPTION="WLAN tools for breaking 802.11 WEP/WPA keys"
HOMEPAGE="http://www.aircrack-ng.org"

if [[ ${PV} == "9999" ]] ; then
	inherit subversion
	ESVN_REPO_URI="http://svn.aircrack-ng.org/trunk"
	KEYWORDS=""
	S="${WORKDIR}/${PN}"
else
	SRC_URI="http://dev.gentoo.org/~zerochaos/distfiles/${PN}-${PV}_p20140803.tar.xz"
	KEYWORDS="~amd64 ~arm ~ppc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
fi

LICENSE="GPL-2"
SLOT="0"

IUSE="+airdrop-ng +airgraph-ng kernel_linux kernel_FreeBSD +netlink +pcre +sqlite +unstable"

DEPEND="dev-libs/openssl
	netlink? ( dev-libs/libnl:3 )
	pcre? ( dev-libs/libpcre )
	airdrop-ng? ( ${PYTHON_DEPS} )
	airgraph-ng? ( ${PYTHON_DEPS} )
	sqlite? ( >=dev-db/sqlite-3.4 )"
RDEPEND="${DEPEND}
	kernel_linux? (
		net-wireless/iw
		net-wireless/wireless-tools
		sys-apps/ethtool
		sys-apps/usbutils
		sys-apps/pciutils )
	sys-apps/hwids
	airdrop-ng? ( net-wireless/lorcon[python,${PYTHON_USEDEP}] )"

REQUIRED_USE="airdrop-ng? ( ${PYTHON_REQUIRED_USE} )
		airgraph-ng? ( ${PYTHON_REQUIRED_USE} )"

src_compile() {
	if [[ $($(tc-getCC) --version) == clang* ]] ; then
		die "Please use gcc, upstream bug http://trac.aircrack-ng.org/ticket/1144"
	fi

	if [[ ${PV} == "9999" ]] ; then
		liveflags=REVFLAGS=-D_REVISION="${ESVN_WC_REVISION}"
	fi

	emake \
	CC="$(tc-getCC)" \
	AR="$(tc-getAR)" \
	LD="$(tc-getLD)" \
	RANLIB="$(tc-getRANLIB)" \
	libnl=$(usex netlink true false) \
	pcre=$(usex pcre true false) \
	sqlite=$(usex sqlite true false) \
	unstable=$(usex unstable true false) \
	${liveflags}

	if use airgraph-ng; then
		cd "${S}/scripts/airgraph-ng"
		distutils-r1_src_compile
	fi
	if use airdrop-ng; then
		cd "${S}/scripts/airdrop-ng"
		distutils-r1_src_compile
	fi
}

src_test() {
	if [[ ${PV} == "9999" ]] ; then
		liveflags=REVFLAGS=-D_REVISION="${ESVN_WC_REVISION}"
	fi

	emake check \
		libnl=$(usex netlink true false) \
		pcre=$(usex pcre true false) \
		sqlite=$(usex sqlite true false) \
		unstable=$(usex unstable true false) \
		${liveflags}
}

src_install() {
	if [[ ${PV} == "9999" ]] ; then
		liveflags=REVFLAGS=-D_REVISION="${ESVN_WC_REVISION}"
	fi

	emake \
		prefix="${ED}/usr" \
		libnl=$(usex netlink true false) \
		pcre=$(usex pcre true false) \
		sqlite=$(usex sqlite true false) \
		unstable=$(usex unstable true false) \
		${liveflags} \
		install

	dodoc AUTHORS ChangeLog INSTALLING README

	if use airgraph-ng; then
		cd "${S}/scripts/airgraph-ng"
		distutils-r1_src_install
	fi
	if use airdrop-ng; then
		cd "${S}/scripts/airdrop-ng"
		distutils-r1_src_install
	fi

	#we don't need aircrack-ng's oui updater, we have our own
	rm "${ED}"/usr/sbin/airodump-ng-oui-update
}

pkg_postinst() {
	# Message is (c) FreeBSD
	# http://www.freebsd.org/cgi/cvsweb.cgi/ports/net-mgmt/aircrack-ng/files/pkg-message.in?rev=1.5
	if use kernel_FreeBSD ; then
		einfo "Contrary to Linux, it is not necessary to use airmon-ng to enable the monitor"
		einfo "mode of your wireless card.  So do not care about what the manpages say about"
		einfo "airmon-ng, airodump-ng sets monitor mode automatically."
		echo
		einfo "To return from monitor mode, issue the following command:"
		einfo "    ifconfig \${INTERFACE} -mediaopt monitor"
		einfo
		einfo "For aireplay-ng you need FreeBSD >= 7.0."
	fi
}