[gentoo-commits] repo/gentoo:master commit in: dev-tex/pythontex/

[Andrey Grozin]

commit:     4da89647dbe7849a6f1f3101341b58782ce57883
Author:     Andrey Grozin <grozin <AT> gentoo <DOT> org>
AuthorDate: Thu Sep 28 11:12:24 2017 +0000
Commit:     Andrey Grozin <grozin <AT> gentoo <DOT> org>
CommitDate: Thu Sep 28 11:12:24 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4da89647

dev-tex/pythontex: initial import from science overlay

Package-Manager: Portage-2.3.6, Repoman-2.3.3

 dev-tex/pythontex/Manifest              |  1 +
 dev-tex/pythontex/metadata.xml          | 14 +++++++++
 dev-tex/pythontex/pythontex-0.16.ebuild | 55 +++++++++++++++++++++++++++++++++
 3 files changed, 70 insertions(+)

diff --git a/dev-tex/pythontex/Manifest b/dev-tex/pythontex/Manifest
new file mode 100644
index 00000000000..38f63312ba3
--- /dev/null
+++ b/dev-tex/pythontex/Manifest
@@ -0,0 +1 @@
+DIST pythontex-0.16.tar.gz 1787147 SHA256 b33cf0189319752ffd14bb5735d0f3570e68545da834793c6fa2c81e164b6f5e SHA512 9a84fd7b7f568308addf9ba01c46fadfaface54b9d484c766831f1048064288fd1ecb5c56774bb0041d8f5705f8d5f8a9cd7258dc33157467eca7b3c70259183 WHIRLPOOL 7c8bd31208e9c4dcb640cc79d1a1885233c544485fcd4bf65772f7d7bc4efa0a5a6c60d15bae9e7d9e27f833b1ef2b06ea313a7008c3f000ec9b017a63ad0fbd

diff --git a/dev-tex/pythontex/metadata.xml b/dev-tex/pythontex/metadata.xml
new file mode 100644
index 00000000000..9586dee6f5e
--- /dev/null
+++ b/dev-tex/pythontex/metadata.xml
@@ -0,0 +1,14 @@
+<?xml version='1.0' encoding='UTF-8'?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>sci@g.o</email>
+    <name>Gentoo Science Project</name>
+  </maintainer>
+  <use>
+    <flag name="highlighting">Syntax highlighting using <pkg>dev-python/pygments</pkg></flag>
+  </use>
+  <upstream>
+    <remote-id type="github">gpoore/pythontex</remote-id>
+  </upstream>
+</pkgmetadata>

diff --git a/dev-tex/pythontex/pythontex-0.16.ebuild b/dev-tex/pythontex/pythontex-0.16.ebuild
new file mode 100644
index 00000000000..4e2cabb8f62
--- /dev/null
+++ b/dev-tex/pythontex/pythontex-0.16.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+
+inherit latex-package python-r1
+
+DESCRIPTION="Fast Access to Python from within LaTeX"
+HOMEPAGE="https://github.com/gpoore/pythontex"
+SRC_URI="https://github.com/gpoore/pythontex/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+SLOT="0"
+LICENSE="LPPL-1.3 BSD"
+KEYWORDS="~amd64 ~x86"
+IUSE="highlighting"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="${PYTHON_DEPS}
+	>=dev-texlive/texlive-latex-2016"
+RDEPEND="${DEPEND}
+	>=dev-texlive/texlive-latex-2016
+	highlighting? ( dev-python/pygments[${PYTHON_USEDEP}] )"
+
+TEXMF=/usr/share/texmf-site
+
+src_compile() {
+	cd ${PN} || die
+	ebegin "Compiling ${PN}"
+	rm ${PN}.sty || die
+	VARTEXFONTS="${T}/fonts" latex ${PN}.ins extra || die
+	eend
+}
+
+src_install() {
+	dodoc ${PN}/README "${S}"/*rst ${PN}_quickstart/*
+
+	cd ${PN} || die
+
+	installation() {
+		if python_is_python3; then
+			python_domodule {de,}${PN}3.py
+		else
+			python_domodule {de,}${PN}2.py
+		fi
+		python_domodule ${PN}_{engines,utils}.py
+		python_doscript {de,}${PN}.py syncpdb.py
+		python_optimize
+	}
+	python_foreach_impl installation
+
+	latex-package_src_doinstall dtx ins sty
+}