1 |
commit: 24ab302c1f4cecae1f37649ae638b7c9ba949dc7 |
2 |
Author: Michał Górny <mgorny <AT> gentoo <DOT> org> |
3 |
AuthorDate: Tue Feb 2 08:29:20 2021 +0000 |
4 |
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org> |
5 |
CommitDate: Tue Feb 2 08:29:20 2021 +0000 |
6 |
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=24ab302c |
7 |
|
8 |
dev-python/ipython: Bump to 7.20.0 |
9 |
|
10 |
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org> |
11 |
|
12 |
dev-python/ipython/Manifest | 1 + |
13 |
dev-python/ipython/ipython-7.20.0.ebuild | 136 +++++++++++++++++++++++++++++++ |
14 |
2 files changed, 137 insertions(+) |
15 |
|
16 |
diff --git a/dev-python/ipython/Manifest b/dev-python/ipython/Manifest |
17 |
index b0267afcb39..5a7e630c1db 100644 |
18 |
--- a/dev-python/ipython/Manifest |
19 |
+++ b/dev-python/ipython/Manifest |
20 |
@@ -1 +1,2 @@ |
21 |
DIST ipython-7.19.0.tar.gz 5225775 BLAKE2B 1909d8336e7fc90959da4ca33ad7edcb8c2dec0a5aa20ca6f643ef53482fe7bf0d52e2bbec7cf97e72a1fd4d37af45ba01166febb25f35b52d69ffc062f0f0e8 SHA512 5350a125da3050acaea4899939a3b9d779009a2f5769fc9f3aa514ce029df050069ef9310d3255ad62f28912b4dec39207267248d3a2c3e9131cffd691322622 |
22 |
+DIST ipython-7.20.0.tar.gz 5140776 BLAKE2B ec01caf874ab9c331eb1f074f9e70acb521fe6d4abe3e8f086d9e9e77cd710c3b0d88c6d7b071abc6962eee8141b65a012ec772cbec3450db25f086fc66cf1c6 SHA512 2fff1a64c3d83e794e76bcbdf54e105f499321d9a7e5d3221cdc3e15a96e90543fd465b8dbee4836965286e7c1f1ea6d13e4d3d88c095164858bf71c161111fe |
23 |
|
24 |
diff --git a/dev-python/ipython/ipython-7.20.0.ebuild b/dev-python/ipython/ipython-7.20.0.ebuild |
25 |
new file mode 100644 |
26 |
index 00000000000..86e6b6231e4 |
27 |
--- /dev/null |
28 |
+++ b/dev-python/ipython/ipython-7.20.0.ebuild |
29 |
@@ -0,0 +1,136 @@ |
30 |
+# Copyright 1999-2021 Gentoo Authors |
31 |
+# Distributed under the terms of the GNU General Public License v2 |
32 |
+ |
33 |
+EAPI=7 |
34 |
+ |
35 |
+DISTUTILS_USE_SETUPTOOLS=no |
36 |
+PYTHON_COMPAT=( python3_{7..9} ) |
37 |
+PYTHON_REQ_USE='readline,sqlite,threads(+)' |
38 |
+ |
39 |
+inherit distutils-r1 optfeature virtualx |
40 |
+ |
41 |
+DESCRIPTION="Advanced interactive shell for Python" |
42 |
+HOMEPAGE="https://ipython.org/ https://github.com/ipython/ipython/" |
43 |
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz" |
44 |
+ |
45 |
+LICENSE="BSD" |
46 |
+SLOT="0" |
47 |
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux" |
48 |
+IUSE="doc examples matplotlib notebook nbconvert qt5 +smp test" |
49 |
+RESTRICT="!test? ( test )" |
50 |
+ |
51 |
+CDEPEND=" |
52 |
+ dev-python/backcall[${PYTHON_USEDEP}] |
53 |
+ dev-python/decorator[${PYTHON_USEDEP}] |
54 |
+ >=dev-python/jedi-0.16[${PYTHON_USEDEP}] |
55 |
+ >=dev-python/pexpect-4.3[${PYTHON_USEDEP}] |
56 |
+ dev-python/pickleshare[${PYTHON_USEDEP}] |
57 |
+ >=dev-python/prompt_toolkit-2[${PYTHON_USEDEP}] |
58 |
+ <dev-python/prompt_toolkit-3.1[${PYTHON_USEDEP}] |
59 |
+ dev-python/pygments[${PYTHON_USEDEP}] |
60 |
+ dev-python/traitlets[${PYTHON_USEDEP}] |
61 |
+ matplotlib? ( dev-python/matplotlib[${PYTHON_USEDEP}] ) |
62 |
+" |
63 |
+ |
64 |
+RDEPEND="${CDEPEND} |
65 |
+ nbconvert? ( dev-python/nbconvert[${PYTHON_USEDEP}] )" |
66 |
+ |
67 |
+BDEPEND=" |
68 |
+ test? ( |
69 |
+ ${CDEPEND} |
70 |
+ app-text/dvipng[truetype] |
71 |
+ >=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}] |
72 |
+ dev-python/nbformat[${PYTHON_USEDEP}] |
73 |
+ dev-python/nose[${PYTHON_USEDEP}] |
74 |
+ >=dev-python/numpy-1.14[${PYTHON_USEDEP}] |
75 |
+ dev-python/requests[${PYTHON_USEDEP}] |
76 |
+ dev-python/testpath[${PYTHON_USEDEP}] |
77 |
+ ) |
78 |
+ doc? ( |
79 |
+ >=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}] |
80 |
+ dev-python/matplotlib[${PYTHON_USEDEP}] |
81 |
+ >=dev-python/sphinx-2[${PYTHON_USEDEP}] |
82 |
+ )" |
83 |
+ |
84 |
+PDEPEND=" |
85 |
+ notebook? ( |
86 |
+ dev-python/notebook[${PYTHON_USEDEP}] |
87 |
+ dev-python/ipywidgets[${PYTHON_USEDEP}] |
88 |
+ dev-python/widgetsnbextension[${PYTHON_USEDEP}] |
89 |
+ ) |
90 |
+ qt5? ( dev-python/qtconsole[${PYTHON_USEDEP}] ) |
91 |
+ smp? ( |
92 |
+ >=dev-python/ipykernel-5.1.0[${PYTHON_USEDEP}] |
93 |
+ >=dev-python/ipyparallel-6.2.3[${PYTHON_USEDEP}] |
94 |
+ )" |
95 |
+ |
96 |
+PATCHES=( "${FILESDIR}"/2.1.0-substitute-files.patch ) |
97 |
+ |
98 |
+DISTUTILS_IN_SOURCE_BUILD=1 |
99 |
+ |
100 |
+python_prepare_all() { |
101 |
+ # Remove out of date insource files |
102 |
+ rm IPython/extensions/cythonmagic.py || die |
103 |
+ rm IPython/extensions/rmagic.py || die |
104 |
+ |
105 |
+ # Prevent un-needed download during build |
106 |
+ if use doc; then |
107 |
+ sed -e "/^ 'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die |
108 |
+ fi |
109 |
+ |
110 |
+ distutils-r1_python_prepare_all |
111 |
+} |
112 |
+ |
113 |
+python_compile_all() { |
114 |
+ if use doc; then |
115 |
+ emake -C docs html_noapi |
116 |
+ HTML_DOCS=( docs/build/html/. ) |
117 |
+ fi |
118 |
+} |
119 |
+ |
120 |
+src_test() { |
121 |
+ virtx distutils-r1_src_test |
122 |
+} |
123 |
+ |
124 |
+python_test() { |
125 |
+ distutils_install_for_testing |
126 |
+ pushd "${TEST_DIR}" >/dev/null || die |
127 |
+ "${TEST_DIR}"/scripts/iptest || die |
128 |
+ popd >/dev/null || die |
129 |
+} |
130 |
+ |
131 |
+python_install() { |
132 |
+ distutils-r1_python_install |
133 |
+ |
134 |
+ # Create ipythonX.Y symlinks. |
135 |
+ # TODO: |
136 |
+ # 1. do we want them for pypy? No. pypy has no numpy |
137 |
+ # 2. handle it in the eclass instead (use _python_ln_rel). |
138 |
+ # With pypy not an option the dosym becomes unconditional |
139 |
+ dosym ../lib/python-exec/${EPYTHON}/ipython \ |
140 |
+ /usr/bin/ipython${EPYTHON#python} |
141 |
+} |
142 |
+ |
143 |
+python_install_all() { |
144 |
+ distutils-r1_python_install_all |
145 |
+ |
146 |
+ if use examples; then |
147 |
+ dodoc -r examples |
148 |
+ docompress -x /usr/share/doc/${PF}/examples |
149 |
+ fi |
150 |
+} |
151 |
+ |
152 |
+pkg_postinst() { |
153 |
+ optfeature "sympyprinting" dev-python/sympy |
154 |
+ optfeature "cythonmagic" dev-python/cython |
155 |
+ optfeature "%lprun magic command" dev-python/line_profiler |
156 |
+ optfeature "%mprun magic command" dev-python/memory_profiler |
157 |
+ |
158 |
+ if use nbconvert; then |
159 |
+ if ! has_version app-text/pandoc ; then |
160 |
+ einfo "Node.js will be used to convert notebooks to other formats" |
161 |
+ einfo "like HTML. Support for that is still experimental. If you" |
162 |
+ einfo "encounter any problems, please use app-text/pandoc instead." |
163 |
+ fi |
164 |
+ fi |
165 |
+} |