[gentoo-commits] gentoo-x86 commit in media-sound/gpodder: gpodder-3.7.0.ebuild ChangeLog

[Samuli Suominen (ssuominen)]

ssuominen    14/07/26 12:17:12

  Modified:             ChangeLog
  Added:                gpodder-3.7.0.ebuild
  Log:
  Version bump wrt #506846 by Coran Fisher
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

Revision  Changes    Path
1.36                 media-sound/gpodder/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/gpodder/ChangeLog?rev=1.36&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/gpodder/ChangeLog?rev=1.36&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/gpodder/ChangeLog?r1=1.35&r2=1.36

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/gpodder/ChangeLog,v
retrieving revision 1.35
retrieving revision 1.36
diff -u -r1.35 -r1.36
--- ChangeLog	6 Apr 2014 10:42:39 -0000	1.35
+++ ChangeLog	26 Jul 2014 12:17:12 -0000	1.36
@@ -1,6 +1,11 @@
 # ChangeLog for media-sound/gpodder
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/gpodder/ChangeLog,v 1.35 2014/04/06 10:42:39 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/gpodder/ChangeLog,v 1.36 2014/07/26 12:17:12 ssuominen Exp $
+
+*gpodder-3.7.0 (26 Jul 2014)
+
+  26 Jul 2014; Samuli Suominen <ssuominen@g.o> +gpodder-3.7.0.ebuild:
+  Version bump wrt #506846 by Coran Fisher
 
   06 Apr 2014; Gilles Dartiguelongue <eva@g.o> gpodder-3.6.0.ebuild:
   Pin gst-python to 0.10 slot.



1.1                  media-sound/gpodder/gpodder-3.7.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/gpodder/gpodder-3.7.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/gpodder/gpodder-3.7.0.ebuild?rev=1.1&content-type=text/plain

Index: gpodder-3.7.0.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/gpodder/gpodder-3.7.0.ebuild,v 1.1 2014/07/26 12:17:12 ssuominen Exp $

EAPI=5
PYTHON_COMPAT=( python2_7 )
PYTHON_REQ_USE="sqlite"
# Required for python_fix_shebang:
DISTUTILS_SINGLE_IMPL=1

inherit distutils-r1 gnome2-utils

DESCRIPTION="A free cross-platform podcast aggregator"
HOMEPAGE="http://gpodder.org/"
SRC_URI="http://gpodder.org/src/${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
IUSE="+dbus bluetooth gstreamer ipod kernel_linux mtp test webkit"

#TODO: add QML UI deps (USE=qt4) and make pygtk optional, see README
COMMON_DEPEND=">=dev-python/eyeD3-0.7
	>=dev-python/feedparser-5.1.2
	>=dev-python/mygpoclient-1.7
	>=dev-python/pygtk-2.16:2
	dbus? ( dev-python/dbus-python )
	bluetooth? ( net-wireless/bluez )
	gstreamer? ( dev-python/gst-python:0.10 )
	ipod? ( media-libs/libgpod[python] )
	mtp? ( >=media-libs/libmtp-1.0.0 )
	webkit? ( dev-python/pywebkitgtk )"
RDEPEND="${COMMON_DEPEND}
	kernel_linux? ( sys-apps/iproute2 )"
DEPEND="${COMMON_DEPEND}
	dev-util/intltool
	sys-apps/help2man
	test? (
		dev-python/minimock
		dev-python/coverage
	)"

src_prepare() {
	sed -i -e '/setup.py.*install/d' makefile || die
	# Fix for "AttributeError: 'gPodder' object has no attribute 'toolbar'":
	python_fix_shebang .
}

src_install() {
	emake DESTDIR="${D}" install
	distutils-r1_src_install
}

src_test() {
	emake releasetest
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	gnome2_icon_cache_update
}

pkg_postrm() {
	gnome2_icon_cache_update
}