[gentoo-commits] gentoo-x86 commit in sys-cluster/vzctl: vzctl-9999.ebuild ChangeLog vzctl-3.0.26.2-r1.ebuild

[Peter Volkov (pva)]

pva         11/04/01 11:34:55

  Modified:             vzctl-9999.ebuild ChangeLog
  Added:                vzctl-3.0.26.2-r1.ebuild
  Log:
  Added note about vzeventd. Added support for solid kernel, #361457. Enable reboot notification, fixes #361453. Thank Andreis_Vinogradovs (slepnoga) for finding all of this.
  
  (Portage version: 2.1.9.45/cvs/Linux x86_64)

Revision  Changes    Path
1.7                  sys-cluster/vzctl/vzctl-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/vzctl/vzctl-9999.ebuild?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/vzctl/vzctl-9999.ebuild?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/vzctl/vzctl-9999.ebuild?r1=1.6&r2=1.7

Index: vzctl-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-cluster/vzctl/vzctl-9999.ebuild,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- vzctl-9999.ebuild	22 Mar 2011 16:28:14 -0000	1.6
+++ vzctl-9999.ebuild	1 Apr 2011 11:34:55 -0000	1.7
@@ -1,6 +1,6 @@
 # Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-cluster/vzctl/vzctl-9999.ebuild,v 1.6 2011/03/22 16:28:14 pva Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/vzctl/vzctl-9999.ebuild,v 1.7 2011/04/01 11:34:55 pva Exp $
 
 EAPI="4"
 
@@ -19,8 +19,7 @@
 	net-firewall/iptables
 	sys-apps/ed
 	sys-apps/iproute2
-	sys-fs/vzquota
-	virtual/cron"
+	sys-fs/vzquota"
 
 DEPEND="${RDEPEND}"
 
@@ -77,16 +76,9 @@
 	ewarn " postup() {"
 	ewarn "     /usr/sbin/vzifup-post \${IFACE}"
 	ewarn " }"
-
-	elog "NOTE: Starting with vzctl-3.0.22 the mechanism for choosing the"
-	elog "interfaces to send ARP requests to has been improved (see description"
-	elog "of NEIGHBOUR_DEVS in vz.conf(5) man page). In case CT IP addresses"
-	elog "are not on the same subnet as HN IPs, it may lead to such CTs being"
-	elog "unreachable from the outside world."
-	elog
-	elog "The solution is to set up a device route(s) for the network your CTs are"
-	elog "in. For more details, see http://bugzilla.openvz.org/show_bug.cgi?id=771#c1"
-	elog
-	elog "The old vzctl behavior can be restored by setting NEIGHBOUR_DEVS to any"
-	elog 'value other than "detect" in /etc/vz/vz.conf.'
+	ewarn
+	ewarn "Starting with 3.0.25 there is new vzeventd service to reboot CTs."
+	ewarn "Please, drop /usr/share/vzctl/scripts/vpsnetclean and"
+	ewarn "/usr/share/vzctl/scripts/vpsreboot from crontab and use"
+	ewarn "/etc/init.d/vzeventd."
 }



1.75                 sys-cluster/vzctl/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/vzctl/ChangeLog?rev=1.75&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/vzctl/ChangeLog?rev=1.75&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/vzctl/ChangeLog?r1=1.74&r2=1.75

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-cluster/vzctl/ChangeLog,v
retrieving revision 1.74
retrieving revision 1.75
diff -u -r1.74 -r1.75
--- ChangeLog	22 Mar 2011 16:28:14 -0000	1.74
+++ ChangeLog	1 Apr 2011 11:34:55 -0000	1.75
@@ -1,6 +1,14 @@
 # ChangeLog for sys-cluster/vzctl
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-cluster/vzctl/ChangeLog,v 1.74 2011/03/22 16:28:14 pva Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-cluster/vzctl/ChangeLog,v 1.75 2011/04/01 11:34:55 pva Exp $
+
+*vzctl-3.0.26.2-r1 (01 Apr 2011)
+
+  01 Apr 2011; Peter Volkov <pva@g.o> +vzctl-3.0.26.2-r1.ebuild,
+  +files/vzctl-3.0.26.2-vzeventd.patch, vzctl-9999.ebuild:
+  Added note about vzeventd. Added support for solid kernel, #361457. Enable
+  reboot notification, fixes #361453. Thank Andreis_Vinogradovs (slepnoga) for
+  finding all of this.
 
 *vzctl-3.0.26.2 (22 Mar 2011)
 



