[gentoo-commits] repo/gentoo:master commit in: dev-python/black/

[Michał Górny]

commit:     84100aa99ab45a4ae9857e9e3ea54335772ef999
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Jan 30 07:19:39 2022 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Jan 30 07:19:39 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=84100aa9

dev-python/black: Bump to 22.1.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/black/Manifest            |  1 +
 dev-python/black/black-22.1.0.ebuild | 49 ++++++++++++++++++++++++++++++++++++
 2 files changed, 50 insertions(+)

diff --git a/dev-python/black/Manifest b/dev-python/black/Manifest
index 200f21f8b85d..20ba92e03eea 100644
--- a/dev-python/black/Manifest
+++ b/dev-python/black/Manifest
@@ -1 +1,2 @@
 DIST black-21.12b0.tar.gz 1200305 BLAKE2B cd019b230d2ba1fab88075a5e14cb5de88a4ee283b53d869564f071a104d2810ca31c04db09310b99a1610bdace7d5b9b360b2a3a4810822322a4eacc8998ad8 SHA512 1f6e4eeafd653fa9db608585110f5c5067942031b2d67e630befa899d7fca3c35f52cbde8fc91c2697fb294fb16525254756ebce16e556fc139b621f738bfa22
+DIST black-22.1.0.tar.gz 1161720 BLAKE2B d74cbdd39dc1576583cee57089cb6d75a338f2d6640697adda79d38d02eeb51664049dca934d5014761d0fd4080ca2f40a3ea10c30e40bde9fe6af6c178b202c SHA512 9b97a3b32ecebebeb61ea581784a9b2215540c20533097fe87d5ef3c046dbe7c2ab8f2f21d1884cbe0ddd458434f17eb9b540764f955385873e6fdef86c3014c

diff --git a/dev-python/black/black-22.1.0.ebuild b/dev-python/black/black-22.1.0.ebuild
new file mode 100644
index 000000000000..40f9911a807b
--- /dev/null
+++ b/dev-python/black/black-22.1.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 2020-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1 optfeature
+
+MY_PV="${PV//_beta/b}"
+MY_P="${PN}-${MY_PV}"
+
+DESCRIPTION="The uncompromising Python code formatter"
+HOMEPAGE="https://black.readthedocs.io/en/stable/ https://github.com/psf/black"
+SRC_URI="https://github.com/psf/${PN}/archive/${MY_PV}.tar.gz -> ${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	>=dev-python/click-8.0.0[${PYTHON_USEDEP}]
+	>=dev-python/mypy_extensions-0.4.3[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2[${PYTHON_USEDEP}]
+	>=dev-python/pathspec-0.9.0[${PYTHON_USEDEP}]
+	>=dev-python/tomli-1.1.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/typing-extensions-3.10.0.0[${PYTHON_USEDEP}]
+	' python3_{8..9})
+"
+BDEPEND="
+	>=dev-python/setuptools_scm-6.3.1[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/aiohttp-3.7.4[${PYTHON_USEDEP}]
+		dev-python/aiohttp-cors[${PYTHON_USEDEP}]
+		dev-python/colorama[${PYTHON_USEDEP}]
+		dev-python/parameterized[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=${MY_PV}
+
+pkg_postinst() {
+	optfeature "blackd - HTTP API for black" "dev-python/aiohttp dev-python/aiohttp-cors"
+}