[gentoo-commits] gentoo-x86 commit in dev-vcs/monotone: monotone-1.0.ebuild ChangeLog monotone-0.99.1.ebuild monotone-0.48.1.ebuild monotone-0.99-r1.ebuild

[Peter Volkov (pva)]

pva         11/09/05 13:33:03

  Modified:             ChangeLog monotone-0.99.1.ebuild
  Added:                monotone-1.0.ebuild
  Removed:              monotone-0.48.1.ebuild monotone-0.99-r1.ebuild
  Log:
  Version bump, bug #381135; updated monotone-0.99.1 to depend on <dev-libs/botan-1.10, bug 380257, thank Dennis Schridde for both reports. Drop old.
  
  (Portage version: 2.1.10.11/cvs/Linux x86_64)

Revision  Changes    Path
1.18                 dev-vcs/monotone/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/monotone/ChangeLog?rev=1.18&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/monotone/ChangeLog?rev=1.18&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/monotone/ChangeLog?r1=1.17&r2=1.18

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-vcs/monotone/ChangeLog,v
retrieving revision 1.17
retrieving revision 1.18
diff -u -r1.17 -r1.18
--- ChangeLog	13 Aug 2011 07:24:53 -0000	1.17
+++ ChangeLog	5 Sep 2011 13:33:03 -0000	1.18
@@ -1,6 +1,16 @@
 # ChangeLog for dev-vcs/monotone
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-vcs/monotone/ChangeLog,v 1.17 2011/08/13 07:24:53 xarthisius Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/monotone/ChangeLog,v 1.18 2011/09/05 13:33:03 pva Exp $
+
+*monotone-1.0 (05 Sep 2011)
+
+  05 Sep 2011; Peter Volkov <pva@g.o> -files/monotone-0.45-gcc45.patch,
+  -monotone-0.48.1.ebuild, -files/monotone-0.48.1-sqlite-3.7.3.patch,
+  -monotone-0.99-r1.ebuild, monotone-0.99.1.ebuild,
+  -files/monotone-0.99-crash.patch, +monotone-1.0.ebuild:
+  Version bump, bug #381135; updated monotone-0.99.1 to depend on
+  <dev-libs/botan-1.10, bug 380257, thank Dennis Schridde for both reports.
+  Drop old.
 
   13 Aug 2011; Kacper Kowalik <xarthisius@g.o> monotone-0.48.1.ebuild,
   monotone-0.99-r1.ebuild, monotone-0.99.1.ebuild:



1.5                  dev-vcs/monotone/monotone-0.99.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/monotone/monotone-0.99.1.ebuild?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/monotone/monotone-0.99.1.ebuild?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/monotone/monotone-0.99.1.ebuild?r1=1.4&r2=1.5

Index: monotone-0.99.1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-vcs/monotone/monotone-0.99.1.ebuild,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- monotone-0.99.1.ebuild	13 Aug 2011 07:24:53 -0000	1.4
+++ monotone-0.99.1.ebuild	5 Sep 2011 13:33:03 -0000	1.5
@@ -1,6 +1,6 @@
 # Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-vcs/monotone/monotone-0.99.1.ebuild,v 1.4 2011/08/13 07:24:53 xarthisius Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/monotone/monotone-0.99.1.ebuild,v 1.5 2011/09/05 13:33:03 pva Exp $
 
 EAPI="4"
 inherit bash-completion elisp-common eutils toolchain-funcs
@@ -18,6 +18,7 @@
 	emacs? ( virtual/emacs )
 	>=dev-libs/libpcre-7.6
 	>=dev-libs/botan-1.8.0
+	<dev-libs/botan-1.10
 	>=dev-db/sqlite-3.3.8
 	>=dev-lang/lua-5.1
 	net-dns/libidn"



1.1                  dev-vcs/monotone/monotone-1.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/monotone/monotone-1.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/monotone/monotone-1.0.ebuild?rev=1.1&content-type=text/plain

Index: monotone-1.0.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-vcs/monotone/monotone-1.0.ebuild,v 1.1 2011/09/05 13:33:03 pva Exp $

# QA failiures reported in https://code.monotone.ca/p/monotone/issues/181/
EAPI="4"
inherit bash-completion elisp-common eutils toolchain-funcs

