[gentoo-commits] gentoo-x86 commit in app-editors/nano: nano-2.3.3.ebuild ChangeLog

[Mike Frysinger (vapier)]

vapier      14/05/30 14:29:23

  Modified:             ChangeLog
  Added:                nano-2.3.3.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key D2E96200)

Revision  Changes    Path
1.307                app-editors/nano/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/nano/ChangeLog?rev=1.307&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/nano/ChangeLog?rev=1.307&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/nano/ChangeLog?r1=1.306&r2=1.307

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-editors/nano/ChangeLog,v
retrieving revision 1.306
retrieving revision 1.307
diff -u -r1.306 -r1.307
--- ChangeLog	16 Mar 2014 02:16:28 -0000	1.306
+++ ChangeLog	30 May 2014 14:29:23 -0000	1.307
@@ -1,6 +1,11 @@
 # ChangeLog for app-editors/nano
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/nano/ChangeLog,v 1.306 2014/03/16 02:16:28 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/nano/ChangeLog,v 1.307 2014/05/30 14:29:23 vapier Exp $
+
+*nano-2.3.3 (30 May 2014)
+
+  30 May 2014; Mike Frysinger <vapier@g.o> +nano-2.3.3.ebuild:
+  Version bump.
 
   16 Mar 2014; Mike Frysinger <vapier@g.o>
   files/nano-2.3.1-gentoo-nanorc.patch:



1.1                  app-editors/nano/nano-2.3.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/nano/nano-2.3.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/nano/nano-2.3.3.ebuild?rev=1.1&content-type=text/plain

Index: nano-2.3.3.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-editors/nano/nano-2.3.3.ebuild,v 1.1 2014/05/30 14:29:23 vapier Exp $

EAPI="4"

inherit eutils
if [[ ${PV} == "9999" ]] ; then
	ESVN_REPO_URI="svn://svn.savannah.gnu.org/nano/trunk/nano"
	inherit subversion autotools
else
	MY_P=${PN}-${PV/_}
	SRC_URI="http://www.nano-editor.org/dist/v${PV:0:3}/${MY_P}.tar.gz"
fi

DESCRIPTION="GNU GPL'd Pico clone with more functionality"
HOMEPAGE="http://www.nano-editor.org/ http://www.gentoo.org/doc/en/nano-basics-guide.xml"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~arm-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="debug justify +magic minimal ncurses nls slang +spell unicode"

RDEPEND=">=sys-libs/ncurses-5.9-r1[unicode?]
	magic? ( sys-apps/file )
	nls? ( virtual/libintl )
	!ncurses? ( slang? ( sys-libs/slang ) )"
DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )
	virtual/pkgconfig"

src_prepare() {
	epatch_user
}

src_configure() {
	eval export ac_cv_{header_magic_h,lib_magic_magic_open}=$(usex magic)
	local myconf=()
	case ${CHOST} in
	*-gnu*|*-uclibc*) myconf+=( "--with-wordbounds" ) ;; #467848
	esac
	econf \
		--bindir="${EPREFIX}"/bin \
		$(use_enable !minimal color) \
		$(use_enable !minimal multibuffer) \
		$(use_enable !minimal nanorc) \
		--disable-wrapping-as-root \
		$(use_enable spell speller) \
		$(use_enable justify) \
		$(use_enable debug) \
		$(use_enable nls) \
		$(use_enable unicode utf8) \
		$(use_enable minimal tiny) \
		$(usex ncurses --without-slang $(use_with slang)) \
		"${myconf[@]}"
}

src_install() {
	default
	rm -rf "${ED}"/usr/share/nano/man-html

	dodoc doc/nanorc.sample
	dohtml doc/faq.html
	insinto /etc
	newins doc/nanorc.sample nanorc
	if ! use minimal ; then
		# Enable colorization by default.
		sed -i \
			-e '/^# include /s:# *::' \
			"${ED}"/etc/nanorc || die
	fi

	dodir /usr/bin
	dosym /bin/nano /usr/bin/nano
}