[gentoo-commits] gentoo-x86 commit in app-arch/xz-utils: ChangeLog xz-utils-5.0.2.ebuild

[Mike Frysinger (vapier)]

vapier      11/04/04 05:16:07

  Modified:             ChangeLog
  Added:                xz-utils-5.0.2.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha28/cvs/Linux x86_64)

Revision  Changes    Path
1.31                 app-arch/xz-utils/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/xz-utils/ChangeLog?rev=1.31&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/xz-utils/ChangeLog?rev=1.31&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/xz-utils/ChangeLog?r1=1.30&r2=1.31

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-arch/xz-utils/ChangeLog,v
retrieving revision 1.30
retrieving revision 1.31
diff -u -r1.30 -r1.31
--- ChangeLog	20 Mar 2011 18:39:17 -0000	1.30
+++ ChangeLog	4 Apr 2011 05:16:07 -0000	1.31
@@ -1,6 +1,11 @@
 # ChangeLog for app-arch/xz-utils
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-arch/xz-utils/ChangeLog,v 1.30 2011/03/20 18:39:17 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-arch/xz-utils/ChangeLog,v 1.31 2011/04/04 05:16:07 vapier Exp $
+
+*xz-utils-5.0.2 (04 Apr 2011)
+
+  04 Apr 2011; Mike Frysinger <vapier@g.o> +xz-utils-5.0.2.ebuild:
+  Version bump.
 
   20 Mar 2011; Raúl Porcel <armin76@g.o> xz-utils-5.0.1.ebuild:
   ia64/m68k/s390/sh stable wrt #355649



1.1                  app-arch/xz-utils/xz-utils-5.0.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/xz-utils/xz-utils-5.0.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-arch/xz-utils/xz-utils-5.0.2.ebuild?rev=1.1&content-type=text/plain

Index: xz-utils-5.0.2.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-arch/xz-utils/xz-utils-5.0.2.ebuild,v 1.1 2011/04/04 05:16:07 vapier Exp $

# Remember: we cannot leverage autotools in this ebuild in order
#           to avoid circular deps with autotools

EAPI="2"

if [[ ${PV} == "9999" ]] ; then
	EGIT_REPO_URI="git://ctrl.tukaani.org/xz.git"
	inherit git autotools
	SRC_URI=""
	EXTRA_DEPEND="sys-devel/gettext dev-vcs/cvs >=sys-devel/libtool-2" #272880 286068
else
	MY_P="${PN/-utils}-${PV/_}"
	SRC_URI="http://tukaani.org/xz/${MY_P}.tar.gz"
	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
	S=${WORKDIR}/${MY_P}
	EXTRA_DEPEND=
fi

inherit eutils multilib

DESCRIPTION="utils for managing LZMA compressed files"
HOMEPAGE="http://tukaani.org/xz/"

LICENSE="LGPL-2.1"
SLOT="0"
IUSE="nls static-libs +threads"

RDEPEND="!<app-arch/lzma-4.63
	!app-arch/lzma-utils
	!<app-arch/p7zip-4.57"
DEPEND="${RDEPEND}
	${EXTRA_DEPEND}"

if [[ ${PV} == "9999" ]] ; then
src_prepare() {
	eautopoint
	eautoreconf
}
fi

src_prepare() {
	epatch "${FILESDIR}"/${PN}-5.0.1-xzgrep-typo.patch #356627
}

src_configure() {
	econf \
		$(use_enable nls) \
		$(use_enable threads) \
		$(use_enable static-libs static)
}

src_install() {
	emake install DESTDIR="${D}" || die
	rm "${D}"/usr/share/doc/xz/COPYING* || die
	mv "${D}"/usr/share/doc/{xz,${PF}} || die
	prepalldocs
	dodoc AUTHORS ChangeLog NEWS README THANKS
}

pkg_preinst() {
	preserve_old_lib /usr/$(get_libdir)/liblzma.so.0
}

pkg_postinst() {
	preserve_old_lib_notify /usr/$(get_libdir)/liblzma.so.0
}