[gentoo-commits] gentoo-x86 commit in sci-visualization/fityk: ChangeLog fityk-0.9.6.ebuild fityk-0.9.3.ebuild

[Sebastien Fabbro (bicatali)]

bicatali    11/01/26 17:44:59

  Modified:             ChangeLog
  Added:                fityk-0.9.6.ebuild
  Removed:              fityk-0.9.3.ebuild
  Log:
  Version bump
  
  (Portage version: 2.1.9.35/cvs/Linux x86_64)

Revision  Changes    Path
1.14                 sci-visualization/fityk/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-visualization/fityk/ChangeLog?rev=1.14&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-visualization/fityk/ChangeLog?rev=1.14&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-visualization/fityk/ChangeLog?r1=1.13&r2=1.14

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-visualization/fityk/ChangeLog,v
retrieving revision 1.13
retrieving revision 1.14
diff -u -r1.13 -r1.14
--- ChangeLog	1 Dec 2010 23:17:36 -0000	1.13
+++ ChangeLog	26 Jan 2011 17:44:59 -0000	1.14
@@ -1,6 +1,12 @@
 # ChangeLog for sci-visualization/fityk
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-visualization/fityk/ChangeLog,v 1.13 2010/12/01 23:17:36 bicatali Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sci-visualization/fityk/ChangeLog,v 1.14 2011/01/26 17:44:59 bicatali Exp $
+
+*fityk-0.9.6 (26 Jan 2011)
+
+  26 Jan 2011; Sébastien Fabbro <bicatali@g.o> -fityk-0.9.3.ebuild,
+  +fityk-0.9.6.ebuild:
+  Version bump
 
 *fityk-0.9.4 (01 Dec 2010)
 



1.1                  sci-visualization/fityk/fityk-0.9.6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-visualization/fityk/fityk-0.9.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-visualization/fityk/fityk-0.9.6.ebuild?rev=1.1&content-type=text/plain

Index: fityk-0.9.6.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-visualization/fityk/fityk-0.9.6.ebuild,v 1.1 2011/01/26 17:44:59 bicatali Exp $

EAPI="3"

WX_GTK_VER="2.8"

PYTHON_DEPEND="python? 2"
SUPPORT_PYTHON_ABIS="1"

inherit python wxwidgets

DESCRIPTION="General-purpose nonlinear curve fitting and data analysis"
HOMEPAGE="http://fityk.nieto.pl/"
SRC_URI="http://cloud.github.com/downloads/wojdyr/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc examples gnuplot lua readline python static-libs wxwidgets"

CDEPEND=">=sci-libs/xylib-0.8
	lua? ( dev-lang/lua )
	readline? ( sys-libs/readline )
	wxwidgets? ( x11-libs/wxGTK:2.8 )"

DEPEND="${CDEPEND}
	dev-libs/boost
	>=sys-devel/libtool-2.2"

RDEPEND="${CDEPEND}
	gnuplot? ( sci-visualization/gnuplot )"

RESTRICT_PYTHON_ABIS="3.*"

src_prepare() {
	has_version "<dev-libs/boost-1.37" && \
		sed -i -e 's:impl/directives.hpp:directives.ipp:g' \
		"${S}/src/optional_suffix.h"

	sed '/^LTLIBRARIES/s:$(pyexec_LTLIBRARIES)::g' \
		-i swig/Makefile.in
	if use python; then
		echo '#!/bin/sh' > config/py-compile
	fi
}

src_configure() {
	econf  \
		--docdir="${EPREFIX}/usr/share/doc/${PF}" \
		--disable-xyconvert \
		$(use_enable lua) \
		$(use_enable python) \
		$(use_enable static-libs static) \
		$(use_enable wxwidgets GUI) \
		$(use_with doc) \
		$(use_with examples samples) \
		$(use_with readline)
}

src_compile() {
	default
	if use python; then
		python_copy_sources swig
		compilation() {
			emake \
				PYTHON_CPPFLAGS="-I$(python_get_includedir)" \
				PYTHON_LDFLAGS="$(python_get_library -l)" \
				PYTHON_SITE_PKG="$(python_get_sitedir)" \
				PYTHON_VERSION="$(python_get_version)" \
				pyexecdir="$(python_get_sitedir)" \
				_fityk.la
		}
		python_execute_function -s --source-dir swig compilation
	fi
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	if use python; then
		installation() {
			emake \
				DESTDIR="${D}" \
				pyexecdir="$(python_get_sitedir)" \
				pythondir="$(python_get_sitedir)" \
				install
		}
		python_execute_function -s --source-dir swig installation
		python_clean_installation_image
	fi
	dodoc NEWS README TODO
}

pkg_postinst() {
	use python && python_mod_optimize ${PN}.py
}

pkg_postrm() {
	use python && python_mod_cleanup ${PN}.py
}