[gentoo-commits] gentoo-x86 commit in app-shells/dash: dash-0.5.6.1-r1.ebuild ChangeLog dash-0.5.6.1.ebuild

[Harald van Dijk (truedfx)]

truedfx     10/08/22 20:24:45

  Modified:             ChangeLog
  Added:                dash-0.5.6.1-r1.ebuild
  Removed:              dash-0.5.6.1.ebuild
  Log:
  Fix IFS handling with read command (#331535)
  (Portage version: 2.2_rc67/cvs/Linux x86_64)

Revision  Changes    Path
1.76                 app-shells/dash/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-shells/dash/ChangeLog?rev=1.76&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-shells/dash/ChangeLog?rev=1.76&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-shells/dash/ChangeLog?r1=1.75&r2=1.76

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-shells/dash/ChangeLog,v
retrieving revision 1.75
retrieving revision 1.76
diff -u -r1.75 -r1.76
--- ChangeLog	31 Jul 2010 22:09:47 -0000	1.75
+++ ChangeLog	22 Aug 2010 20:24:45 -0000	1.76
@@ -1,6 +1,12 @@
 # ChangeLog for app-shells/dash
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
 
+*dash-0.5.6.1-r1 (22 Aug 2010)
+
+  22 Aug 2010; Harald van Dijk <truedfx@g.o> -dash-0.5.6.1.ebuild,
+  +dash-0.5.6.1-r1.ebuild, +files/dash-0.5.6.1-read-ifs.patch:
+  Fix IFS handling with read command (#331535)
+
   31 Jul 2010; Lars Wendler <polynomial-c@g.o> dash-0.5.6.1.ebuild:
   non-maintainer commit: Readded keywords. Ebuild now removes offending
   patch which lead to bug #328929. Commit done with kind permission from



1.1                  app-shells/dash/dash-0.5.6.1-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-shells/dash/dash-0.5.6.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-shells/dash/dash-0.5.6.1-r1.ebuild?rev=1.1&content-type=text/plain

Index: dash-0.5.6.1-r1.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-shells/dash/dash-0.5.6.1-r1.ebuild,v 1.1 2010/08/22 20:24:45 truedfx Exp $

EAPI="2"

inherit autotools eutils flag-o-matic

DEB_PV=${PV%.*}
DEB_PATCH=${PV##*.}
DEB_PF="${PN}_${DEB_PV}.${DEB_PATCH}-1~exp0"
MY_P="${PN}-${DEB_PV}"

DESCRIPTION="DASH is a direct descendant of the NetBSD version of ash (the Almquist SHell) and is POSIX compliant"
HOMEPAGE="http://gondor.apana.org.au/~herbert/dash/"
SRC_URI="http://gondor.apana.org.au/~herbert/dash/files/${PN}-${DEB_PV}.tar.gz
	mirror://debian/pool/main/d/dash/${DEB_PF}.diff.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="libedit static"

DEPEND="libedit? ( dev-libs/libedit )"

S=${WORKDIR}/${MY_P}

src_prepare() {
	epatch "${WORKDIR}"/${DEB_PF}.diff
	rm  */debian/diff/0006--INPUT-exit-127-if-command_file-is-given-but-doesn-t.diff \
		|| die #328929
	epatch */debian/diff/*
	epatch "${FILESDIR}"/${P}-read-ifs.patch #331535

	# Fix the invalid sort
	sed -i -e 's/LC_COLLATE=C/LC_ALL=C/g' src/mkbuiltins

	# Always statically link libedit in to ensure we always boot if it changes
	# which it has done in the past.
	local s="s/-ledit/-Wl,-Bstatic -ledit -Wl,-Bdynamic -lcurses/g"
	use static && s="s/-ledit/-ledit -lcurses/g"
	sed -i -e "${s}" configure.ac || die "Failed to sed configure.ac"

	# May as well, as the debian patches force this anyway
	eautoreconf
}

src_configure() {
	use static && append-ldflags -static
	econf \
		--bindir=/bin \
		$(use_with libedit)
}

src_install() {
	emake install DESTDIR="${D}" || die
	dodoc ChangeLog */debian/changelog
}