[gentoo-commits] gentoo-x86 commit in dev-libs/opensc: opensc-0.12.2-r2.ebuild ChangeLog opensc-0.12.2-r1.ebuild

[Diego Petteno (flameeyes)]

flameeyes    12/08/26 23:40:02

  Modified:             ChangeLog
  Added:                opensc-0.12.2-r2.ebuild
  Removed:              opensc-0.12.2-r1.ebuild
  Log:
  Fix bug #432770 thanks to Maxim Kammerer.
  
  (Portage version: 2.2.0_alpha122/cvs/Linux x86_64)

Revision  Changes    Path
1.124                dev-libs/opensc/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/opensc/ChangeLog?rev=1.124&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/opensc/ChangeLog?rev=1.124&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/opensc/ChangeLog?r1=1.123&r2=1.124

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/opensc/ChangeLog,v
retrieving revision 1.123
retrieving revision 1.124
diff -u -r1.123 -r1.124
--- ChangeLog	24 Jun 2012 08:18:12 -0000	1.123
+++ ChangeLog	26 Aug 2012 23:40:02 -0000	1.124
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/opensc
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/opensc/ChangeLog,v 1.123 2012/06/24 08:18:12 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/opensc/ChangeLog,v 1.124 2012/08/26 23:40:02 flameeyes Exp $
+
+*opensc-0.12.2-r2 (26 Aug 2012)
+
+  26 Aug 2012; Diego E. Pettenò <flameeyes@g.o> +opensc-0.12.2-r2.ebuild,
+  -opensc-0.12.2-r1.ebuild:
+  Fix bug #432770 thanks to Maxim Kammerer.
 
   24 Jun 2012; Diego E. Pettenò <flameeyes@g.o>
   files/opensc-0.12.2-parallelinstall.patch, opensc-0.12.2-r1.ebuild:



1.1                  dev-libs/opensc/opensc-0.12.2-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/opensc/opensc-0.12.2-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/opensc/opensc-0.12.2-r2.ebuild?rev=1.1&content-type=text/plain

Index: opensc-0.12.2-r2.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/opensc/opensc-0.12.2-r2.ebuild,v 1.1 2012/08/26 23:40:02 flameeyes Exp $

EAPI=4

inherit eutils autotools

DESCRIPTION="Libraries and applications to access smartcards"
HOMEPAGE="http://www.opensc-project.org/opensc/"
SRC_URI="http://www.opensc-project.org/files/${PN}/${P}.tar.gz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="doc libtool +pcsc-lite openct readline ssl zlib"

RDEPEND="libtool? ( sys-devel/libtool )
	zlib? ( sys-libs/zlib )
	readline? ( sys-libs/readline )
	ssl? ( dev-libs/openssl )
	openct? ( >=dev-libs/openct-0.5.0 )
	pcsc-lite? ( >=sys-apps/pcsc-lite-1.3.0 )"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	app-text/docbook-xsl-stylesheets
	dev-libs/libxslt"

REQUIRED_USE="
	pcsc-lite? ( !openct )
	openct? ( !pcsc-lite )"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-0.12.1-crossbuild.patch
	epatch "${FILESDIR}"/${P}-parallelinstall.patch
	epatch "${FILESDIR}"/${P}-dl.patch
	eautoreconf
}

src_configure() {
	# disable everything, enable selectively
	local myconf="--disable-pcsc --disable-openct --disable-ctapi"

	if use pcsc-lite; then
		myconf+=" --enable-pcsc"
	elif use openct; then
		myconf+=" --enable-openct"
	else
		myconf+=" --enable-ctapi"
	fi

	# the configure script prefers libtool's libltdl over
	# the native system's dlopen ... so we have to manually
	# control the behavior to something a bit more sane
	export ac_cv_header_ltdl_h=$(usex libtool) \
		   ac_cv_lib_ltdl_lt_dlopen=$(usex libtool)

	econf \
		--docdir="/usr/share/doc/${PF}" \
		--htmldir='$(docdir)/html' \
		--disable-static \
		$(use_enable doc) \
		$(use_enable openct) \
		$(use_enable readline) \
		$(use_enable zlib) \
		$(use_enable ssl openssl) \
		${myconf}
}

src_install() {
	default
	find "${ED}"/usr -name '*.la' -delete
}