[gentoo-commits] gentoo-x86 commit in dev-util/w32api: w32api-4.0.3.1.ebuild ChangeLog

[Mike Frysinger (vapier)]

vapier      14/06/02 04:34:22

  Modified:             ChangeLog
  Added:                w32api-4.0.3.1.ebuild
  Log:
  Version bump #511492 by Yevgeny Filatov.
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key D2E96200)

Revision  Changes    Path
1.19                 dev-util/w32api/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/w32api/ChangeLog?rev=1.19&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/w32api/ChangeLog?rev=1.19&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/w32api/ChangeLog?r1=1.18&r2=1.19

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/w32api/ChangeLog,v
retrieving revision 1.18
retrieving revision 1.19
diff -u -r1.18 -r1.19
--- ChangeLog	8 May 2012 20:06:36 -0000	1.18
+++ ChangeLog	2 Jun 2014 04:34:22 -0000	1.19
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/w32api
-# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/w32api/ChangeLog,v 1.18 2012/05/08 20:06:36 vapier Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/w32api/ChangeLog,v 1.19 2014/06/02 04:34:22 vapier Exp $
+
+*w32api-4.0.3.1 (02 Jun 2014)
+
+  02 Jun 2014; Mike Frysinger <vapier@g.o> +w32api-4.0.3.1.ebuild:
+  Version bump #511492 by Yevgeny Filatov.
 
   08 May 2012; Mike Frysinger <vapier@g.o> w32api-3.14.ebuild,
   w32api-3.17.2.ebuild:



1.1                  dev-util/w32api/w32api-4.0.3.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/w32api/w32api-4.0.3.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/w32api/w32api-4.0.3.1.ebuild?rev=1.1&content-type=text/plain

Index: w32api-4.0.3.1.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/w32api/w32api-4.0.3.1.ebuild,v 1.1 2014/06/02 04:34:22 vapier Exp $

EAPI="4"

export CBUILD=${CBUILD:-${CHOST}}
export CTARGET=${CTARGET:-${CHOST}}
if [[ ${CTARGET} == ${CHOST} ]] ; then
	if [[ ${CATEGORY/cross-} != ${CATEGORY} ]] ; then
		export CTARGET=${CATEGORY/cross-}
	fi
fi

inherit eutils flag-o-matic toolchain-funcs

MY_P="${P:0:${#P}-2}-${PV:0-1}-mingw32"
DESCRIPTION="Free Win32 runtime and import library definitions"
HOMEPAGE="http://www.mingw.org/"
# http://sourceforge.net/projects/mingw/files/MinGW/Base/w32api/
SRC_URI="mirror://sourceforge/mingw/${MY_P}-src.tar.lzma"

LICENSE="BSD"
SLOT="0"
# Collides with mingw-runtime-4.x
#KEYWORDS="~amd64 ~ppc ~sparc ~x86"
IUSE="crosscompile_opts_headers-only"
RESTRICT="strip"

DEPEND="app-arch/xz-utils"
RDEPEND=""

S=${WORKDIR}/${MY_P/-m/.m}-src

just_headers() {
	use crosscompile_opts_headers-only && [[ ${CHOST} != ${CTARGET} ]]
}

pkg_setup() {
	if [[ ${CBUILD} == ${CHOST} ]] && [[ ${CHOST} == ${CTARGET} ]] ; then
		die "Invalid configuration; do not emerge this directly"
	fi
}

src_configure() {
	just_headers && return 0

	CHOST=${CTARGET} strip-unsupported-flags
	filter-flags -frecord-gcc-switches
	tc-export AR
	econf \
		--host=${CTARGET} \
		--prefix=/usr/${CTARGET}/usr \
		--docdir="${EPREFIX}/usr/share/doc/${PF}"
}

src_install() {
	if just_headers ; then
		insinto /usr/${CTARGET}/usr/include
		doins -r include/*
	else
		emake -j1 install DESTDIR="${D}"
		env -uRESTRICT CHOST=${CTARGET} prepallstrip

		# Make sure diff cross-compilers don't collide #414075
		mv "${D}"/usr/share/doc/{${PF},${CTARGET}-${PF}} || die
	fi
}