[gentoo-commits] gentoo-x86 commit in sci-electronics/splat: splat-1.4.2.ebuild ChangeLog

[Thomas Beierlein (tomjbe)]

tomjbe      15/01/01 17:03:25

  Modified:             ChangeLog
  Added:                splat-1.4.2.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key 0x762053D5)

Revision  Changes    Path
1.18                 sci-electronics/splat/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-electronics/splat/ChangeLog?rev=1.18&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-electronics/splat/ChangeLog?rev=1.18&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-electronics/splat/ChangeLog?r1=1.17&r2=1.18

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-electronics/splat/ChangeLog,v
retrieving revision 1.17
retrieving revision 1.18
diff -u -r1.17 -r1.18
--- ChangeLog	29 Nov 2014 12:57:05 -0000	1.17
+++ ChangeLog	1 Jan 2015 17:03:25 -0000	1.18
@@ -1,6 +1,11 @@
 # ChangeLog for sci-electronics/splat
-# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-electronics/splat/ChangeLog,v 1.17 2014/11/29 12:57:05 tomjbe Exp $
+# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sci-electronics/splat/ChangeLog,v 1.18 2015/01/01 17:03:25 tomjbe Exp $
+
+*splat-1.4.2 (01 Jan 2015)
+
+  01 Jan 2015; Thomas Beierlein <tomjbe@g.o> +splat-1.4.2.ebuild:
+  Version bump
 
 *splat-1.4.1-r1 (29 Nov 2014)
 



1.1                  sci-electronics/splat/splat-1.4.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-electronics/splat/splat-1.4.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-electronics/splat/splat-1.4.2.ebuild?rev=1.1&content-type=text/plain

Index: splat-1.4.2.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-electronics/splat/splat-1.4.2.ebuild,v 1.1 2015/01/01 17:03:25 tomjbe Exp $

EAPI=5
inherit eutils toolchain-funcs

DESCRIPTION="RF Signal Propagation, Loss, And Terrain analysis tool for the spectrum between 20 MHz and 20 GHz"
HOMEPAGE="http://www.qsl.net/kd2bd/splat.html"
SRC_URI="http://www.qsl.net/kd2bd/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="doc hires linguas_es"

DEPEND="sys-libs/zlib
	app-arch/bzip2"

RDEPEND="${DEPEND}"

src_prepare() {
	epatch "${FILESDIR}/${PN}-1.2.2-gcc43.patch"
}

src_configure() {
	# fake resulting file from interactive configuration script
	# using default resolution
	cat <<- EOF > "${S}/splat.h"
		/* Parameters for 3 arc-second standard resolution mode of operation */
		#define MAXPAGES 9
		#define HD_MODE 0
	EOF
	if use hires; then
		# fake resulting file from interactive configuration script
		# using default resolution
		cat <<- EOF > "${S}/hires.h"
			/* Parameters for 3 arc-second hires resolution mode of operation */
			#define MAXPAGES 9
			#define HD_MODE 1
	EOF
	fi
}

src_compile() {

	local CC=$(tc-getCC) CXX=$(tc-getCXX)

	${CXX} -Wall ${CXXFLAGS} ${LDFLAGS} itwom3.0.cpp splat.cpp -o rfsplat -lm -lbz2 || die
	if use hires; then
		cp "${S}/hires.h" "${S}/splat.h"
		${CXX} -Wall ${CXXFLAGS} ${LDFLAGS} itwom3.0.cpp splat.cpp -o rfsplat-hd -lm -lbz2 || die
	fi

	cd utils
	${CC} -Wall ${CFLAGS} ${LDFLAGS} citydecoder.c -o citydecoder
	${CC} -Wall ${CFLAGS} ${LDFLAGS} usgs2sdf.c    -o usgs2sdf
	${CC} -Wall ${CFLAGS} ${LDFLAGS} srtm2sdf.c    -o srtm2sdf   -lbz2
	#${CC} -Wall ${CFLAGS} ${LDFLAGS} fontdata.c    -o fontdata   -lz
	${CC} -Wall ${CFLAGS} ${LDFLAGS} bearing.c     -o bearing    -lm
}

src_install() {
	local SPLAT_LANG="english"
	use linguas_es && SPLAT_LANG="spanish"
	# splat binary
	dobin rfsplat
	if use hires; then
		dobin rfsplat-hd
	fi

	# utilities
	dobin utils/{citydecoder,usgs2sdf,srtm2sdf,postdownload,bearing}
	newman docs/${SPLAT_LANG}/man/splat.man rfsplat.1

	dodoc CHANGES README utils/fips.txt
	newdoc utils/README README.UTILS

	if use doc; then
		dodoc docs/${SPLAT_LANG}/{pdf/splat.pdf,postscript/splat.ps}
	fi
	#sample data
	docinto sample_data
	dodoc sample_data/*
}

pkg_postinst() {
	elog "The original SPLAT! command got renamed to 'rfsplat' to avoid"
	elog "filename collission with app-portage/splat."
	elog ""
	elog "Be aware that it is still referenced as 'splat' in the documentation."
}