[gentoo-commits] repo/gentoo:master commit in: x11-misc/autorandr/

[Florian Schmaus]

commit:     069a2651e71face888b8de57af7808a04c9095e2
Author:     Florian Schmaus <flow <AT> gentoo <DOT> org>
AuthorDate: Wed Nov 30 09:20:50 2022 +0000
Commit:     Florian Schmaus <flow <AT> gentoo <DOT> org>
CommitDate: Wed Nov 30 09:39:35 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=069a2651

x11-misc/autorandr: drop 1.12.1

Signed-off-by: Florian Schmaus <flow <AT> gentoo.org>

 x11-misc/autorandr/autorandr-1.12.1.ebuild | 65 ------------------------------
 1 file changed, 65 deletions(-)

diff --git a/x11-misc/autorandr/autorandr-1.12.1.ebuild b/x11-misc/autorandr/autorandr-1.12.1.ebuild
deleted file mode 100644
index 2235547cc76e..000000000000
--- a/x11-misc/autorandr/autorandr-1.12.1.ebuild
+++ /dev/null
@@ -1,65 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_COMPAT=( python3_{8..11} )
-
-inherit bash-completion-r1 distutils-r1 systemd udev
-
-if [[ "${PV}" = "9999" ]] ; then
-	inherit git-r3
-	EGIT_REPO_URI="https://github.com/phillipberndt/${PN}.git"
-else
-	SRC_URI="https://github.com/phillipberndt/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
-	KEYWORDS="amd64 x86"
-fi
-
-DESCRIPTION="Automatically select a display configuration based on connected devices"
-HOMEPAGE="https://github.com/phillipberndt/autorandr"
-
-LICENSE="GPL-3"
-SLOT="0"
-IUSE="launcher udev"
-
-RDEPEND="
-	x11-apps/xrandr
-	launcher? ( x11-libs/libxcb )
-	udev? ( virtual/udev )
-"
-DEPEND="${RDEPEND}"
-BDEPEND="virtual/pkgconfig"
-
-src_compile() {
-	distutils-r1_src_compile
-
-	if use launcher; then
-		emake contrib/autorandr_launcher/autorandr-launcher
-	fi
-}
-
-src_install() {
-	distutils-r1_src_install
-
-	doman autorandr.1
-
-	local targets=(
-		autostart_config
-		bash_completion
-		systemd
-		$(usev launcher)
-		$(usev udev)
-	)
-
-	emake DESTDIR="${D}" \
-		  BASH_COMPLETIONS_DIR="$(get_bashcompdir)" \
-		  SYSTEMD_UNIT_DIR="$(systemd_get_systemunitdir)" \
-		  UDEV_RULES_DIR="$(get_udevdir)"/rules.d \
-		  $(printf "install_%s " "${targets[@]}")
-}
-
-pkg_postinst() {
-	if use udev; then
-		udev_reload
-	fi
-}