[gentoo-commits] proj/gnome:master commit in: dev-libs/libgweather/

[Gilles Dartiguelongue]

commit:     d52dda0935720d0736ac5f9fae1fc347df6e950a
Author:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
AuthorDate: Mon Nov 18 22:57:37 2013 +0000
Commit:     Gilles Dartiguelongue <eva <AT> gentoo <DOT> org>
CommitDate: Sun Dec  1 23:04:26 2013 +0000
URL:        http://git.overlays.gentoo.org/gitweb/?p=proj/gnome.git;a=commit;h=d52dda09

dev-libs/libgweather: 3.8.3 → 3.10.1

---
 dev-libs/libgweather/libgweather-3.10.1.ebuild | 54 ++++++++++++++++++++++++++
 dev-libs/libgweather/libgweather-9999.ebuild   | 47 ++++++++++++----------
 2 files changed, 81 insertions(+), 20 deletions(-)

diff --git a/dev-libs/libgweather/libgweather-3.10.1.ebuild b/dev-libs/libgweather/libgweather-3.10.1.ebuild
new file mode 100644
index 0000000..156823a
--- /dev/null
+++ b/dev-libs/libgweather/libgweather-3.10.1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="5"
+GCONF_DEBUG="no"
+VALA_MIN_API_VERSION="0.18"
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 vala
+
+DESCRIPTION="Library to access weather information from online services"
+HOMEPAGE="https://wiki.gnome.org/LibGWeather"
+
+LICENSE="GPL-2+"
+SLOT="2/3-6" # subslot = 3-(libgweather-3 soname suffix)
+IUSE="glade +introspection vala"
+REQUIRED_USE="vala? ( introspection )"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~x86-solaris"
+
+COMMON_DEPEND="
+	>=x11-libs/gtk+-2.90.0:3[introspection?]
+	>=dev-libs/glib-2.35.1:2
+	>=net-libs/libsoup-2.34:2.4
+	>=dev-libs/libxml2-2.6.0
+	>=sys-libs/timezone-data-2010k
+
+	glade? ( >=dev-util/glade-3.16:3.10 )
+	introspection? ( >=dev-libs/gobject-introspection-0.9.5 )
+"
+RDEPEND="${COMMON_DEPEND}
+	!<gnome-base/gnome-applets-2.22.0
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/gtk-doc-am-1.11
+	>=dev-util/intltool-0.50
+	>=sys-devel/gettext-0.18
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	DOCS="AUTHORS ChangeLog MAINTAINERS NEWS"
+	gnome2_src_configure \
+		--disable-static \
+		$(use_enable glade glade-catalog) \
+		$(use_enable introspection) \
+		$(use_enable vala)
+}

diff --git a/dev-libs/libgweather/libgweather-9999.ebuild b/dev-libs/libgweather/libgweather-9999.ebuild
index 1e853b8..b5bd4b8 100644
--- a/dev-libs/libgweather/libgweather-9999.ebuild
+++ b/dev-libs/libgweather/libgweather-9999.ebuild
@@ -1,22 +1,24 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Header: $
 
 EAPI="5"
 GCONF_DEBUG="no"
-GNOME2_LA_PUNT="yes"
+VALA_MIN_API_VERSION="0.18"
+VALA_USE_DEPEND="vapigen"
 
-inherit gnome2
+inherit gnome2 vala
 if [[ ${PV} = 9999 ]]; then
 	inherit gnome2-live
 fi
 
 DESCRIPTION="Library to access weather information from online services"
-HOMEPAGE="https://live.gnome.org/LibGWeather"
+HOMEPAGE="https://wiki.gnome.org/LibGWeather"
 
 LICENSE="GPL-2+"
-SLOT="2/3-1" # subslot = 3-(libgweather-3 soname suffix)
-IUSE="+introspection"
+SLOT="2/3-6" # subslot = 3-(libgweather-3 soname suffix)
+IUSE="glade +introspection vala"
+REQUIRED_USE="vala? ( introspection )"
 if [[ ${PV} = 9999 ]]; then
 	IUSE="${IUSE} doc"
 	KEYWORDS=""
@@ -24,37 +26,42 @@ else
 	KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~x86-solaris"
 fi
 
-# libsoup-gnome is to be used because libsoup[gnome] might not
-# get libsoup-gnome installed by the time ${P} is built
-COMMON_DEPEND=">=x11-libs/gtk+-2.90.0:3[introspection?]
-	>=dev-libs/glib-2.13
-	>=net-libs/libsoup-gnome-2.25.1:2.4
+COMMON_DEPEND="
+	>=x11-libs/gtk+-2.90.0:3[introspection?]
+	>=dev-libs/glib-2.35.1:2
+	>=net-libs/libsoup-2.34:2.4
 	>=dev-libs/libxml2-2.6.0
 	>=sys-libs/timezone-data-2010k
 
+	glade? ( >=dev-util/glade-3.16:3.10 )
 	introspection? ( >=dev-libs/gobject-introspection-0.9.5 )
 "
 RDEPEND="${COMMON_DEPEND}
 	!<gnome-base/gnome-applets-2.22.0
 "
 DEPEND="${COMMON_DEPEND}
-	>=dev-util/gtk-doc-am-1.9
+	>=dev-util/gtk-doc-am-1.11
 	>=dev-util/intltool-0.50
-	sys-devel/gettext
+	>=sys-devel/gettext-0.18
 	virtual/pkgconfig
+	vala? ( $(vala_depend) )
 "
 
 if [[ ${PV} = 9999 ]]; then
 	DEPEND="${DEPEND}
-		doc? ( >=dev-util/gtk-doc-1.9 )"
+		doc? ( >=dev-util/gtk-doc-1.11 )"
 fi
 
+src_prepare() {
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
 src_configure() {
 	DOCS="AUTHORS ChangeLog MAINTAINERS NEWS"
-	# Do not add --disable-all-translations-in-one-xml : it will enable them
-	G2CONF="${G2CONF}
-		--enable-locations-compression
-		--disable-static
-		$(use_enable introspection)"
-	gnome2_src_configure
+	gnome2_src_configure \
+		--disable-static \
+		$(use_enable glade glade-catalog) \
+		$(use_enable introspection) \
+		$(use_enable vala)
 }