[gentoo-commits] repo/gentoo:master commit in: dev-python/django/

[Michał Górny]

commit:     6616bc16290a75dde41c78a7bc0a42756f4ace87
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Mon Feb  1 16:38:54 2021 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Mon Feb  1 17:04:18 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6616bc16

dev-python/django: Bump to 2.2.18

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/django/Manifest             |  2 +
 dev-python/django/django-2.2.18.ebuild | 94 ++++++++++++++++++++++++++++++++++
 2 files changed, 96 insertions(+)

diff --git a/dev-python/django/Manifest b/dev-python/django/Manifest
index bdbcbcd0713..638384b6b80 100644
--- a/dev-python/django/Manifest
+++ b/dev-python/django/Manifest
@@ -1,5 +1,7 @@
 DIST Django-2.2.17.checksum.txt 2438 BLAKE2B 5d9454884110f1debec7fa1644b13be43b9b6b8d3f333a05df823332c94a6f4a220791bf0cc7d139baf5aac856443a4b211dd8e98d23d4cc62d1d6ce7ebd69c8 SHA512 0dc71edfe3264d3353238124dc5374aac07fb73ede167a52f16bf3b147bf351651f4197a1fe5027dca23ad144755fff6447f06d8cdf11126184cf5e291c90402
 DIST Django-2.2.17.tar.gz 8885492 BLAKE2B 30046adc54c31e0e8dac3c573da58e8536246ba6fc5675ec5ad5efc4b170331b893ffe766e7eb404b445d5b37e018e1ac9e2b8e659a5f10c4c165ec9ef5c00d1 SHA512 4ba1e12332cafaa49a087494f9e85e992a414ad153ef935fcf50f1a533ac9c7049a421140552f77b3dbf41c51a4f42aca13dc5f8f479049c21037c541a34320b
+DIST Django-2.2.18.checksum.txt 2556 BLAKE2B a2cbb2f10c8173bfbb29033d2e33035a04ce0a6c997a3930f4fc59951e46ea31df23a664df1a11b7d652d7efb794b55d7dadb4e0868245afbb2951f630b674c9 SHA512 f48fda050be7d88783bdbdeafc5bf8dd130eb43b7ff08bb1ac7602f5e94615cb2f02a05787dbb025df3f01d70f789d03220651b8217de5ba48cffadb0d57ba7d
+DIST Django-2.2.18.tar.gz 9180844 BLAKE2B 4001c89674dacaddea279e4e9484cc820a18115bda3a0f8091797fd0924ee7b9aad0e520b1bda21b539e8b140dc473154e4cd6f11a16fb706dd3ee8e7dd8679f SHA512 8c38330042244513576151a9ae64293b9838df42dcb4204713859dd8fcd81154edf42738d0bd05770c9bbe13bfdb1f73781453cf1d14fbc31149a2cb89e34b59
 DIST Django-3.0.11.checksum.txt 2438 BLAKE2B df936992a02e5a34b26e91654962507d973f8831c1eebada4cbdb578f83fba974532867b9f20828afc2467c2521e117b8dd543cde6f664d3c122a95207c50608 SHA512 a7b98d102775cc7854b0c242507d4ff8778984dc8b2e269352103249d6d1c5cea7e6eb8dbe08700b19ad4428e30c469e0e959a622ea4ce3198a75f72b2bb8871
 DIST Django-3.0.11.tar.gz 8958879 BLAKE2B 078ffde9ae186ae8add2136c303ba38a1b38525481b2272384b8a1bb3428dcf6a31991a86b2078aea6cf250808af399acac5461a33c8e1fda5d6bc552eac478f SHA512 d24e8167f3f871f24ea5e288557a49d71f9b5c398c84e8434d5d3dc224ef62775121a016ad89e997fabe88893adc3a83176211d5b9a9730ec23d37d256aa4fb0
 DIST Django-3.0.12.checksum.txt 2556 BLAKE2B 9012a130029c6fe73ace78fbdd32f1653bb7a7e84c343c394acc5563b7de9b5d6ec58734fdf79f2e7657f18644dd3a12c12c4a400a1002ad74d0891738ef4137 SHA512 46e7291f4d73472a118ff3aca4f597d6abde4a4217bb95ed84fda91efd0ed63e946d9ddf35ae65ff1e898462aebc32a3a43241f261099b17667958412d5afb32

diff --git a/dev-python/django/django-2.2.18.ebuild b/dev-python/django/django-2.2.18.ebuild
new file mode 100644
index 00000000000..8f0c89ec277
--- /dev/null
+++ b/dev-python/django/django-2.2.18.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{7..8} )
+PYTHON_REQ_USE='sqlite?,threads(+)'
+
+inherit bash-completion-r1 distutils-r1 optfeature verify-sig
+
+MY_P=${P^}
+DESCRIPTION="High-level Python web framework"
+HOMEPAGE="https://www.djangoproject.com/ https://pypi.org/project/Django/"
+SRC_URI="
+	https://media.djangoproject.com/releases/$(ver_cut 1-2)/${MY_P}.tar.gz
+	verify-sig? ( https://media.djangoproject.com/pgp/${MY_P}.checksum.txt )"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD"
+# admin fonts: Roboto (media-fonts/roboto)
+LICENSE+=" Apache-2.0"
+# admin icons, jquery, xregexp.js
+LICENSE+=" MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
+IUSE="doc sqlite test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/pytz[${PYTHON_USEDEP}]
+	>=dev-python/sqlparse-0.2.2[${PYTHON_USEDEP}]"
+BDEPEND="
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		$(python_gen_impl_dep sqlite)
+		${RDEPEND}
+		dev-python/docutils[${PYTHON_USEDEP}]
+		dev-python/jinja[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pillow[webp,${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/selenium[${PYTHON_USEDEP}]
+		dev-python/tblib[${PYTHON_USEDEP}]
+		sys-devel/gettext
+	)
+	verify-sig? ( app-crypt/openpgp-keys-django )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.0.7-bashcomp.patch
+)
+
+distutils_enable_sphinx docs --no-autodoc
+
+VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/django.asc
+
+src_unpack() {
+	if use verify-sig; then
+		cd "${DISTDIR}" || die
+		verify-sig_verify_signed_checksums \
+			"${MY_P}.checksum.txt" sha256 "${MY_P}.tar.gz"
+		cd "${WORKDIR}" || die
+	fi
+
+	default
+}
+
+python_test() {
+	# Tests have non-standard assumptions about PYTHONPATH,
+	# and don't work with ${BUILD_DIR}/lib.
+	PYTHONPATH=. "${EPYTHON}" tests/runtests.py --settings=test_sqlite -v2 ||
+		die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	newbashcomp extras/django_bash_completion ${PN}-admin
+	bashcomp_alias ${PN}-admin django-admin.py
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	elog "Additional Backend support can be enabled via"
+	optfeature "MySQL backend support" dev-python/mysqlclient
+	optfeature "PostgreSQL backend support" dev-python/psycopg:2
+	elog
+	elog "Other features can be enhanced by"
+	optfeature "GEO Django" "sci-libs/gdal[geos]"
+	optfeature "Memcached support" dev-python/pylibmc dev-python/python-memcached
+	optfeature "ImageField Support" dev-python/pillow
+	optfeature "Password encryption" dev-python/bcrypt
+	optfeature "High-level abstractions for Django forms" dev-python/django-formtools
+}