[gentoo-commits] gentoo-x86 commit in media-video/nvidia-settings: ChangeLog nvidia-settings-180.22.ebuild

[Piotr Jaroszynski (peper)]

peper       09/01/21 14:49:57

  Modified:             ChangeLog
  Added:                nvidia-settings-180.22.ebuild
  Log:
  Add 188.22.
  (Portage version: 2.1.6.6/cvs/Linux 2.6.27-gentoo-r3 x86_64)

Revision  Changes    Path
1.52                 media-video/nvidia-settings/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/nvidia-settings/ChangeLog?rev=1.52&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/nvidia-settings/ChangeLog?rev=1.52&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/nvidia-settings/ChangeLog?r1=1.51&r2=1.52

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/nvidia-settings/ChangeLog,v
retrieving revision 1.51
retrieving revision 1.52
diff -u -r1.51 -r1.52
--- ChangeLog	13 Oct 2008 00:40:38 -0000	1.51
+++ ChangeLog	21 Jan 2009 14:49:57 -0000	1.52
@@ -1,6 +1,12 @@
 # ChangeLog for media-video/nvidia-settings
-# Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/nvidia-settings/ChangeLog,v 1.51 2008/10/13 00:40:38 ricmm Exp $
+# Copyright 2000-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/nvidia-settings/ChangeLog,v 1.52 2009/01/21 14:49:57 peper Exp $
+
+*nvidia-settings-180.22 (21 Jan 2009)
+
+  21 Jan 2009; Piotr Jaroszyński <peper@g.o>
+  +nvidia-settings-180.22.ebuild:
+  Add 180.22.
 
 *nvidia-settings-177.80 (13 Oct 2008)
 



1.1                  media-video/nvidia-settings/nvidia-settings-180.22.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/nvidia-settings/nvidia-settings-180.22.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-video/nvidia-settings/nvidia-settings-180.22.ebuild?rev=1.1&content-type=text/plain

Index: nvidia-settings-180.22.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/nvidia-settings/nvidia-settings-180.22.ebuild,v 1.1 2009/01/21 14:49:57 peper Exp $

inherit eutils toolchain-funcs multilib

MY_P="${PN}-1.0"

DESCRIPTION="NVIDIA Linux X11 Settings Utility"
HOMEPAGE="http://www.nvidia.com/"
SRC_URI="ftp://download.nvidia.com/XFree86/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="-* ~amd64 ~x86 ~x86-fbsd"
IUSE=""

# xorg-server is used in the depends as nvidia-settings builds against some
# headers in /usr/include/xorg/.
# This also allows us to optimize out a lot of the other dependancies, as
# between gtk and xorg-server, almost all libraries and headers are accounted
# for.
DEPEND=">=x11-libs/gtk+-2
	dev-util/pkgconfig
	x11-base/xorg-server
	x11-libs/libXt
	x11-libs/libXv
	x11-proto/xf86driproto
	x11-proto/xf86vidmodeproto"

RDEPEND=">=x11-libs/gtk+-2
	x11-base/xorg-server
	x11-libs/libXt
	x11-drivers/nvidia-drivers"

S="${WORKDIR}/${MY_P}"

src_compile() {
	einfo "Building libXNVCtrl..."
	cd "${S}/src/libXNVCtrl"
	make clean || die "Cleaning old libXNVCtrl failed"
	emake CDEBUGFLAGS="${CFLAGS}" CC="$(tc-getCC)" libXNVCtrl.a || die "Building libXNVCtrl failed!"

	cd "${S}"
	einfo "Building nVidia-Settings..."
	emake  CC="$(tc-getCC)" || die "Failed to build nvidia-settings"
}

src_install() {
	# Install the executable
	exeinto /usr/bin
	doexe nvidia-settings

	# Install libXNVCtrl and headers
	insinto "/usr/$(get_libdir)"
	doins src/libXNVCtrl/libXNVCtrl.a
	insinto /usr/include/NVCtrl
	doins src/libXNVCtrl/{NVCtrl,NVCtrlLib}.h

	# Install icon and .desktop entry
	doicon "${FILESDIR}/icon/${PN}.png"
	domenu "${FILESDIR}/icon/${PN}.desktop"

	# Install manpage
	doman doc/nvidia-settings.1

	# Now install documentation
	dodoc doc/*.txt
}