1.1                  sys-cluster/vzctl/vzctl-3.0.26.2-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/vzctl/vzctl-3.0.26.2-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-cluster/vzctl/vzctl-3.0.26.2-r1.ebuild?rev=1.1&content-type=text/plain

Index: vzctl-3.0.26.2-r1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-cluster/vzctl/vzctl-3.0.26.2-r1.ebuild,v 1.1 2011/04/01 11:34:55 pva Exp $

EAPI="4"

inherit bash-completion eutils

DESCRIPTION="OpenVZ ConTainers control utility"
HOMEPAGE="http://openvz.org/"
SRC_URI="http://download.openvz.org/utils/${PN}/${PV}/src/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ia64 ~ppc64 ~sparc ~x86"
IUSE="bash-completion"

RDEPEND="
	net-firewall/iptables
	sys-apps/ed
	sys-apps/iproute2
	sys-fs/vzquota"

DEPEND="${RDEPEND}"

src_prepare() {
	# Set default OSTEMPLATE on gentoo
	sed -e 's:=redhat-:=gentoo-:' -i etc/dists/default || die
	epatch "${FILESDIR}/vzctl-3.0.26.2-vzeventd.patch"
}

src_configure() {
	econf \
		--localstatedir=/var \
		--enable-udev \
		$(use_enable bash-completion bashcomp) \
		--enable-logrotate
}

src_install() {
	emake DESTDIR="${D}" install install-gentoo

	# install the bash-completion script into the right location
	rm -rf "${ED}"/etc/bash_completion.d
	dobashcompletion etc/bash_completion.d/vzctl.sh vzctl

	# We need to keep some dirs
	keepdir /vz/{dump,lock,root,private,template/cache}
	keepdir /etc/vz/names /var/lib/vzctl/veip
}

pkg_postinst() {
	bash-completion_pkg_postinst
	local conf_without_OSTEMPLATE
	for file in \
		$(find "${EROOT}/etc/vz/conf/" \( -name *.conf -a \! -name 0.conf \)); do
		if ! grep '^OSTEMPLATE' $file > /dev/null; then
			conf_without_OSTEMPLATE+=" $file"
		fi
	done

	if [[ -n ${conf_without_OSTEMPLATE} ]]; then
		ewarn
		ewarn "OSTEMPLATE default was changed from redhat-like to gentoo."
		ewarn "This means that any VEID.conf files without explicit or correct"
		ewarn "OSTEMPLATE set will use gentoo scripts instead of redhat."
		ewarn "Please check the following configs:"
		for file in ${conf_without_OSTEMPLATE}; do
			ewarn "${file}"
		done
		ewarn
	fi

	ewarn "To avoid loosing network to CTs on iface down/up, please, add the"
	ewarn "following code to /etc/conf.d/net:"
	ewarn " postup() {"
	ewarn "     /usr/sbin/vzifup-post \${IFACE}"
	ewarn " }"
	ewarn
	ewarn "Starting with 3.0.25 there is new vzeventd service to reboot CTs."
	ewarn "Please, drop /usr/share/vzctl/scripts/vpsnetclean and"
	ewarn "/usr/share/vzctl/scripts/vpsreboot from crontab and use"
	ewarn "/etc/init.d/vzeventd."
}