[gentoo-commits] gentoo-x86 commit in net-fs/netatalk: netatalk-2.2.0.ebuild ChangeLog

[Steve Dibb (beandog)]

beandog     11/09/02 17:11:23

  Modified:             ChangeLog
  Added:                netatalk-2.2.0.ebuild
  Log:
  Version bump, bug 353177; Rename init script from atalk to netatalk; Restrict test; Add avahi use flag; Add GPL-2 as license
  
  (Portage version: 2.1.9.42/cvs/Linux x86_64)

Revision  Changes    Path
1.68                 net-fs/netatalk/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/netatalk/ChangeLog?rev=1.68&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/netatalk/ChangeLog?rev=1.68&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/netatalk/ChangeLog?r1=1.67&r2=1.68

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-fs/netatalk/ChangeLog,v
retrieving revision 1.67
retrieving revision 1.68
diff -u -r1.67 -r1.68
--- ChangeLog	4 Jan 2011 20:26:10 -0000	1.67
+++ ChangeLog	2 Sep 2011 17:11:23 -0000	1.68
@@ -1,6 +1,13 @@
 # ChangeLog for net-fs/netatalk
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-fs/netatalk/ChangeLog,v 1.67 2011/01/04 20:26:10 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-fs/netatalk/ChangeLog,v 1.68 2011/09/02 17:11:23 beandog Exp $
+
+*netatalk-2.2.0 (02 Sep 2011)
+
+  02 Sep 2011; Steve Dibb <beandog@g.o> +netatalk-2.2.0.ebuild,
+  +files/netatalk-2.2.0-path_afp_ipc.patch:
+  Version bump, bug 353177; Rename init script from atalk to netatalk; Restrict
+  test; Add avahi use flag; Add GPL-2 as license
 
 *netatalk-2.1.5 (04 Jan 2011)
 



1.1                  net-fs/netatalk/netatalk-2.2.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/netatalk/netatalk-2.2.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-fs/netatalk/netatalk-2.2.0.ebuild?rev=1.1&content-type=text/plain

Index: netatalk-2.2.0.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-fs/netatalk/netatalk-2.2.0.ebuild,v 1.1 2011/09/02 17:11:23 beandog Exp $

EAPI="2"

inherit pam

RESTRICT="test"
DESCRIPTION="Kernel level implementation of the AppleTalk Protocol Suite"
HOMEPAGE="http://netatalk.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"

LICENSE="GPL-2 BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="+avahi cracklib cups debug kerberos pam slp ssl tcpd xfs"

RDEPEND=">=sys-libs/db-4.2.52
	avahi? ( net-dns/avahi[dbus] )
	cracklib? ( sys-libs/cracklib )
	pam? ( virtual/pam )
	ssl? ( dev-libs/openssl )
	tcpd? ( sys-apps/tcp-wrappers )
	slp? ( net-libs/openslp )
	cups? ( net-print/cups )
	kerberos? ( virtual/krb5 )
	>=sys-apps/coreutils-7.1
	!app-text/yudit
	dev-libs/libgcrypt"
DEPEND="${RDEPEND}
	xfs? ( sys-fs/xfsprogs )"

src_prepare() {
	# until someone that understands their config script build
	# system gets a patch pushed upstream to make
	# --enable-srvloc passed to configure also add slpd to the
	# use line on the initscript, we'll need to do it this way
	if use slp ; then
		sed -i -e '/^[[:space:]]*use\>/s:$: slpd:' \
			distrib/initscripts/rc.atalk.gentoo.tmpl || die
	fi
	epatch "${FILESDIR}/${P}-path_afp_ipc.patch" || die "epatch failed"
}

src_configure() {
	use xfs || eval $(printf 'export ac_cv_header_%s=no\n' {linux,xfs}_{dqblk_xfs,libxfs,xqm,xfs_fs}_h)

	# Ignore --enable-gentoo, we install the init.d by hand and we avoid having
	# to sed the Makefiles to not do rc-update.
	# --enable-shadow: let build system detect shadow.h in toolchain
	econf \
		$(use_with pam) \
		$(use_enable avahi zeroconf) \
		$(use_enable cups) \
		$(use_enable debug) \
		$(use_enable tcpd tcp-wrappers) \
		$(use_enable kerberos krbV-uam) \
		--disable-krb4-uam \
		$(use_enable slp srvloc) \
		$(use_with ssl ssl-dir) \
		$(use_with cracklib) \
		--disable-afs \
		--enable-fhs \
		--with-bdb=/usr
}

src_compile() {
	emake || die

	# Create the init script manually (it's more messy to --enable-gentoo)
	emake -C distrib/initscripts rc.atalk.gentoo || die
}

src_install() {
	emake DESTDIR="${D}" install || die
	dodoc CONTRIBUTORS NEWS VERSION AUTHORS doc/README.AppleTalk

	newinitd distrib/initscripts/rc.atalk.gentoo netatalk || die

	# The pamd file isn't what we need, use pamd_mimic_system
	rm -rf "${D}/etc/pam.d"
	pamd_mimic_system netatalk auth account password session

	# Move /usr/include/netatalk to /usr/include/netatalk2 to avoid collisions
	# with /usr/include/netatalk/at.h provided by glibc (strange, uh?)
	# Packages that wants to link to netatalk should then probably change the
	# includepath then, but right now, nothing uses netatalk.
	# On a side note, it also solves collisions with freebsd-lib and other libcs
	mv "${D}"/usr/include/netatalk{,2} || die
	sed -i \
		-e 's/include <netatalk/include <netatalk2/g' \
		"${D}"usr/include/{netatalk2,atalk}/* || die
}