[gentoo-commits] gentoo-x86 commit in dev-lang/parrot: parrot-2.9.1.ebuild ChangeLog

[Patrick Lauer (patrick)]

patrick     10/11/01 13:38:21

  Modified:             ChangeLog
  Added:                parrot-2.9.1.ebuild
  Log:
  Bump for #343267
  
  (Portage version: 2.2.0_alpha3/cvs/Linux x86_64)

Revision  Changes    Path
1.38                 dev-lang/parrot/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/parrot/ChangeLog?rev=1.38&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/parrot/ChangeLog?rev=1.38&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/parrot/ChangeLog?r1=1.37&r2=1.38

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/parrot/ChangeLog,v
retrieving revision 1.37
retrieving revision 1.38
diff -u -r1.37 -r1.38
--- ChangeLog	16 Sep 2010 16:40:21 -0000	1.37
+++ ChangeLog	1 Nov 2010 13:38:21 -0000	1.38
@@ -1,6 +1,11 @@
 # ChangeLog for dev-lang/parrot
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/parrot/ChangeLog,v 1.37 2010/09/16 16:40:21 scarabeus Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/parrot/ChangeLog,v 1.38 2010/11/01 13:38:21 patrick Exp $
+
+*parrot-2.9.1 (01 Nov 2010)
+
+  01 Nov 2010; Patrick Lauer <patrick@g.o> +parrot-2.9.1.ebuild:
+  Bump for #343267
 
   16 Sep 2010; Tomáš Chvátal <scarabeus@g.o> parrot-2.6.0.ebuild,
   parrot-2.7.0.ebuild:



1.1                  dev-lang/parrot/parrot-2.9.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/parrot/parrot-2.9.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/parrot/parrot-2.9.1.ebuild?rev=1.1&content-type=text/plain

Index: parrot-2.9.1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-lang/parrot/parrot-2.9.1.ebuild,v 1.1 2010/11/01 13:38:21 patrick Exp $

EAPI=3

inherit eutils multilib

DESCRIPTION="Virtual machine designed to efficiently compile and execute bytecode for dynamic languages"
HOMEPAGE="http://www.parrot.org/"
#SRC_URI="ftp://ftp.parrot.org/pub/parrot/releases/supported/${PV}/${P}.tar.bz2"
SRC_URI="ftp://ftp.parrot.org/pub/parrot/releases/stable/${PV}/${P}.tar.bz2"

LICENSE="Artistic-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="opengl nls doc examples gdbm gmp ssl +unicode pcre"

RDEPEND="sys-libs/readline
	opengl? ( media-libs/freeglut )
	nls? ( sys-devel/gettext )
	unicode? ( >=dev-libs/icu-2.6 )
	gdbm? ( >=sys-libs/gdbm-1.8.3-r1 )
	gmp? ( >=dev-libs/gmp-4.1.4 )
	ssl? ( dev-libs/openssl )
	pcre? ( dev-libs/libpcre )"

DEPEND="dev-lang/perl[doc?]
	${RDEPEND}"

src_configure() {
	myconf="--disable-rpath"
	use unicode || myconf+=" --without-icu"
	use ssl     || myconf+=" --without-crypto"
	use gdbm    || myconf+=" --without-gdbm"
	use nls     || myconf+=" --without-gettext"
	use gmp     || myconf+=" --without-gmp"
	use opengl  || myconf+=" --without-opengl"
	use pcre    || myconf+=" --without-pcre"

	perl Configure.pl \
		--ccflags="${CFLAGS}" \
		--linkflags="${LDFLAGS}" \
		--prefix="${EROOT}"/usr \
		--libdir="${EROOT}"/usr/$(get_libdir) \
		--mandir="${EROOT}"/usr/share/man \
		--sysconfdir="${EROOT}"/etc \
		--sharedstatedir="${EROOT}"/var/lib/parrot \
		--pkgconfigdir=pkgconfig \
		$myconf || die
}

src_compile() {
	export LD_LIBRARY_PATH=${LD_LIBRARY_PATH:+$LD_LIBRARY_PATH:}"${S}"/blib/lib
	# occasionally dies in parallel make
	emake -j1 || die
	if use doc ; then
		emake -j1 html || die
	fi
}

src_test() {
	emake -j1 test || die
}

src_install() {
	emake -j1 install-dev DESTDIR="${ED}" DOC_DIR="${EROOT}/usr/share/doc/${PF}" || die
	dodoc CREDITS DEPRECATED.pod DONORS.pod NEWS PBC_COMPAT PLATFORMS RESPONSIBLE_PARTIES TODO || die
	if use examples; then
		insinto "${EROOT}/usr/share/doc/${PF}/examples"
		doins -r examples/* || die
	fi
	if use doc; then
		insinto "${EROOT}/usr/share/doc/${PF}/editor"
		doins -r editor || die
		cd docs/html
		dohtml -r developer.html DONORS.pod.html index.html ops.html parrotbug.html pdds.html \
			pmc.html tools.html docs src tools || die
	fi
}