[gentoo-commits] gentoo-x86 commit in app-editors/focuswriter: focuswriter-1.5.2.ebuild ChangeLog focuswriter-1.4.1.ebuild

[Michael Palimaka (kensington)]

kensington    14/07/31 10:49:52

  Modified:             ChangeLog
  Added:                focuswriter-1.5.2.ebuild
  Removed:              focuswriter-1.4.1.ebuild
  Log:
  Version bump wrt bug #508578. Remove old.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0x06B1F38DCA45A1EC!)

Revision  Changes    Path
1.19                 app-editors/focuswriter/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/focuswriter/ChangeLog?rev=1.19&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/focuswriter/ChangeLog?rev=1.19&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/focuswriter/ChangeLog?r1=1.18&r2=1.19

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-editors/focuswriter/ChangeLog,v
retrieving revision 1.18
retrieving revision 1.19
diff -u -r1.18 -r1.19
--- ChangeLog	4 Feb 2014 13:43:40 -0000	1.18
+++ ChangeLog	31 Jul 2014 10:49:52 -0000	1.19
@@ -1,6 +1,12 @@
 # ChangeLog for app-editors/focuswriter
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/focuswriter/ChangeLog,v 1.18 2014/02/04 13:43:40 hasufell Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/focuswriter/ChangeLog,v 1.19 2014/07/31 10:49:52 kensington Exp $
+
+*focuswriter-1.5.2 (31 Jul 2014)
+
+  31 Jul 2014; Michael Palimaka <kensington@g.o>
+  +focuswriter-1.5.2.ebuild, -focuswriter-1.4.1.ebuild:
+  Version bump wrt bug #508578. Remove old.
 
 *focuswriter-1.4.4 (04 Feb 2014)
 



1.1                  app-editors/focuswriter/focuswriter-1.5.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/focuswriter/focuswriter-1.5.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/focuswriter/focuswriter-1.5.2.ebuild?rev=1.1&content-type=text/plain

Index: focuswriter-1.5.2.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-editors/focuswriter/focuswriter-1.5.2.ebuild,v 1.1 2014/07/31 10:49:52 kensington Exp $

EAPI=5

PLOCALES="ar ca cs da de el en en_GB es_MX es fi fr he hu hy id it ja ko nl pl
pt_BR pt ro ru sk sr sv tr uk vi zh_CN zh_TW"
PLOCALE_BACKUP="en"
inherit fdo-mime gnome2-utils l10n readme.gentoo qt4-r2

DESCRIPTION="A fullscreen and distraction-free word processor"
HOMEPAGE="http://gottcode.org/focuswriter/"
SRC_URI="http://gottcode.org/${PN}/${P}-src.tar.bz2"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug"

RDEPEND="app-text/hunspell
	dev-qt/qtcore:4
	dev-qt/qtgui:4
	sys-libs/zlib"
DEPEND="${RDEPEND}
	virtual/pkgconfig"

DOCS=( ChangeLog CREDITS NEWS README )
DOC_CONTENTS="Focuswriter has optional sound support if media-libs/sdl-mixer is
installed with wav useflag enabled."

src_prepare() {
	l10n_for_each_disabled_locale_do rm_loc
}

src_configure() {
	eqmake4 PREFIX="${EPREFIX}/usr"
}

src_install() {
	readme.gentoo_create_doc
	qt4-r2_src_install
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	readme.gentoo_pkg_postinst
	gnome2_icon_cache_update
	fdo-mime_desktop_database_update
}

pkg_postrm() {
	gnome2_icon_cache_update
	fdo-mime_desktop_database_update
}

rm_loc() {
	sed -e "s|translations/${PN}_${1}.ts||"	-i ${PN}.pro || die 'sed failed'
	rm translations/${PN}_${1}.{ts,qm} || die "removing ${1} locale failed"
}