[gentoo-commits] gentoo-x86 commit in net-firewall/arno-iptables-firewall: arno-iptables-firewall-2.0.1e.ebuild ChangeLog arno-iptables-firewall-1.9.2d.ebuild arno-iptables-firewall-1.9.2a.ebuild arno-iptables-firewall-2.0.1d-r1.ebuild

[Tom Wijsman (tomwij)]

tomwij      14/04/02 09:33:56

  Modified:             ChangeLog
  Added:                arno-iptables-firewall-2.0.1e.ebuild
  Removed:              arno-iptables-firewall-1.9.2d.ebuild
                        arno-iptables-firewall-1.9.2a.ebuild
                        arno-iptables-firewall-2.0.1d-r1.ebuild
  Log:
  Version bump to 2.0.1e; fixes bug #500114, proxied commit for Ferenc Erki. Removed old.
  
  (Portage version: HEAD/cvs/Linux x86_64, signed Manifest commit with key 6D34E57D)

Revision  Changes    Path
1.12                 net-firewall/arno-iptables-firewall/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/arno-iptables-firewall/ChangeLog?rev=1.12&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/arno-iptables-firewall/ChangeLog?rev=1.12&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/arno-iptables-firewall/ChangeLog?r1=1.11&r2=1.12

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-firewall/arno-iptables-firewall/ChangeLog,v
retrieving revision 1.11
retrieving revision 1.12
diff -u -r1.11 -r1.12
--- ChangeLog	26 Jan 2014 11:03:38 -0000	1.11
+++ ChangeLog	2 Apr 2014 09:33:56 -0000	1.12
@@ -1,6 +1,15 @@
 # ChangeLog for net-firewall/arno-iptables-firewall
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-firewall/arno-iptables-firewall/ChangeLog,v 1.11 2014/01/26 11:03:38 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-firewall/arno-iptables-firewall/ChangeLog,v 1.12 2014/04/02 09:33:56 tomwij Exp $
+
+*arno-iptables-firewall-2.0.1e (02 Apr 2014)
+
+  02 Apr 2014; Tom Wijsman <TomWij@g.o>
+  +arno-iptables-firewall-2.0.1e.ebuild, -arno-iptables-firewall-1.9.2a.ebuild,
+  -arno-iptables-firewall-1.9.2d.ebuild,
+  -arno-iptables-firewall-2.0.1d-r1.ebuild:
+  Version bump to 2.0.1e; fixes bug #500114, proxied commit for Ferenc Erki.
+  Removed old.
 
   26 Jan 2014; Agostino Sarubbo <ago@g.o>
   arno-iptables-firewall-2.0.1d-r2.ebuild:



1.1                  net-firewall/arno-iptables-firewall/arno-iptables-firewall-2.0.1e.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/arno-iptables-firewall/arno-iptables-firewall-2.0.1e.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-firewall/arno-iptables-firewall/arno-iptables-firewall-2.0.1e.ebuild?rev=1.1&content-type=text/plain

Index: arno-iptables-firewall-2.0.1e.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-firewall/arno-iptables-firewall/arno-iptables-firewall-2.0.1e.ebuild,v 1.1 2014/04/02 09:33:56 tomwij Exp $

EAPI=5
inherit readme.gentoo systemd

DESCRIPTION="Arno's iptables firewall script"
HOMEPAGE="http://rocky.eld.leidenuniv.nl"
SRC_URI="http://rocky.eld.leidenuniv.nl/${PN}/${PN}_${PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+plugins"

# sys-apps/coreutils dependency wrt
# https://bugs.gentoo.org/show_bug.cgi?id=448716

DEPEND=""
RDEPEND="net-firewall/iptables
	|| ( <sys-apps/coreutils-8.20 >sys-apps/coreutils-8.20-r1 )
	sys-apps/iproute2
	plugins? ( net-dns/bind-tools )"

S="${WORKDIR}/${PN}_${PV}"

DISABLE_AUTOFORMATTING="yes"
DOC_CONTENTS="You will need to configure /etc/${PN}/firewall.conf
before using this package. To start the script, run:

/etc/init.d/${PN} start (for OpenRC)
systemctl start ${PN} (for systemd)

If you want to start this script at boot, run:

rc-update add ${PN} default (for OpenRC)
systemctl enable ${PN} (for systemd)"

src_prepare() {
	sed -i -e 's:/usr/local/share/:/usr/libexec/:' \
		etc/"${PN}"/firewall.conf || die "Sed failed!"
	sed -i -e 's:/usr/local/sbin/:/usr/sbin/:' \
		lib/systemd/system/"${PN}.service" || die "Sed failed!"
}

src_install() {
	insinto /etc/"${PN}"
	doins etc/"${PN}"/firewall.conf
	doins etc/"${PN}"/custom-rules

	doinitd "${FILESDIR}/${PN}"
	systemd_dounit lib/systemd/system/"${PN}.service"

	dobin bin/arno-fwfilter
	dosbin bin/"${PN}"

	insinto /usr/libexec/"${PN}"
	doins share/"${PN}"/environment

	dodoc CHANGELOG README
	readme.gentoo_create_doc

	if use plugins
	then
		insinto /etc/"${PN}"/plugins
		doins etc/"${PN}"/plugins/*

		insinto /usr/libexec/"${PN}"/plugins
		doins share/"${PN}"/plugins/*.plugin

		exeinto /usr/libexec/"${PN}"/plugins
		doexe share/"${PN}"/plugins/dyndns-host-open-helper
		doexe share/"${PN}"/plugins/traffic-accounting-helper
		doexe share/"${PN}"/plugins/traffic-accounting-log-rotate
		doexe share/"${PN}"/plugins/traffic-accounting-show

		docinto plugins
		dodoc share/"${PN}"/plugins/*.CHANGELOG
	fi

	doman share/man/man1/arno-fwfilter.1 \
		share/man/man8/"${PN}".8
}

pkg_postinst () {
	ewarn "When you stop this script, all firewall rules are flushed!"
	ewarn "Make sure to not use multiple firewall scripts simultaneously"
	ewarn "unless you know what you are doing!"
	readme.gentoo_print_elog
}