DESCRIPTION="Monotone Distributed Version Control System"
HOMEPAGE="http://monotone.ca"
SRC_URI="http://monotone.ca/downloads/${PV}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="1"
KEYWORDS="~amd64 ~ia64 ~x86"
IUSE="doc emacs ipv6 nls"

RDEPEND="sys-libs/zlib
	emacs? ( virtual/emacs )
	>=dev-libs/libpcre-7.6
	>=dev-libs/botan-1.8.0
	>=dev-db/sqlite-3.3.8
	>=dev-lang/lua-5.1
	net-dns/libidn"
DEPEND="${RDEPEND}
	>=dev-libs/boost-1.33.1
	nls? ( >=sys-devel/gettext-0.11.5 )
	doc? ( sys-apps/texinfo )"

pkg_setup() {
	enewgroup monotone
	enewuser monotone -1 -1 /var/lib/monotone monotone
}

src_prepare() {
	if [[ $(gcc-major-version) -lt "3"  ||
		( $(gcc-major-version) -eq "3" && $(gcc-minor-version) -le 3 ) ]]; then
		die 'requires >=gcc-3.4'
	fi
}

src_configure() {
	econf \
		$(use_enable nls) \
		$(use_enable ipv6)
}

src_compile() {
	emake

	use doc && emake html

	if use emacs; then
		cd contrib || die
		elisp-compile *.el || die
	fi
}

src_test() {
	# Disables netsync_bind_opt test
	# https://code.monotone.ca/p/monotone/issues/179/
	export DISABLE_NETWORK_TESTS=true
	# bash_completion test fails too. Expected thus disab
	# https://code.monotone.ca/p/monotone/issues/180/
	rm test/extra/bash_completion/ -rf
	if [[ ${UID} != 0 ]]; then
		emake check
	else
		# Tests fail if run as root
		su portage emake check
	fi
}

src_install() {
	emake DESTDIR="${D}" install

	mv "${ED}"/usr/share/doc/${PN} "${ED}"/usr/share/doc/${PF} || die

	dobashcompletion contrib/monotone.bash_completion

	if use doc; then
		dohtml -r html/*
		dohtml -r figures
	fi

	if use emacs; then
		elisp-install ${PN} contrib/*.{el,elc} || die "elisp-install failed"
		elisp-site-file-install "${FILESDIR}"/50${PN}-gentoo.el \
			|| die
	fi

	dodoc AUTHORS NEWS README* UPGRADE
	docinto contrib
	docompress -x /usr/share/doc/${PF}/contrib
	dodoc -r contrib
	newconfd "${FILESDIR}"/monotone.confd monotone
	newinitd "${FILESDIR}"/${PN}-0.36.initd monotone

	insinto /etc/monotone
	newins "${FILESDIR}"/hooks.lua hooks.lua
	newins "${FILESDIR}"/read-permissions read-permissions
	newins "${FILESDIR}"/write-permissions write-permissions

	keepdir /var/lib/monotone/keys/ /var/{log,run}/monotone
	fowners monotone:monotone /var/lib/monotone{,/keys} /var/{log,run}/monotone
}

pkg_postinst() {
	use emacs && elisp-site-regen
	bash-completion_pkg_postinst

	elog
	elog "For details and instructions to upgrade from previous versions,"
	elog "please read /usr/share/doc/${PF}/UPGRADE.bz2"
	elog
	elog "  1. edit /etc/conf.d/monotone"
	elog "  2. import the first keys to enable access with"
	elog "     env HOME=\${homedir} mtn pubkey me@×××××××.net | /etc/init.d/monotone import"
	elog "     Thereafter, those with write permission can add other keys via"
	elog "     netsync with 'monotone push --key-to-push=IDENT' and then IDENT"
	elog "     can be used in the read-permission and write-permission files."
	elog "  3. adjust permisions in /etc/monotone/read-permissions"
	elog "                      and /etc/monotone/write-permissions"
	elog "  4. start the daemon: /etc/init.d/monotone start"
	elog "  5. make persistent: rc-update add monotone default"
	elog
}

pkg_postrm() {
	use emacs && elisp-site-regen
}