[gentoo-commits] repo/gentoo:master commit in: dev-libs/libgit2-glib/

[Mart Raudsepp]

commit:     3899325e4e1729e5f5cecb0a68bd7a2fd725a4ac
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Tue Apr 18 08:52:46 2017 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Tue Apr 18 10:53:36 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=3899325e

dev-libs/libgit2-glib: bump to 0.25.0

Package-Manager: Portage-2.3.5, Repoman-2.3.2

 dev-libs/libgit2-glib/Manifest                   |  1 +
 dev-libs/libgit2-glib/libgit2-glib-0.25.0.ebuild | 58 ++++++++++++++++++++++++
 2 files changed, 59 insertions(+)

diff --git a/dev-libs/libgit2-glib/Manifest b/dev-libs/libgit2-glib/Manifest
index bf8d9f57082..0b89806a3e7 100644
--- a/dev-libs/libgit2-glib/Manifest
+++ b/dev-libs/libgit2-glib/Manifest
@@ -1 +1,2 @@
 DIST libgit2-glib-0.24.4.tar.xz 458360 SHA256 3a211f756f250042f352b3070e7314a048c88e785dba9d118b851253a7c60220 SHA512 55874f77ded1474eab6f84d3426c8cddd56a42b04b8b3e50e4294f396b8c10025a38bc925c0b74ba3e52022c696f07e7f69b75c443bbd0af0f9e0769b7c4555f WHIRLPOOL 22a17e940a670ccb31cf0fc229b8f042794e10e7c5996d4059779d3a7b2ab5865b9cf1bc1a32a9297e88e5b069b281e7f20b2db636f91d5f8af9df8f14d23346
+DIST libgit2-glib-0.25.0.tar.xz 420500 SHA256 4a256b9acfb93ea70d37213a4083e2310e59b05f2c7595242fe3c239327bc565 SHA512 f265d5da4bba28de2aa7254d36fa596b9e348c6543cd559cbb9c1f9610d4b63af00c82fb4138f345e15109503e0d61101d3344c68539348cb268403387a4418e WHIRLPOOL beb276d2637edca19a96f7eca94bc8b318b31e6c014044e7526c9c397ec376dea38891eb0985351899ad26de1436f4713e3ac0d708966e4e41d41d516208072f

diff --git a/dev-libs/libgit2-glib/libgit2-glib-0.25.0.ebuild b/dev-libs/libgit2-glib/libgit2-glib-0.25.0.ebuild
new file mode 100644
index 00000000000..d771ee339a5
--- /dev/null
+++ b/dev-libs/libgit2-glib/libgit2-glib-0.25.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+GCONF_DEBUG="no"
+PYTHON_COMPAT=( python{3_4,3_5} )
+VALA_USE_DEPEND="vapigen"
+
+inherit eutils gnome2 python-r1 vala
+
+DESCRIPTION="Git library for GLib"
+HOMEPAGE="https://wiki.gnome.org/Projects/Libgit2-glib"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="python ssh +vala"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+# Specify libgit2 dependency with subslot because libgit2 upstream has a habit
+# of changing their API in each release in ways that break libgit2-glib
+RDEPEND="
+	>=dev-libs/libgit2-0.25.0:0/25[ssh?]
+	>=dev-libs/glib-2.44.0:2
+	python? (
+		${PYTHON_DEPS}
+		dev-python/pygobject:3[${PYTHON_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.11
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		$(use_enable python) \
+		$(use_enable ssh) \
+		$(use_enable vala)
+}
+
+src_install() {
+	gnome2_src_install
+
+	if use python ; then
+		install_gi_override() {
+			python_moduleinto "$(python_get_sitedir)/gi/overrides"
+			python_domodule "${S}"/${PN}/Ggit.py
+		}
+		python_foreach_impl install_gi_override
+	fi
+}