[gentoo-commits] repo/gentoo:master commit in: games-fps/rott/

[Austin English]

commit:     452c7c70d4969cd3e80e4aa609047a3ef8147ddc
Author:     Austin English <wizardedit <AT> gentoo <DOT> org>
AuthorDate: Thu Feb  9 23:09:31 2017 +0000
Commit:     Austin English <wizardedit <AT> gentoo <DOT> org>
CommitDate: Tue Feb 14 23:41:18 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=452c7c70

games-fps/rott: remove deprecated games eclass

Also update to EAPI 6

Gentoo-Bug: https://bugs.gentoo.org/574082

Package-Manager: Portage-2.3.2, Repoman-2.3.1

 games-fps/rott/rott-1.1.2-r1.ebuild | 56 +++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

diff --git a/games-fps/rott/rott-1.1.2-r1.ebuild b/games-fps/rott/rott-1.1.2-r1.ebuild
new file mode 100644
index 0000000000..d14d5f9918
--- /dev/null
+++ b/games-fps/rott/rott-1.1.2-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit eutils
+
+DESCRIPTION="Rise of the Triad for Linux!"
+HOMEPAGE="http://www.icculus.org/rott/"
+SRC_URI="http://www.icculus.org/rott/releases/${P}.tar.gz
+	demo? ( http://filesingularity.timedoctor.org/swdata.zip )"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="demo"
+
+RDEPEND="media-libs/libsdl[sound,joystick,video]
+	media-libs/sdl-mixer"
+DEPEND="${RDEPEND}
+	app-arch/unzip"
+
+S=${WORKDIR}/${P}/rott
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e '/^CC =/d' \
+		Makefile || die "sed failed"
+	emake clean
+}
+
+src_compile() {
+	emake -j1 \
+		EXTRACFLAGS="${CFLAGS} -DDATADIR=\\\"/usr/share/${PN}/\\\"" \
+		SHAREWARE=$(usex demo "1" "0")
+}
+
+src_install() {
+	dobin rott
+	dodoc ../doc/*.txt ../README
+	doman ../doc/rott.6
+	if use demo ; then
+		cd "${WORKDIR}" || die
+		insinto /usr/share/${PN}
+		doins *.dmo huntbgin.* remote1.rts
+	fi
+}
+
+pkg_postinst() {
+	if ! use demo ; then
+		elog "To play the full version, just copy the"
+		elog "data files to /usr/share/${PN}/"
+	fi
+}