[gentoo-commits] gentoo-x86 commit in media-libs/allegro: ChangeLog allegro-4.2.2-r1.ebuild

[Tristan Heaven (nyhm)]

nyhm        08/06/01 15:55:51

  Modified:             ChangeLog
  Added:                allegro-4.2.2-r1.ebuild
  Log:
  Fix autoconf-2.62 failure, bug #218208; Install liballeg.so symlink, bug #220955
  (Portage version: 2.2_pre7/cvs/Linux 2.6.25.4 Intel(R) Core(TM)2 Duo CPU E6750 @ 2.66GHz)

Revision  Changes    Path
1.78                 media-libs/allegro/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/allegro/ChangeLog?rev=1.78&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/allegro/ChangeLog?rev=1.78&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/allegro/ChangeLog?r1=1.77&r2=1.78

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/allegro/ChangeLog,v
retrieving revision 1.77
retrieving revision 1.78
diff -u -r1.77 -r1.78
--- ChangeLog	13 May 2008 12:17:58 -0000	1.77
+++ ChangeLog	1 Jun 2008 15:55:51 -0000	1.78
@@ -1,6 +1,13 @@
 # ChangeLog for media-libs/allegro
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/allegro/ChangeLog,v 1.77 2008/05/13 12:17:58 fmccor Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/allegro/ChangeLog,v 1.78 2008/06/01 15:55:51 nyhm Exp $
+
+*allegro-4.2.2-r1 (01 Jun 2008)
+
+  01 Jun 2008; Tristan Heaven <nyhm@g.o>
+  +files/allegro-4.2.2-autoconf.patch, +allegro-4.2.2-r1.ebuild:
+  Fix autoconf-2.62 failure, bug #218208; Install liballeg.so symlink, bug
+  #220955
 
   13 May 2008; Ferris McCormick <fmccor@g.o> allegro-4.2.2.ebuild:
   Sparc stable, Bug #221821.



1.1                  media-libs/allegro/allegro-4.2.2-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/allegro/allegro-4.2.2-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/allegro/allegro-4.2.2-r1.ebuild?rev=1.1&content-type=text/plain

Index: allegro-4.2.2-r1.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/allegro/allegro-4.2.2-r1.ebuild,v 1.1 2008/06/01 15:55:51 nyhm Exp $

inherit autotools multilib eutils

DESCRIPTION="cross-platform multimedia library"
HOMEPAGE="http://alleg.sourceforge.net/"
SRC_URI="mirror://sourceforge/alleg/${P}.tar.gz"

LICENSE="Allegro"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="X alsa arts esd fbcon jack oss svga vga"

RDEPEND="alsa? ( media-libs/alsa-lib )
	esd? ( media-sound/esound )
	arts? ( kde-base/arts )
	X? (
		x11-libs/libX11
		x11-libs/libXcursor
		x11-libs/libXext
		x11-libs/libXpm
		x11-libs/libXt
		x11-libs/libXxf86dga
		x11-libs/libXxf86vm
	)
	svga? ( media-libs/svgalib )
	jack? ( media-sound/jack-audio-connection-kit )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	X? (
		x11-proto/xextproto
		x11-proto/xf86dgaproto
		x11-proto/xf86vidmodeproto
		x11-proto/xproto
	)"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch \
		"${FILESDIR}"/${P}-exec-stack.patch \
		"${FILESDIR}"/${P}-flags.patch \
		"${FILESDIR}"/${P}-autoconf.patch
	eautoreconf
}

src_compile() {
	econf \
		--enable-linux \
		--enable-static \
		--enable-staticprog \
		--disable-asm \
		--disable-mmx \
		--disable-sse \
		$(use_enable oss ossdigi) \
		$(use_enable oss ossmidi) \
		$(use_enable alsa alsadigi) \
		$(use_enable alsa alsamidi) \
		$(use_enable esd esddigi) \
		$(use_enable arts artsdigi) \
		$(use_with X x) \
		$(use_enable X xwin-shm) \
		$(use_enable X xwin-vidmode) \
		$(use_enable X xwin-dga) \
		$(use_enable X xwin-dga2) \
		$(use_enable fbcon) \
		$(use_enable svga svgalib) \
		$(use_enable vga) \
		$(use_enable jack jackdigi) \
		|| die
	emake -j1 || die "emake failed"
}

src_install() {
	emake -j1 DESTDIR="${D}" install || die "emake install failed"
	dosym liballeg-${PV}.so /usr/$(get_libdir)/liballeg.so \
		|| die "dosym failed"

	if use X ; then
		newbin setup/setup ${PN}-setup || die "newbin failed"
		insinto /usr/share/${PN}
		doins {keyboard,language,setup/setup}.dat || die "doins failed"
		newicon misc/alex.png ${PN}.png
		make_desktop_entry ${PN}-setup "Allegro Setup" ${PN} "Settings"
	fi

	dodoc AUTHORS CHANGES THANKS readme.txt todo.txt
	doman docs/man/*.3
	doinfo docs/info/${PN}.info
	dohtml docs/html/*
	docinto txt
	dodoc docs/txt/*.txt
	docinto rtf
	dodoc docs/rtf/*.rtf
	docinto build
	dodoc docs/build/*.txt
}

pkg_postinst() {
	ewarn "Please run \"revdep-rebuild --library liballeg.so.4.2\""
	ewarn "if you are upgrading allegro from 4.2.0."
}



-- 
gentoo-commits@l.g.o mailing list