[gentoo-commits] repo/gentoo:master commit in: net-libs/libpcap/

[Jeroen Roovers]

commit:     4086cf9ecb0418c6cb1ad3e717c3a2807641aea4
Author:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
AuthorDate: Thu Jan  9 13:36:20 2020 +0000
Commit:     Jeroen Roovers <jer <AT> gentoo <DOT> org>
CommitDate: Thu Jan  9 13:39:04 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4086cf9e

net-libs/libpcap: Add USE=usb dependency, drop KEYWORDS=riscv

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Bug: https://bugs.gentoo.org/498896
Signed-off-by: Jeroen Roovers <jer <AT> gentoo.org>

 net-libs/libpcap/libpcap-1.9.1-r2.ebuild | 80 ++++++++++++++++++++++++++++++++
 1 file changed, 80 insertions(+)

diff --git a/net-libs/libpcap/libpcap-1.9.1-r2.ebuild b/net-libs/libpcap/libpcap-1.9.1-r2.ebuild
new file mode 100644
index 00000000000..96323e01da6
--- /dev/null
+++ b/net-libs/libpcap/libpcap-1.9.1-r2.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools multilib-minimal
+
+DESCRIPTION="A system-independent library for user-level network packet capture"
+HOMEPAGE="
+	https://www.tcpdump.org/
+	https://github.com/the-tcpdump-group/libpcap
+"
+SRC_URI="
+	https://github.com/the-tcpdump-group/${PN}/archive/${P/_}.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x86-solaris"
+IUSE="bluetooth dbus netlink -remote static-libs usb -yydebug"
+
+RDEPEND="
+	bluetooth? ( net-wireless/bluez:=[${MULTILIB_USEDEP}] )
+	dbus? ( sys-apps/dbus[${MULTILIB_USEDEP}] )
+	netlink? ( dev-libs/libnl:3[${MULTILIB_USEDEP}] )
+	usb? ( virtual/libusb:1[${MULTILIB_USEDEP}] )
+"
+DEPEND="
+	${RDEPEND}
+	sys-devel/flex
+	virtual/yacc
+	dbus? ( virtual/pkgconfig[${MULTILIB_USEDEP}] )
+"
+
+S=${WORKDIR}/${PN}-${P/_}
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.8.1-usbmon.patch
+	"${FILESDIR}"/${PN}-1.9.1-pcap-config.patch
+)
+
+src_prepare() {
+	default
+
+	echo ${PV} > VERSION || die
+
+	eautoreconf
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" \
+	econf \
+		$(use_enable bluetooth) \
+		$(use_enable dbus) \
+		$(use_enable remote) \
+		$(use_enable usb) \
+		$(use_enable yydebug) \
+		$(use_with netlink libnl) \
+		--enable-ipv6
+}
+
+multilib_src_compile() {
+	emake all shared
+}
+
+multilib_src_install_all() {
+	dodoc CREDITS CHANGES VERSION TODO README.* doc/README.*
+
+	# remove static libraries (--disable-static does not work)
+	if ! use static-libs; then
+		find "${ED}" -name '*.a' -exec rm {} + || die
+	fi
+
+	find "${ED}" -name '*.la' -delete || die
+
+	# We need this to build pppd on G/FBSD systems
+	if [[ "${USERLAND}" == "BSD" ]]; then
+		insinto /usr/include
+		doins pcap-int.h portability.h
+	fi
+}