[gentoo-commits] repo/gentoo:master commit in: sys-auth/libnss-pgsql/

[Aaron W. Swenson]

commit:     681f42e078527a1a2f7a47d8cb00e72e3f8990d2
Author:     Aaron W. Swenson <titanofold <AT> gentoo <DOT> org>
AuthorDate: Sat Nov  2 16:10:51 2019 +0000
Commit:     Aaron W. Swenson <titanofold <AT> gentoo <DOT> org>
CommitDate: Sat Nov  2 16:10:57 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=681f42e0

sys-auth/libnss-pgsql: Bump EAPI to 7

Package-Manager: Portage-2.3.76, Repoman-2.3.16
Signed-off-by: Aaron W. Swenson <titanofold <AT> gentoo.org>

 .../libnss-pgsql/libnss-pgsql-1.5.0_beta-r1.ebuild | 48 ++++++++++++++++++++++
 1 file changed, 48 insertions(+)

diff --git a/sys-auth/libnss-pgsql/libnss-pgsql-1.5.0_beta-r1.ebuild b/sys-auth/libnss-pgsql/libnss-pgsql-1.5.0_beta-r1.ebuild
new file mode 100644
index 00000000000..62a4efe9017
--- /dev/null
+++ b/sys-auth/libnss-pgsql/libnss-pgsql-1.5.0_beta-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+KEYWORDS="~amd64 ~x86"
+
+DESCRIPTION="Name Service Switch module for use with PostgreSQL"
+HOMEPAGE="http://pgfoundry.org/projects/sysauth/"
+
+MY_P="${P/_/-}"
+SRC_URI="http://pgfoundry.org/frs/download.php/1878/${MY_P}.tgz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE=""
+
+RDEPEND="dev-db/postgresql:*"
+DEPEND="${RDEPEND}
+		app-text/xmlto"
+
+src_prepare() {
+	eapply "${FILESDIR}/${P}-gentoo.patch"
+	eapply_user
+	eautoreconf
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	find "${D}" -name '*.la' -delete || die
+
+	dodoc AUTHORS ChangeLog NEWS README
+	insinto /usr/share/doc/${PF}/examples
+	doins conf/*
+}
+
+pkg_postinst() {
+	elog "Next steps:"
+	elog "1. Create the required tables in the database:"
+	elog "   $ psql a_database -f /usr/share/doc/${PF}/examples/dbschema.sql"
+	elog "2. Create the configuration file '/etc/nss-pgsql.conf'"
+	elog "   You can copy the example from /usr/share/doc/${PF}/examples/nss-pgsql.conf"
+	elog "3. Edit /etc/nsswitch.conf to use the NSS service 'pgsql'"
+	elog "   An example is available here: /usr/share/doc/${PF}/examples/nsswitch.conf"
+}