[gentoo-commits] gentoo-x86 commit in dev-libs/leveldb: leveldb-1.18-r1.ebuild ChangeLog

[Mike Frysinger (vapier)]

vapier      15/03/06 09:12:42

  Modified:             ChangeLog
  Added:                leveldb-1.18-r1.ebuild
  Log:
  Fix USE=-snappy handling #541186 by Johan Bergström. Move memenv.h header to leveldb/helpers/ to match Debian.
  
  (Portage version: 2.2.17/cvs/Linux x86_64, signed Manifest commit with key D2E96200)

Revision  Changes    Path
1.28                 dev-libs/leveldb/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/leveldb/ChangeLog?rev=1.28&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/leveldb/ChangeLog?rev=1.28&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/leveldb/ChangeLog?r1=1.27&r2=1.28

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/leveldb/ChangeLog,v
retrieving revision 1.27
retrieving revision 1.28
diff -u -r1.27 -r1.28
--- ChangeLog	21 Feb 2015 18:34:07 -0000	1.27
+++ ChangeLog	6 Mar 2015 09:12:42 -0000	1.28
@@ -1,6 +1,13 @@
 # ChangeLog for dev-libs/leveldb
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/leveldb/ChangeLog,v 1.27 2015/02/21 18:34:07 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/leveldb/ChangeLog,v 1.28 2015/03/06 09:12:42 vapier Exp $
+
+*leveldb-1.18-r1 (06 Mar 2015)
+
+  06 Mar 2015; Mike Frysinger <vapier@g.o>
+  +files/leveldb-1.18-configure.patch, +leveldb-1.18-r1.ebuild:
+  Fix USE=-snappy handling #541186 by Johan Bergström. Move memenv.h header to
+  leveldb/helpers/ to match Debian.
 
 *leveldb-1.18 (21 Feb 2015)
 



1.1                  dev-libs/leveldb/leveldb-1.18-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/leveldb/leveldb-1.18-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/leveldb/leveldb-1.18-r1.ebuild?rev=1.1&content-type=text/plain

Index: leveldb-1.18-r1.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/leveldb/leveldb-1.18-r1.ebuild,v 1.1 2015/03/06 09:12:42 vapier Exp $

EAPI=5

inherit eutils multilib toolchain-funcs versionator

DESCRIPTION="a fast key-value storage library written at Google"
HOMEPAGE="http://leveldb.org/ https://github.com/google/leveldb"
SRC_URI="https://github.com/google/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~mips ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
IUSE="+snappy static-libs +tcmalloc"

DEPEND="tcmalloc? ( dev-util/google-perftools )
	snappy? (
		app-arch/snappy
		static-libs? ( app-arch/snappy[static-libs] )
	)"
RDEPEND="${DEPEND}"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-1.18-mips.patch
	epatch "${FILESDIR}"/${PN}-1.18-configure.patch #541186

	local SHARED_MINOR=$(get_version_component_range 2)
	sed \
		-e "s/\(^ SHARED_MINOR =\).*/\1 ${SHARED_MINOR}/" \
		"${FILESDIR}/${PN}-1.9.0-memenv-so.patch" > memenv-so.patch
	epatch memenv-so.patch
}

src_configure() {
	# These vars all get picked up by build_detect_platform
	# which the Makefile runs for us automatically.
	tc-export AR CC CXX
	export OPT="-DNDEBUG ${CPPFLAGS}"

	TARGET_OS="Linux" \
	USE_SNAPPY=$(usex snappy) \
	USE_TCMALLOC=no \
	TMPDIR=${T} \
	sh -x ./build_detect_platform build_config.mk ./
}

src_compile() {
	emake $(usex static-libs 'libmemenv.a' 'LIBRARY=') all libmemenv.SHARED
}

src_test() {
	emake check
}

src_install() {
	insinto /usr/include
	doins -r include/*
	# This matches the path Debian picked.  Upstream provides no guidance.
	insinto /usr/include/leveldb/helpers
	doins helpers/memenv/memenv.h

	dolib.so libleveldb*$(get_libname)*
	use static-libs && dolib.a libleveldb.a libmemenv.a
	dolib.so libmemenv*$(get_libname)*
}