[gentoo-commits] gentoo-x86 commit in x11-terms/roxterm: ChangeLog roxterm-2.3.4.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    11/12/30 13:57:20

  Modified:             ChangeLog
  Added:                roxterm-2.3.4.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha81/cvs/Linux x86_64)

Revision  Changes    Path
1.55                 x11-terms/roxterm/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/roxterm/ChangeLog?rev=1.55&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/roxterm/ChangeLog?rev=1.55&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/roxterm/ChangeLog?r1=1.54&r2=1.55

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-terms/roxterm/ChangeLog,v
retrieving revision 1.54
retrieving revision 1.55
diff -u -r1.54 -r1.55
--- ChangeLog	6 Dec 2011 05:37:37 -0000	1.54
+++ ChangeLog	30 Dec 2011 13:57:20 -0000	1.55
@@ -1,6 +1,11 @@
 # ChangeLog for x11-terms/roxterm
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-terms/roxterm/ChangeLog,v 1.54 2011/12/06 05:37:37 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-terms/roxterm/ChangeLog,v 1.55 2011/12/30 13:57:20 ssuominen Exp $
+
+*roxterm-2.3.4 (30 Dec 2011)
+
+  30 Dec 2011; Samuli Suominen <ssuominen@g.o> +roxterm-2.3.4.ebuild:
+  Version bump.
 
 *roxterm-2.3.1 (06 Dec 2011)
 



1.1                  x11-terms/roxterm/roxterm-2.3.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/roxterm/roxterm-2.3.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-terms/roxterm/roxterm-2.3.4.ebuild?rev=1.1&content-type=text/plain

Index: roxterm-2.3.4.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-terms/roxterm/roxterm-2.3.4.ebuild,v 1.1 2011/12/30 13:57:20 ssuominen Exp $

EAPI=4
PYTHON_DEPEND="2:2.6"
inherit gnome2-utils python

DESCRIPTION="A terminal emulator designed to integrate with the ROX environment"
HOMEPAGE="http://roxterm.sourceforge.net/"
SRC_URI="mirror://sourceforge/roxterm/${P}.tar.bz2"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="nls"

RDEPEND="dev-libs/dbus-glib
	>=dev-libs/glib-2.16
	x11-libs/gtk+:3
	x11-libs/libICE
	x11-libs/libSM
	x11-libs/vte:2.90"
DEPEND="${RDEPEND}
	dev-libs/libxslt
	dev-util/pkgconfig
	dev-python/lockfile
	|| ( media-gfx/imagemagick media-gfx/graphicsmagick[imagemagick] )
	nls? ( app-text/po4a sys-devel/gettext )"

pkg_setup() {
	python_set_active_version 2
	python_pkg_setup
}

src_prepare() {
	python_convert_shebangs 2 mscript.py

	# build system is crap
	sed -i -e 's:TerminalEmulator:System;&:' roxterm.desktop || die
	sed -i -e '/ctx.install_doc/s:COPYING ::' mscript.py || die
	sed -i -e "/CFLAGS/s:-O2 -g:${CFLAGS}:" {maitch,mscript}.py || die
	sed -i \
		-e "/LDFLAGS/s:'':'${LDFLAGS}':" \
		-e 's:--mode=link:--mode=link --tag=CC:' \
		maitch.py || die
}

src_configure() {
	local myconf=( --prefix=/usr --docdir=/usr/share/doc/${PF} --destdir="${D}" )
	use nls || myconf+=( --disable-gettext --disable-po4a --disable-translations )
	./mscript.py configure "${myconf[@]}"
}

src_compile() { ./mscript.py build; }
src_install() { ./mscript.py install; }
pkg_preinst() { gnome2_icon_savelist; }
pkg_postinst() { gnome2_icon_cache_update; }
pkg_postrm() { gnome2_icon_cache_update; }