[gentoo-commits] repo/gentoo:master commit in: dev-python/django/

[Michał Górny]

commit:     7a13a4d8237836331c7cdad0554cc3206583b572
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Dec  1 09:57:37 2020 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Dec  1 10:32:03 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7a13a4d8

dev-python/django: Bump to 3.1.4

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/django/Manifest            |  2 +
 dev-python/django/django-3.1.4.ebuild | 95 +++++++++++++++++++++++++++++++++++
 2 files changed, 97 insertions(+)

diff --git a/dev-python/django/Manifest b/dev-python/django/Manifest
index 4f6f6a1cc9a..d96f1b18353 100644
--- a/dev-python/django/Manifest
+++ b/dev-python/django/Manifest
@@ -8,3 +8,5 @@ DIST Django-3.1.1.tar.gz 9250616 BLAKE2B 220c53873a70bb30f0ea9b48a70ba71b2de517c
 DIST Django-3.1.2.tar.gz 9387482 BLAKE2B 77e330b4b42f85ef416e90a2690c6315f2a8d30b5705f64b86f62daabe3ff60b24d9fcf8a1276e7425e5cf0e03833a5ca601d15dc3e1aa32f7b5d7a9792302da SHA512 39115e942c26c9af27c4079f590e15caa86cc5c0e012873d7be23809e39de178b2dd935919dee21bbee153bccb17463abcece1db3b1f7dfa95b7b55879488876
 DIST Django-3.1.3.checksum.txt 2429 BLAKE2B 7184da75a1da2c615c78a892c8331ff4abfec86e1ae93f8a74c836988d97ecafbbadaecffd352904c01b40a840a80f4d24e8b48f2570054a2349ef6c58bb43e3 SHA512 ecb1de139b05e697253e0b09fd15b692050be647cceb30d8f1482613d0c3393a3017460aabd7ff71ad1de2a8c70cc9276525d7a2a9285540a052805c969f55d8
 DIST Django-3.1.3.tar.gz 9253273 BLAKE2B 9284b637ea39e028ebabe44de50dacfe6a89621fcc5eea73b7f470fc998faeb361da428be8f3f3e349f25b8629b5a350f3a5b7c35ea50183b285daf63d8944a7 SHA512 0f49316dc61a299a257313c27051852e948337491047bacb2221c9c753a5cf4bafb2ed686311ad5345dd3045260331afccb013c21503891538340225a469d1ad
+DIST Django-3.1.4.checksum.txt 2466 BLAKE2B 635ddd40b542890aef29f53df0fad172e48450081f57c72042a71bb5de654b1d1f5f7ce0c588b1070a203e1d4afe3a1ed19431dd23a2a67cd510d4072c79a00f SHA512 729b771008489bbf0563002e438ef88abb2a14b2c29f307cb2db9c75450f30ac8bd4920bf0493dbec06b3640fc0d4b6817e8a054af1028ad065bd321c761a6c3
+DIST Django-3.1.4.tar.gz 9392125 BLAKE2B b583442de50c358e70a49b9ef557d43211e6faee17933a44012dbb9f0dac3ccbf0a91e01a2b8b798fff7ae05100199e9e9c94a81748b41ea13e49d12bb510617 SHA512 02cfaabb25e5f932dcbf659faba2f0afe298e4bee4f510f7adebfff181bdd13c3a0b08e8ce379bcc59326d904be8699db4ce31065d93566b93cad758365207f5

diff --git a/dev-python/django/django-3.1.4.ebuild b/dev-python/django/django-3.1.4.ebuild
new file mode 100644
index 00000000000..6e2cded2dbc
--- /dev/null
+++ b/dev-python/django/django-3.1.4.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_USE_SETUPTOOLS=rdepend
+PYTHON_COMPAT=( python3_{6..9} )
+PYTHON_REQ_USE='sqlite?,threads(+)'
+
+inherit bash-completion-r1 distutils-r1 optfeature verify-sig
+
+MY_P=${P^}
+DESCRIPTION="High-level Python web framework"
+HOMEPAGE="https://www.djangoproject.com/ https://pypi.org/project/Django/"
+SRC_URI="
+	https://media.djangoproject.com/releases/$(ver_cut 1-2)/${MY_P}.tar.gz
+	verify-sig? ( https://media.djangoproject.com/pgp/${MY_P}.checksum.txt )"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD"
+# admin fonts: Roboto (media-fonts/roboto)
+LICENSE+=" Apache-2.0"
+# admin icons, jquery, xregexp.js
+LICENSE+=" MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86 ~x64-macos"
+IUSE="doc sqlite test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-python/asgiref[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	>=dev-python/sqlparse-0.2.2[${PYTHON_USEDEP}]"
+BDEPEND="
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		$(python_gen_impl_dep sqlite)
+		${RDEPEND}
+		dev-python/docutils[${PYTHON_USEDEP}]
+		dev-python/jinja[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pillow[webp,${PYTHON_USEDEP}]
+		dev-python/pyyaml[${PYTHON_USEDEP}]
+		dev-python/selenium[${PYTHON_USEDEP}]
+		dev-python/tblib[${PYTHON_USEDEP}]
+		sys-devel/gettext
+	)
+	verify-sig? ( >=app-crypt/openpgp-keys-django-20201201 )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.1-bashcomp.patch
+)
+
+distutils_enable_sphinx docs --no-autodoc
+
+VERIFY_SIG_OPENPGP_KEY_PATH=${BROOT}/usr/share/openpgp-keys/django.asc
+
+src_unpack() {
+	if use verify-sig; then
+		cd "${DISTDIR}" || die
+		verify-sig_verify_signed_checksums \
+			"${MY_P}.checksum.txt" sha256 "${MY_P}.tar.gz"
+		cd "${WORKDIR}" || die
+	fi
+
+	default
+}
+
+python_test() {
+	# Tests have non-standard assumptions about PYTHONPATH,
+	# and don't work with ${BUILD_DIR}/lib.
+	PYTHONPATH=. "${EPYTHON}" tests/runtests.py --settings=test_sqlite -v2 ||
+		die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	newbashcomp extras/django_bash_completion ${PN}-admin
+	bashcomp_alias ${PN}-admin django-admin.py
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	elog "Additional Backend support can be enabled via"
+	optfeature "MySQL backend support" dev-python/mysqlclient
+	optfeature "PostgreSQL backend support" dev-python/psycopg:2
+	elog
+	elog "Other features can be enhanced by"
+	optfeature "GEO Django" "sci-libs/gdal[geos]"
+	optfeature "Memcached support" dev-python/pylibmc dev-python/python-memcached
+	optfeature "ImageField Support" dev-python/pillow
+	optfeature "Password encryption" dev-python/bcrypt
+	optfeature "High-level abstractions for Django forms" dev-python/django-formtools
+}