[gentoo-commits] repo/gentoo:master commit in: dev-python/pbr/

[Matt Thode]

commit:     34af332af0b816cc22f4f922462153bd4c55cc1a
Author:     Matthew Thode <prometheanfire <AT> gentoo <DOT> org>
AuthorDate: Tue Jan  3 16:37:29 2017 +0000
Commit:     Matt Thode <prometheanfire <AT> gentoo <DOT> org>
CommitDate: Tue Jan  3 16:37:29 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=34af332a

dev-python/pbr: fix bug 603848, missed import

Package-Manager: portage-2.3.0

 dev-python/pbr/pbr-1.10.0-r1.ebuild | 76 +++++++++++++++++++++++++++++++++++++
 1 file changed, 76 insertions(+)

diff --git a/dev-python/pbr/pbr-1.10.0-r1.ebuild b/dev-python/pbr/pbr-1.10.0-r1.ebuild
new file mode 100644
index 00000000..bbd33b5
--- /dev/null
+++ b/dev-python/pbr/pbr-1.10.0-r1.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_{4,5} pypy pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="Inject some useful and sensible default behaviors into setuptools"
+HOMEPAGE="https://github.com/openstack-dev/pbr"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="test"
+
+# git is needed for tests, see https://bugs.launchpad.net/pbr/+bug/1326682 and https://bugs.gentoo.org/show_bug.cgi?id=561038
+# docutils is needed for sphinx exceptions... https://bugs.gentoo.org/show_bug.cgi?id=603848
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/coverage-3.6[${PYTHON_USEDEP}]
+		>=dev-python/fixtures-1.3.1[${PYTHON_USEDEP}]
+		<dev-python/fixtures-2.0[${PYTHON_USEDEP}]
+		>=dev-python/mock-1.2[${PYTHON_USEDEP}]
+		>=dev-python/subunit-0.0.18[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.1.2[${PYTHON_USEDEP}]
+		!~dev-python/sphinx-1.2.0[${PYTHON_USEDEP}]
+		<dev-python/sphinx-1.3[${PYTHON_USEDEP}]
+		>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+		>=dev-python/testrepository-0.0.18[${PYTHON_USEDEP}]
+		>=dev-python/testresources-0.2.4[${PYTHON_USEDEP}]
+		>=dev-python/testscenarios-0.4[${PYTHON_USEDEP}]
+		>=dev-python/testtools-1.4.0[${PYTHON_USEDEP}]
+		dev-python/virtualenv[${PYTHON_USEDEP}]
+		dev-python/wheel[${PYTHON_USEDEP}]
+		dev-python/docutils[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)"
+PDEPEND=""
+
+# This normally actually belongs here.
+python_prepare_all() {
+	# This test passes when run within the source and doesn't represent a failure, but rather
+	# a gentoo sandbox constraint
+	# Rm tests that rely upon the package being already installed and fail
+	sed -e s':test_console_script_develop:_&:' \
+		-e s':test_console_script_install:_&:' \
+		-e s':test_sdist_extra_files:_&:' \
+		-e s':test_command_hooks:_&:' \
+		-e s':test_sdist_git_extra_files:_&:' \
+		-i pbr/tests/test_core.py || die
+	sed -e s':test_command_hooks:_&:' \
+		-e s':test_global_setup_hooks:_&:' \
+		-i pbr/tests/test_hooks.py || die
+	sed \
+		-e "s:test_wsgi_script_install:_&:" \
+		-i pbr/tests/test_wsgi.py || die
+	einfo "rogue tests disabled"
+	sed -i '/^hacking/d' test-requirements.txt || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	distutils_install_for_testing
+
+	rm -rf .testrepository || die "couldn't remove '.testrepository' under ${EPTYHON}"
+
+	testr init || die "testr init failed under ${EPYTHON}"
+	testr run || die "testr run failed under ${EPYTHON}"
+}