[gentoo-commits] repo/gentoo:master commit in: app-vim/python-mode/

[Michał Górny]

commit:     b82a469c7cacd58d40b4d934d49c0d7316525ebe
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Apr 21 16:29:16 2017 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sat May 27 15:19:20 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b82a469c

app-vim/python-mode: Port to python-single-r1

 app-vim/python-mode/python-mode-0.6.18-r4.ebuild | 62 ++++++++++++++++++++++++
 1 file changed, 62 insertions(+)

diff --git a/app-vim/python-mode/python-mode-0.6.18-r4.ebuild b/app-vim/python-mode/python-mode-0.6.18-r4.ebuild
new file mode 100644
index 00000000000..e8f195d59fa
--- /dev/null
+++ b/app-vim/python-mode/python-mode-0.6.18-r4.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+VIM_PLUGIN_MESSAGES="filetype"
+VIM_PLUGIN_HELPFILES="PythonModeCommands"
+VIM_PLUGIN_HELPURI="https://github.com/klen/python-mode"
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit python-single-r1 vim-plugin
+
+DESCRIPTION="Provide python code looking for bugs, refactoring and other useful things"
+HOMEPAGE="http://www.vim.org/scripts/script.php?script_id=3770 https://github.com/klen/python-mode"
+SRC_URI="https://github.com/klen/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-3"
+KEYWORDS="~amd64 ~x86"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	|| (
+		app-editors/vim[python,${PYTHON_USEDEP}]
+		app-editors/gvim[python,${PYTHON_USEDEP}]
+	)
+	dev-python/astng[${PYTHON_USEDEP}]
+	dev-python/autopep8[${PYTHON_USEDEP}]
+	dev-python/pyflakes[${PYTHON_USEDEP}]
+	dev-python/pylint[${PYTHON_USEDEP}]
+	dev-python/rope[${PYTHON_USEDEP}]
+	dev-python/ropemode[${PYTHON_USEDEP}]"
+
+src_prepare() {
+	eapply "${FILESDIR}"/${P}-dont-add-cwd-to-syspath.patch
+	eapply_user
+
+	# debundling fun
+	rm -rf pylibs/pylama/{pep8.py,pyflakes} pylibs/{autopep8.py}
+	#rm -rf pylibs/{rope,ropemode}  #475686
+	sed -e 's/from .pep8/from pep8/g' \
+		-e 's/from .pyflakes/from pyflakes/g' \
+		-i pylibs/pylama/utils.py || die
+	# there's still pylint left, I failed to debundle it :/
+
+	mv pylint.ini "${T}" || die
+	sed -e "s|expand(\"<sfile>:p:h:h\")|\"${EPREFIX}/usr/share/${PN}\"|" \
+		-i autoload/pymode.vim || die # use custom path
+}
+
+src_install() {
+	vim-plugin_src_install
+	insinto usr/share/${PN}
+	doins "${T}"/pylint.ini
+}
+
+pkg_postinst() {
+	vim-plugin_pkg_postinst
+	einfo "If you use custom pylintrc make sure you append the contents of"
+	einfo " ${EPREFIX}/usr/share/${PN}/pylint.ini"
+	einfo "to it. Otherwise PyLint command will not work properly."
+}