[gentoo-commits] gentoo-x86 commit in app-editors/bluefish: bluefish-2.0.0_rc2.ebuild metadata.xml ChangeLog

[Daniel Pielmeier (billie)]

billie      10/01/25 22:30:27

  Modified:             metadata.xml ChangeLog
  Added:                bluefish-2.0.0_rc2.ebuild
  Log:
  Version bump.
  (Portage version: 2.1.7.16/cvs/Linux i686)

Revision  Changes    Path
1.2                  app-editors/bluefish/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/bluefish/metadata.xml?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/bluefish/metadata.xml?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/bluefish/metadata.xml?r1=1.1&r2=1.2

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-editors/bluefish/metadata.xml,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- metadata.xml	30 Aug 2003 10:58:11 -0000	1.1
+++ metadata.xml	25 Jan 2010 22:30:26 -0000	1.2
@@ -1,6 +1,9 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-<herd>no-herd</herd>
-<maintainer><email>hanno@g.o</email></maintainer>
+	<herd>no-herd</herd>
+	<maintainer><email>hanno@g.o</email></maintainer>
+	<use>
+		<flag name="gucharmap">Enable gucharmap dictionary plugin</flag>
+	</use>
 </pkgmetadata>



1.68                 app-editors/bluefish/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/bluefish/ChangeLog?rev=1.68&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/bluefish/ChangeLog?rev=1.68&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/bluefish/ChangeLog?r1=1.67&r2=1.68

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-editors/bluefish/ChangeLog,v
retrieving revision 1.67
retrieving revision 1.68
diff -u -r1.67 -r1.68
--- ChangeLog	22 Jan 2010 23:57:50 -0000	1.67
+++ ChangeLog	25 Jan 2010 22:30:26 -0000	1.68
@@ -1,6 +1,12 @@
 # ChangeLog for app-editors/bluefish
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/bluefish/ChangeLog,v 1.67 2010/01/22 23:57:50 billie Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/bluefish/ChangeLog,v 1.68 2010/01/25 22:30:26 billie Exp $
+
+*bluefish-2.0.0_rc2 (25 Jan 2010)
+
+  25 Jan 2010; Daniel Pielmeier <billie@g.o>
+  +bluefish-2.0.0_rc2.ebuild, metadata.xml:
+  Version bump.
 
 *bluefish-2.0.0_rc1 (22 Jan 2010)
 



1.1                  app-editors/bluefish/bluefish-2.0.0_rc2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/bluefish/bluefish-2.0.0_rc2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/bluefish/bluefish-2.0.0_rc2.ebuild?rev=1.1&content-type=text/plain

Index: bluefish-2.0.0_rc2.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-editors/bluefish/bluefish-2.0.0_rc2.ebuild,v 1.1 2010/01/25 22:30:26 billie Exp $

EAPI=2

inherit autotools eutils fdo-mime

IUSE="gucharmap nls python spell"

MY_P=${P/_/-}

DESCRIPTION="A GTK HTML editor for the experienced web designer or programmer."
SRC_URI="http://www.bennewitz.com/bluefish/stable/source/${MY_P}.tar.bz2"
HOMEPAGE="http://bluefish.openoffice.nl/"

LICENSE="GPL-2"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
SLOT="0"

RDEPEND="
	dev-libs/libpcre
	x11-libs/gtk+:2
	spell? ( app-text/enchant[aspell] )"

DEPEND="${RDEPEND}
	dev-libs/glib:2
	dev-libs/libxml2
	dev-util/pkgconfig
	x11-libs/pango
	gucharmap? ( gnome-extra/gucharmap )
	nls? ( sys-devel/gettext dev-util/intltool )
	python? ( dev-lang/python )"

S=${WORKDIR}/${MY_P}

src_prepare () {
	# Fixes automagic installation of charmap plugin
	# Upstream bug: https://bugzilla.gnome.org/show_bug.cgi?id=570990
	epatch "${FILESDIR}"/${PN}-2.0.0_rc1-gucharmap-automagic.patch
	eautoreconf
}

src_configure() {
	econf \
		--disable-dependency-tracking \
		--disable-update-databases \
		--disable-xml-catalog-update \
		--enable-splash-screen \
		$(use_enable nls) \
		$(use_enable spell spell-check) \
		$(use_enable gucharmap charmap) \
		$(use_enable python)
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update

	einfo "Adding XML catalog entries..."
	/usr/bin/xmlcatalog  --noout \
		--add 'public' 'Bluefish/DTD/Bflang' 'bflang.dtd' \
		--add 'system' 'http://bluefish.openoffice.nl/DTD/bflang.dtd' 'bflang.dtd' \
		--add 'rewriteURI' 'http://bluefish.openoffice.nl/DTD' '/usr/share/xml/bluefish-unstable' \
		/etc/xml/catalog \
		|| ewarn "Failed to add XML catalog entries."
}

pkg_postrm() {
	einfo "Removing XML catalog entries..."
	/usr/bin/xmlcatalog  --noout \
		--del 'Bluefish/DTD/Bflang' \
		--del 'http://bluefish.openoffice.nl/DTD/bflang.dtd' \
		--del 'http://bluefish.openoffice.nl/DTD' \
		/etc/xml/catalog \
		|| ewarn "Failed to remove XML catalog entries."
}