[gentoo-commits] repo/gentoo:master commit in: dev-libs/quazip/

[Manuel Rüger]

commit:     6d8e78202c46295135c6d8607f926939a3ebb20d
Author:     Manuel Rüger <mrueg <AT> gentoo <DOT> org>
AuthorDate: Sat Apr 15 22:26:50 2017 +0000
Commit:     Manuel Rüger <mrueg <AT> gentoo <DOT> org>
CommitDate: Sat Apr 15 22:26:50 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6d8e7820

dev-libs/quazip: Version bump to 0.7.3

Package-Manager: Portage-2.3.5, Repoman-2.3.2

 dev-libs/quazip/Manifest            |  1 +
 dev-libs/quazip/quazip-0.7.3.ebuild | 93 +++++++++++++++++++++++++++++++++++++
 2 files changed, 94 insertions(+)

diff --git a/dev-libs/quazip/Manifest b/dev-libs/quazip/Manifest
index 2778b97e7f6..661d946522b 100644
--- a/dev-libs/quazip/Manifest
+++ b/dev-libs/quazip/Manifest
@@ -1 +1,2 @@
 DIST quazip-0.7.2.tar.gz 466915 SHA256 91d827fbcafd099ae814cc18a8dd3bb709da6b8a27c918ee1c6c03b3f29440f4 SHA512 669efb01edefee084ae755728aa2392bf160331fb13db62b7fac5e91bd45c29bb824a41ec63dd4a74c4a9780848d3308c0dcdb503f907a0fcccfbe969c291dd0 WHIRLPOOL 512661cab59eb2bda5e3a45ee800577bc2b8d3016a4076ca253b64de627098b4e2f62e20397dfe7a2f72aeaad7abdda8f1027e109ce1e8b6d6bfe117456600fb
+DIST quazip-0.7.3.tar.gz 439536 SHA256 2ad4f354746e8260d46036cde1496c223ec79765041ea28eb920ced015e269b5 SHA512 d4b55bd040e47e97e7bd5d080399ae4aa5fbc4985d6ab5979b468abc852c91b2e3e5d35af90d4b4de3bb01ea9135d0247473d6eab0413392b1c8567dc799a9fe WHIRLPOOL b159e1a9abfb973535e7113c219b1925d029f86bf62f2d7a50a1ee60f8444ddf3e5815a36a06f20d6b4e8639a76b7d011a5c317d6aea4602165f3b6e7fd482c8

diff --git a/dev-libs/quazip/quazip-0.7.3.ebuild b/dev-libs/quazip/quazip-0.7.3.ebuild
new file mode 100644
index 00000000000..e3a070a0450
--- /dev/null
+++ b/dev-libs/quazip/quazip-0.7.3.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils flag-o-matic multibuild qmake-utils
+
+DESCRIPTION="A simple C++ wrapper over Gilles Vollant's ZIP/UNZIP package"
+HOMEPAGE="http://quazip.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1-with-linking-exception"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="qt4 +qt5 static-libs test"
+
+REQUIRED_USE="|| ( qt4 qt5 )"
+
+RDEPEND="
+	sys-libs/zlib[minizip]
+	qt4? ( dev-qt/qtcore:4 )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtnetwork:5
+	)
+"
+DEPEND="${RDEPEND}
+	test? (
+		qt4? ( dev-qt/qttest:4 )
+	)
+"
+
+DOCS=( NEWS.txt README.txt )
+HTML_DOCS=( doc/html/. )
+
+pkg_setup() {
+	MULTIBUILD_VARIANTS=( $(usev qt4) $(usev qt5) )
+}
+
+src_prepare() {
+	if ! use static-libs ; then
+		sed -e "/^install/ s/quazip_static//" -i quazip/CMakeLists.txt || die
+	fi
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	myconfigure() {
+		local libdir=$(get_libdir)
+		local mycmakeargs=(
+			-DLIB_SUFFIX=${libdir/lib/}
+		)
+		unset libdir
+		if [[ ${MULTIBUILD_VARIANT} = qt4 ]]; then
+			mycmakeargs+=( -DBUILD_WITH_QT4=ON )
+		fi
+		if [[ ${MULTIBUILD_VARIANT} = qt5 ]]; then
+			local -x CXXFLAGS="${CXXFLAGS}"
+			append-cxxflags -std=c++11 -fPIC
+			mycmakeargs+=( -DBUILD_WITH_QT4=OFF )
+		fi
+		cmake-utils_src_configure
+	}
+
+	multibuild_foreach_variant myconfigure
+}
+
+src_compile() {
+	multibuild_foreach_variant cmake-utils_src_compile
+}
+
+src_test() {
+	cd "${S}"/qztest || die
+	mytest() {
+		if [[ ${MULTIBUILD_VARIANT} = qt4 ]]; then
+			eqmake4 \
+				LIBS+="-L${WORKDIR}/${P}-qt4"
+			emake
+			LD_LIBRARY_PATH="${WORKDIR}/${P}-qt4" ./qztest || die
+		fi
+	}
+
+	multibuild_foreach_variant mytest
+}
+
+src_install() {
+	multibuild_foreach_variant cmake-utils_src_install
+
+	# compatibility with not yet fixed rdeps (Gentoo bug #598136)
+	if ! use qt4; then
+		dosym libquazip5.so /usr/$(get_libdir)/libquazip.so
+	fi
+}