[gentoo-commits] gentoo-x86 commit in net-misc/spice-gtk: metadata.xml ChangeLog spice-gtk-0.6.ebuild

[Tiziano Mueller (dev-zero)]

dev-zero    11/04/27 14:17:06

  Modified:             metadata.xml ChangeLog
  Added:                spice-gtk-0.6.ebuild
  Log:
  Version bump, also solves bug #364201.
  
  (Portage version: 2.1.9.46/cvs/Linux x86_64)

Revision  Changes    Path
1.2                  net-misc/spice-gtk/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/spice-gtk/metadata.xml?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/spice-gtk/metadata.xml?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/spice-gtk/metadata.xml?r1=1.1&r2=1.2

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/spice-gtk/metadata.xml,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- metadata.xml	24 Feb 2011 13:46:09 -0000	1.1
+++ metadata.xml	27 Apr 2011 14:17:06 -0000	1.2
@@ -7,6 +7,7 @@
 		<name>Tiziano Müller</name>
 	</maintainer>
 	<use>
+		<flag name="gtk3">Link against <pkg>x11-libs/gtk+:3</pkg> instead of <pkg>x11-libs/gtk+:2</pkg></flag>
 		<flag name="introspection">Use <pkg>dev-libs/gobject-introspection</pkg> for introspection</flag>
 	</use>
 </pkgmetadata>



1.2                  net-misc/spice-gtk/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/spice-gtk/ChangeLog?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/spice-gtk/ChangeLog?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/spice-gtk/ChangeLog?r1=1.1&r2=1.2

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/spice-gtk/ChangeLog,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- ChangeLog	24 Feb 2011 13:46:09 -0000	1.1
+++ ChangeLog	27 Apr 2011 14:17:06 -0000	1.2
@@ -1,6 +1,12 @@
 # ChangeLog for net-misc/spice-gtk
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/spice-gtk/ChangeLog,v 1.1 2011/02/24 13:46:09 dev-zero Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/spice-gtk/ChangeLog,v 1.2 2011/04/27 14:17:06 dev-zero Exp $
+
+*spice-gtk-0.6 (27 Apr 2011)
+
+  27 Apr 2011; Tiziano Müller <dev-zero@g.o> +spice-gtk-0.6.ebuild,
+  metadata.xml:
+  Version bump, also solves bug #364201.
 
 *spice-gtk-0.5 (24 Feb 2011)
 



1.1                  net-misc/spice-gtk/spice-gtk-0.6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/spice-gtk/spice-gtk-0.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/spice-gtk/spice-gtk-0.6.ebuild?rev=1.1&content-type=text/plain

Index: spice-gtk-0.6.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/spice-gtk/spice-gtk-0.6.ebuild,v 1.1 2011/04/27 14:17:06 dev-zero Exp $

EAPI=3

inherit python gnome2-utils

PYTHON_DEPEND="python? 2"

DESCRIPTION="Set of GObject and Gtk objects for connecting to Spice servers and a client GUI."
HOMEPAGE="http://spice-space.org http://gitorious.org/spice-gtk"
SRC_URI="http://spice-space.org/download/gtk/${P}.tar.bz2"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64"
IUSE="+cairo doc gnome gstreamer gtk3 introspection kde +pulseaudio python sasl static-libs"

RDEPEND="pulseaudio? ( !gstreamer? ( media-sound/pulseaudio ) )
	gstreamer? ( media-libs/gstreamer )
	>=app-emulation/spice-protocol-0.8.0-r1
	>=x11-libs/pixman-0.17.7
	>=media-libs/celt-0.5.1.1:0.5.1
	dev-libs/openssl
	gtk3? ( x11-libs/gtk+:3[introspection?] )
	!gtk3? ( x11-libs/gtk+:2[introspection?] )
	dev-libs/glib:2
	>=x11-libs/cairo-1.2
	virtual/jpeg
	sys-libs/zlib
	introspection? ( dev-libs/gobject-introspection )
	python? ( dev-python/pygtk:2 )
	sasl? ( dev-libs/cyrus-sasl )
	gnome? ( gnome-base/gconf )"
DEPEND="${RDEPEND}
	dev-lang/python
	dev-lang/perl
	dev-perl/Text-CSV
	dev-python/pyparsing
	dev-util/pkgconfig"

pkg_setup() {
	if use gstreamer && use pulseaudio ; then
		ewarn "spice-gtk can use only one audio backend: gstreamer will be used since you enabled both."
	fi
}

src_configure() {
	local audio="no"
	local gtk="2.0"

	use pulseaudio && audio="pulse"
	use gstreamer && audio="gstreamer"
	use gtk3 && gtk="3.0"

	econf \
		$(use_enable static-libs static) \
		$(use_enable introspection) \
		--with-audio="${audio}" \
		$(use_with !cairo x11) \
		$(use_with python) \
		$(use_with sasl) \
		--with-gtk="${gtk}"

}

src_install() {
	emake -j1 DESTDIR="${D}" install || die "emake install failed"

	use static-libs || rm -rf "${D}"/usr/lib*/*.la
	use python && rm -rf "${D}"/usr/lib*/python*/site-packages/*.la
	use doc || rm -rf "${D}/usr/share/gtk-doc"

	dodoc AUTHORS NEWS README TODO

	if use gnome ; then
		insinto /etc/gconf/schemas
		doins "${FILESDIR}/spice.schemas"
	fi
	if use kde ; then
		insinto /usr/share/kde4/services
		doins "${FILESDIR}/spice.protocol"
	fi

}

pkg_preinst() {
	use gnome && gnome2_gconf_savelist
}

pkg_postinst() {
	use gnome && gnome2_gconf_install
}

pkg_prerm() {
	use gnome && gnome2_gconf_uninstall
}