Gentoo Archives: gentoo-commits

From: Andreas Sturmlechner <asturm@g.o>
To: gentoo-commits@l.g.o
Subject: [gentoo-commits] proj/kde:master commit in: kde-plasma/plasma-nm/
Date: Mon, 17 Jan 2022 17:50:06
Message-Id: 1642441601.94e8b4657cd6c2a9fc88ee8636402c842a12d988.asturm@gentoo
1 commit: 94e8b4657cd6c2a9fc88ee8636402c842a12d988
2 Author: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
3 AuthorDate: Mon Jan 17 17:40:46 2022 +0000
4 Commit: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
5 CommitDate: Mon Jan 17 17:46:41 2022 +0000
6 URL: https://gitweb.gentoo.org/proj/kde.git/commit/?id=94e8b465
7
8 kde-plasma/plasma-nm: 5.23.90 version bump
9
10 Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>
11
12 kde-plasma/plasma-nm/plasma-nm-5.23.90.ebuild | 90 +++++++++++++++++++++++++++
13 1 file changed, 90 insertions(+)
14
15 diff --git a/kde-plasma/plasma-nm/plasma-nm-5.23.90.ebuild b/kde-plasma/plasma-nm/plasma-nm-5.23.90.ebuild
16 new file mode 100644
17 index 0000000000..2069ad4247
18 --- /dev/null
19 +++ b/kde-plasma/plasma-nm/plasma-nm-5.23.90.ebuild
20 @@ -0,0 +1,90 @@
21 +# Copyright 1999-2022 Gentoo Authors
22 +# Distributed under the terms of the GNU General Public License v2
23 +
24 +EAPI=8
25 +
26 +ECM_TEST="true"
27 +KFMIN=5.90.0
28 +PVCUT=$(ver_cut 1-3)
29 +QTMIN=5.15.2
30 +inherit ecm kde.org
31 +
32 +DESCRIPTION="KDE Plasma applet for NetworkManager"
33 +
34 +LICENSE="GPL-2 LGPL-2.1"
35 +SLOT="5"
36 +KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~riscv ~x86"
37 +IUSE="modemmanager openconnect teamd"
38 +
39 +DEPEND="
40 + >=app-crypt/qca-2.3.0:2
41 + >=dev-qt/qtdbus-${QTMIN}:5
42 + >=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
43 + >=dev-qt/qtgui-${QTMIN}:5
44 + >=dev-qt/qtnetwork-${QTMIN}:5
45 + >=dev-qt/qtwidgets-${QTMIN}:5
46 + >=kde-frameworks/kcompletion-${KFMIN}:5
47 + >=kde-frameworks/kconfig-${KFMIN}:5
48 + >=kde-frameworks/kconfigwidgets-${KFMIN}:5
49 + >=kde-frameworks/kcoreaddons-${KFMIN}:5
50 + >=kde-frameworks/kdbusaddons-${KFMIN}:5
51 + >=kde-frameworks/kdeclarative-${KFMIN}:5
52 + >=kde-frameworks/ki18n-${KFMIN}:5
53 + >=kde-frameworks/kio-${KFMIN}:5
54 + >=kde-frameworks/kitemviews-${KFMIN}:5
55 + >=kde-frameworks/knotifications-${KFMIN}:5
56 + >=kde-frameworks/kservice-${KFMIN}:5
57 + >=kde-frameworks/kwallet-${KFMIN}:5
58 + >=kde-frameworks/kwidgetsaddons-${KFMIN}:5
59 + >=kde-frameworks/kwindowsystem-${KFMIN}:5
60 + >=kde-frameworks/kxmlgui-${KFMIN}:5
61 + >=kde-frameworks/networkmanager-qt-${KFMIN}:5[teamd=]
62 + >=kde-frameworks/plasma-${KFMIN}:5
63 + >=kde-frameworks/solid-${KFMIN}:5
64 + net-misc/networkmanager[teamd=]
65 + modemmanager? (
66 + >=dev-qt/qtxml-${QTMIN}:5
67 + >=kde-frameworks/modemmanager-qt-${KFMIN}:5
68 + net-misc/mobile-broadband-provider-info
69 + )
70 + openconnect? (
71 + >=dev-qt/qtxml-${QTMIN}:5
72 + net-vpn/networkmanager-openconnect
73 + net-vpn/openconnect:=
74 + )
75 +"
76 +RDEPEND="${DEPEND}
77 + >=dev-qt/qtquickcontrols-${QTMIN}:5
78 + >=dev-qt/qtquickcontrols2-${QTMIN}:5
79 + >=kde-frameworks/kirigami-${KFMIN}:5
80 + >=kde-plasma/kde-cli-tools-${PVCUT}:5
81 +"
82 +BDEPEND="virtual/pkgconfig"
83 +
84 +src_prepare() {
85 + ecm_src_prepare
86 +
87 + # TODO: try to get a build switch upstreamed
88 + if ! use openconnect; then
89 + sed -e "s/^pkg_check_modules.*openconnect/#&/" -i CMakeLists.txt || die
90 + fi
91 +}
92 +
93 +src_configure() {
94 + local mycmakeargs=(
95 + -DDISABLE_MODEMMANAGER_SUPPORT=$(usex !modemmanager)
96 + $(cmake_use_find_package modemmanager KF5ModemManagerQt)
97 + )
98 +
99 + ecm_src_configure
100 +}
101 +
102 +pkg_postinst() {
103 + ecm_pkg_postinst
104 +
105 + if ! has_version "kde-plasma/plasma-workspace:5"; then
106 + elog "${PN} is not terribly useful without kde-plasma/plasma-workspace:5."
107 + elog "However, the networkmanagement KCM can be called from either systemsettings"
108 + elog "or manually: $ kcmshell5 kcm_networkmanagement"
109 + fi
110 +}